Envoie automatique d'un mail avec PJ/batch

[kalmard]

Bonjour,
D'abord je vous remercie de l'attention que vous accorderez à mon problème.

J'ai créer une table excel liée à un base access, et sur excel j'ai saisi le code ci-dessous afin d'envoyer par mail via outlook mon classeur (xlsm) vers destinateur prédéfini. Ce code(que j'ai trouver sur le net) marche très bien mais le seul souci c'est qu'il n'envoie pas directement le mail il me faut encore qu'il sur "envoyer" dans outlook.

Je veux donc:
-que mon code vb envoie directement le mail à son destinataire
-Mettre ce code dans macro que je pourrais exécuter depuis un batch (ou une commande MS-dos)


je bloque depuis quelques temps à ce niveau, je fais appel aux experts Excel.


Le code utilisé est le suivant:

Sub envoimail() 
'test sur agence d'Auxerre 
 
Workbooks.Open Filename:= _ 
"C:\Mes Documents\FD\PARIS.xls" 
 
Dim Outlook As Object 
Dim Mail As Object 
Dim Dest As String 
Dim Objet As String 
Dim Corps As String 
 
Dest = "papaye@moimeme.com" 'adresse du destinataire 
Objet = "Bilan général'" 
'Exemple de corps de texte avec texte et sauts de ligne 
Corps = "Bonjour, " & _ 
vbCrLf & vbCrLf & _ 
"Ci-joint le fichiers des appels du mois passé pour votre agence." & _ 
vbCrLf & vbCrLf & _ 
"Nous restons bien entendu à votre disposition pour tout renseignement complémentaire." & _ 
vbCrLf & vbCrLf & _ 
"Cordialement." & _ 
vbCrLf & vbCrLf 
 
 
Set Outlook = CreateObject("Outlook.Application" ) 
Set Mail = Outlook.CreateItem(0) 
 
With Mail 
.to = Dest 
.CC = "" 
.BCC = "" 
.Subject = Objet 
.Body = Corps 
.Attachments.Add ActiveWorkbook.FullName 
.Display 
ActiveWindow.Close 
End With 
End Sub

Merci d'avance pour votre aide

Kalmard

 

[joss56]

Re : Envoie automatique d'un mail avec PJ/batch

Bonjour

Pour l'envoi automatique, tu peux télécharger "ClickYes".
Pour le fichier batch, je ne sais pour MS-DOS mais avec VBSript, ça doit fonctionner.

Bonne journée
Jocelyn

 

[kalmard]

Re : Envoie automatique d'un mail avec PJ/batch

Salut, Jocelyn

Peux-tu m'en direun peu plus sur ce "ClickYes"?

Merci

Bonne journée.

 

[joss56]

Re : Envoie automatique d'un mail avec PJ/batch

C'est un petit logiciel qui permet d'envoyer des mails "en rafale" sans avoir à cliquer sur la confirmation d'Outlook à chaque message.
A la réflexion, en relisant ton post, je me dis qu'il suffirait peut-être de paramétrer Outlook pour que les messages ne transitent pas par la boîte d'envoi, tout simplement.

Reviens nous dire.
A+
Jocelyn

 

[kalmard]

Re : Envoie automatique d'un mail avec PJ/batch

Je viens de télécharger "Clickyes express" , tu peux me dire à quel niveau de mon code dois-je le mettre.

Parametrer Outlook en quoi faisant?

Merci.

 

[joss56]

Re : Envoie automatique d'un mail avec PJ/batch

D'après Microsoft:

"Dans le menu Outils, cliquez sur Options, puis sur l'onglet Messagerie. Activez la case à cocher Envoyer immédiatement une fois connecté de façon à ce que les messages soient envoyés dès que vous cliquez sur Envoyer."

Pour ClickYes : voir le fichier joint

A+
Jocelyn

 

[kalmard]

Re : Envoie automatique d'un mail avec PJ/batch

Merci jocelyn,

J'essaie tout ça et je te dis ce que ça donne.
A+

 

[kalmard]

Re : Envoie automatique d'un mail avec PJ/batch

Salut Joss56,

Ton code marche meilleusement bien,

j'ai juste modifier légèrement pour ajouter la pièce jointe.

En gros j'ai ceci:

Option Explicit
 Sub EmailWithClickYes()
'Author       : Ken Puls (www.excelguru.ca)
'Macro Purpose: To send an email through Outlook without worrying about
'               security prompts

    Dim objOL As Object
    Dim objMail As Object
    Dim objwShell As Object
    Dim strEmail As String
    
  
    'Set your email address here
    strEmail = "papaye@banane.com"

    'Turn on error handling
    On Error GoTo Cleanup

    'Activate ClickYes
    Set objwShell = CreateObject("wscript.shell")
    objwShell.Run ("""C:\Program Files\Express ClickYes\ClickYes.exe"" -activate")

    'Bind to Outlook
    Set objOL = CreateObject("Outlook.Application")

    'Create a new email and send it
    Set objMail = objOL.CreateItem(0)    '0=olmailitem
    With objMail
        .To = strEmail
        .Subject = "Testing ClickYes Routine"
        .Body = "This is a test of the ClickYes program"
        .Attachments.Add ActiveWorkbook.FullName
        .Send
    End With

    'Stop Clickyes
    objwShell.Run ("""C:\Program Files\Express ClickYes\ClickYes.exe"" -stop")

Cleanup:
    'Release all objects
    Set objMail = Nothing
    Set objOL = Nothing
    Set objwShell = Nothing
    On Error GoTo 0
End Sub

Grand merci à toi.

A bientôt

Kalmard

 

[joss56]

Re : Envoie automatique d'un mail avec PJ/batch

Salut Kalmard,

Rendons à César....ce fichier n'est pas de mon cru. Remercions son auteur. Je ne suis qu'un "passeur" d'informations sur ce coup-là!
Bonne journée,

Jocelyn