Faire la somme des chiffres d'una date

[Merlin333]

Bonjour à tous
Je suis Novice sur Excel ou VBa j'ai besoin de votre aide svp
J'aimerais faire la somme des chiffres qui composent une date
Par exemple le 24/07/2012
24+07+2012=2043
et dans une deuxième colonne faire la somme des chiffres de ce nombre
soit =9
Pouvez m'aider merci

 

[Compte Supprimé 979]

Re : Faire la somme des chiffres d'una date

Bonjour Merlin333 et bienvenue sur ce forum

Une possibilité, sachant que ta date est en A1
En B1 :

=JOUR(A1)+MOIS(A1)+ANNEE(A1)

En C1 :

=GAUCHE(B1;1)+STXT(B1;2;1)+STXT(B1;3;1)+DROITE(B1;1)

A+

 

[Merlin333]

Re : Faire la somme des chiffres d'una date

Bonjour et Merci beaucoup si je veux reduire le résultat à un chiffre
par exemple 25/07/2012 me donne 10 mais je veux obtenir 1 est ce que je dois rajouter une colonne sur le meme principe

 

[tdenfert]

Re : Faire la somme des chiffres d'una date

Bonjour
avec la date en B5 en c5

=ANNEE(B5)+MOIS(B5)+JOUR(B5)

et la somme totale

=STXT(C5;1;1)*1+STXT(C5;2;1)*1+STXT(C5;3;1)*1+STXT(C5;4;1)*1

edit Bonjour à tous

ma soluce corrigée

=SI(STXT(C5;1;1)*1+STXT(C5;2;1)*1+STXT(C5;3;1)*1+STXT(C5;4;1)*1<10;STXT(C5;1;1)*1+STXT(C5;2;1)*1+STXT(C5;3;1)*1+STXT(C5;4;1)*1;DROITE(STXT(C5;1;1)*1+STXT(C5;2;1)*1+STXT(C5;3;1)*1+STXT(C5;4;1)*1;1)*1+GAUCHE(STXT(C5;1;1)*1+STXT(C5;2;1)*1+STXT(C5;3;1)*1+STXT(C5;4;1)*1;1))

 

[Merlin333]

Re : Faire la somme des chiffres d'una date

Merci à tous cela fonctionne

 

[Victor21]

Re : Faire la somme des chiffres d'una date

Bonjour, Merlin333, et bienvenue sur XLD

La date en A1, essayez (format standard ) :

=SI(STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);1;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);2;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);3;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);4;1)>9;STXT(STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);1;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);2;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);3;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);4;1);1;1)+STXT(STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);1;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);2;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);3;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);4;1);2;1);STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);1;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);2;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);3;1)+STXT(JOUR(A1)+MOIS(A1)+ANNEE(A1);4;1))

Bonjour, Bruno, tdenfert

 

[Merlin333]

Re : Faire la somme des chiffres d'una date

Merci c'est parfait

 

[R@chid]

Re : Faire la somme des chiffres d'una date

Bonjour @ tous,
Salut Bruno, Salut Patrick, Salut tdenfert (Pardon pas vu)
Avec Formule matricielle et sans colonne intermédiaire,
Date en A2 et Formule en B2,

=SOMME(1*(STXT(TEXTE(SOMME(1*(STXT(ANNEE(A2)+MOIS(A2)+JOUR(A2);LIGNE($1:$4);1)));"00");LIGNE($1:$2);1)))

@ valider par Ctrl+Maj+Entree

Ou bien avec SOMMEPROD() et validation classique,

=SOMMEPROD(1*(STXT(TEXTE(SOMMEPROD(1*(STXT(ANNEE(A2)+MOIS(A2)+JOUR(A2);LIGNE($1:$4);1)));"00");LIGNE($1:$2);1)))

Amicalement

Edit1 : Voir Fichier Recapitulatif,
Edit2 : Voir PJ, je l'ai modifie @ cause de l’incompatibilité avec Excel2003

 

[Staple1600]

Re : Faire la somme des chiffres d'una date

Bonsoir à tous


Y'aurait comme de la numérologie dans l'air non ?
Dans ce cas, jadis, dans un fil, on pouvait lire
https://www.excel-downloads.com/threads/reduction-theosophique.70224/

RACINE THÉOSOPHIQUE – Définition
La réduction théosophique – ou racine essentielle - est un nom complexe pour une opération somme toute des plus simples. Il s'agit de faire la somme des chiffres du nombre. De recommencer, si nécessaire, avec le résultat. Jusqu'à obtenir un seul chiffre.	123 => 1 + 2 + 3 = 6 La racine théosophique de 123 est 6. 456 => 4 + 5 + 6 = 15 => 1 + 5 = 6 La racine théosophique de 456 est 6.

source: [FONT=&amp]Gérard Villemin.[/FONT]

 

[david84]

Re : Faire la somme des chiffres d'una date

Bonsoir tout le monde,
une autre possibilité en matriciel :

=GAUCHE(SOMME(STXT(SOMME(STXT(SUBSTITUE(TEXTE(A2;"jj/mm/aaaa");"/";"");LIGNE($1:$8);1)*1);LIGNE($1:$2);1)*1);1)*1

A+

 

[Modeste geedee]

Re : Faire la somme des chiffres d'una date

bonsour®

Bonsoir tout le monde,
une autre possibilité en matriciel :

=GAUCHE(SOMME(STXT(SOMME(STXT(SUBSTITUE(TEXTE(A2;"jj/mm/aaaa");"/";"");LIGNE($1:$8);1)*1);LIGNE($1:$2);1)*1);1)*1

A+

plus court ...
=GAUCHE(SOMME(STXT(SOMME(STXT(TEXTE(A2;"jjmmaaaa");LIGNE($1:$8);1)*1);LIGNE($1:$2);1)*1);1)*1

 

[Pierrot93]

Re : Faire la somme des chiffres d'una date

Bonjour à tous,

une approche vba, la date en A1 :

MsgBox (Replace(Range("A1").Text, "/", "") - 1) Mod 9 + 1

bonne journée
@+

 

[david84]

Re : Faire la somme des chiffres d'una date

Bonjour,
en adaptant la proposition VBA de Pierrot, cela pourrait donner :

=SI(MOD(TEXTE(A2;"jjmmaaaa");9)=0;9;MOD(TEXTE(A2;"jjmmaaaa");9))

Plus court et en validation classique.
Bravo Pierrot mais comment t'est venue l'idée de passer par MOD ?
A+

 

[Pierrot93]

Re : Faire la somme des chiffres d'una date

Re, bonjour David

Bravo Pierrot mais comment t'est venue l'idée de passer par MOD ?

merci David, bonne question.... j'ai du voir cela un jour quelque part, mais où....

 

[Compte Supprimé 979]

Re : Faire la somme des chiffres d'una date

Bonjour le fil

[n'apporte rien au sujet]

juste un mot ... IMPRESSIONNANT ... comment arrive t'on à trouver des formules pareilles

Chapeau bas Mister Pierrot93 et bravo pour l'adaptation en formule Mister David84

Au plaisir