Extraire du texte souligné

[lionelch1]

Bonjour ,

Je recherche une formule pour extraire dans une autre colonne du texte souligné (Excel 2003)
ci joint fichier exemple

merci
Lionel

 

[Robert]

Re : Extraire du texte souligné

Bonjour Lionel, bonjour le forum,

Par formule je ne sais pas faire. Je te propose le code VBA ci-dessous :

Sub Macro1()
Dim dl As Integer 'déclare la variable dl (Dernière Ligne)
Dim c As String 'déclare la variable c (Caractère)
Dim m As String 'déclare la variable m (Mot)
Dim i As Integer 'déclare la variable i (Incrément)


With Sheets("Feuil1") 'prend en compte l'onglet "Feuil1"
    dl = .Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne éditée dl de la colonne A
    For Each cel In .Range("A2:A" & dl) 'boucle 1 : sur toutes les cellule éditées cel de la colonne A
        m = "" 'réinitialise la variable m
        For i = 1 To Len(cel.Value) 'boucle 2 : sur tos les caractères de la cellule cel
            'si le caractère est souligné rajoute le caractère au mot m
            If cel.Characters(Start:=i, Length:=1).Font.Underline = xlUnderlineStyleSingle Then m = m & Mid(cel.Value, i, 1)
        Next i 'prochain caractère de la boucle 2
        cel.Offset(0, 1).Value = m 'place le mot m dans la colonne B
    Next cel 'prochaine cellule de la boucle 1
End With 'fin de la prise en compte de l'onglet "Feuil1"
End Sub

Le fichier :

 

[tototiti2008]

Re : Extraire du texte souligné

Bonjour lionelch1,

un essai :

à mettre dans un module standard

Function ExtrSoulign(Cellule As Range) As String
Dim i As Long
    ExtrSoulign = ""
    For i = 1 To Len(Cellule)
        If Cellule.Characters(Start:=i, Length:=1).Font.Underline <> xlUnderlineStyleNone Then
            ExtrSoulign = ExtrSoulign & Cellule.Characters(Start:=i, Length:=1).Text
        End If
    Next i
End Function

puis dans une cellule

=extrsoulign(A2)

Edit : Bonjour Robert

 

[lionelch1]

Re : Extraire du texte souligné

Bonjour a tout les deux ,
pour le code VBA de Robert cela fonctionne mais tres long a avoir le resultat
( plus de 500 lignes avec une trentaine de mots dans chaque cellules )
pour le module standart , je ne sais pas faire !!
merci
Lionel

 

[Robert]

Re : Extraire du texte souligné

Bonjour Lionel, Tototiti, bonjour le forum,

Aussi long que de se le faire à la main ? je parlais du copier/collier œuf Corse...

 

[lionelch1]

Re : Extraire du texte souligné

Deja avec 2 lignes en plus on voit que c'est long
fichier joint
Lionel

 

[Robert]

Re : Extraire du texte souligné

Bonjour Lionel, Tototiti, bonjour le forum,

Désolé je ne sais pas faire plus vite...

 

[tototiti2008]

Re : Extraire du texte souligné

Re,

Oui, forcément, on a pas d'autre choix que de parcourir caractère à caractère pour savoir s'il est souligné
Donc sur des pavés de texte, c'est un peu long, mais surement moins que la version manuelle