Effectuer une somme ciblée parmi plusieurs données

[caribou22]

Bonjour, qu'elle excellente trouvaille comme site!!!

Alors j'ai une question pour le moins simple, mais je suis incapable de déterminer la fonction appropriée.

Voici mon problème:

J'ai 14 données distribuées aléatoirement dans une colonne.

Parmi ces 14 données je souhaite connaître la somme des 8 plus élevées. Existe-t-il une fonction qui me permettrait d'effectuer ce calcul sans trier les données ?

Merci d'avance!

 

[ninbihan]

Re : Effectuer une somme ciblée parmi plusieurs données

Bonjour Caribou22

Si on considère ta plage de 14 valeurs en A1;A14 tu peux essayer ceci :

=GRANDE.VALEUR(A1:A14;1)+GRANDE.VALEUR(A1:A14;2)+GRANDE.VALEUR(A1:A14;3)+GRANDE.VALEUR(A1:A14;4)+GRANDE.VALEUR(A1:A14;5)+GRANDE.VALEUR(A1:A14;6)+GRANDE.VALEUR(A1:A14;7)+GRANDE.VALEUR(A1:A14;8)

ou cela:

=SOMMEPROD((A1:A14>GRANDE.VALEUR(A1:A14;8))*A1:A14)+(GRANDE.VALEUR(A1:A14;8)*(8-SOMMEPROD((A1:A14>GRANDE.VALEUR(A1:A14;8))*1)))

Bonne journée,

Ninbihan

 

[Tibo]

Re : Effectuer une somme ciblée parmi plusieurs données

Bonjour caribou22 et bienvenue, salut ninbihan ,

Une autre solution toujours avec SOMMEPROD :

=SOMMEPROD((A1:A14>=GRANDE.VALEUR(A1:A14;8))*A1:A14)

Attention en cas de présence de doublons.

@+

 

[caribou22]

Re : Effectuer une somme ciblée parmi plusieurs données

Merci des réponses! C'est très apprécié, je vais le tester ce soir.

Cependant, j'avais oublié de spécifier dans mon message que ma version est anglophone. Connaissez vous les termes anglais pour SOMMEPROD et GRANDE.VALEUR

Probablement GREAT VALUE pour le 2e et je vais tenter de trouver l'autre, mais je pose la question quand même au cas où. SUMPROD peut-être ?

Tibo: Quel peut être le problème avec les doublons, car effectivement, il m'arrive d'avoir des doublons dans mes colonnes de chiffres et le nombre qui arrive en 9e position, même s'il est égal au huitième, ne doit pas être calculé.

Merci!

 

[Tibo]

Re : Effectuer une somme ciblée parmi plusieurs données

Bonjour,

Les traductions :

SOMMEPROD = SUMPRODUCT

GRANDE.VALEUR = LARGE

Attention : normalement, il faut remplacer les ; par des ,

Je te laisse tester en cas de présence de doublons. Si pas de problème, on laisse comme ça, sinon, on trouvera une autre solution

@+

@+

 

[abcd]

Re : Effectuer une somme ciblée parmi plusieurs données

Bonjour,

A essayer :

=SOMME(GRANDE.VALEUR(A1:A14;{1;2;3;4;5;6;7;8}))

abcd

 

[caribou22]

Re : Effectuer une somme ciblée parmi plusieurs données

Alors j'ai testé toutes vos propositions.

Ces deux là ont fonctionné:

=GRANDE.VALEUR(A1:A14;1)+GRANDE.VALEUR(A1:A14;2)+GRANDE.VALEUR(A1:A14;3)+GRANDE.VALEUR(A1:A14;4)+GRANDE.VALEUR(A1:A14;5)+GRANDE.VALEUR(A1:A14;6)+GRANDE.VALEUR(A1:A14;7)+GRANDE.VALEUR(A1:A14;8)

et

=SOMME(GRANDE.VALEUR(A1:A14;{1;2;3;4;5;6;7;8}))

Celle-ci a donné une mauvaise réponse

=SOMMEPROD((A1:A14>=GRANDE.VALEUR(A1:A14;8))*A1:A14)

et celle-ci n'a pas donné de réponse:=SOMMEPROD((A1:A14>GRANDE.VALEUR(A1:A14;8))*A1:A14)+(GRANDE.VALEUR(A1:A14;8)*(8-SOMMEPROD((A1:A14>GRANDE.VALEUR(A1:A14;8))*1)))

Ceci dit, merci énormément, je vais gagner beaucoup de temps grâce à cette formule qui va m'éviter d'avoir à utiliser des macros.

 

[caribou22]

Re : Effectuer une somme ciblée parmi plusieurs données

------------------

 

[caribou22]

Re : Effectuer une somme ciblée parmi plusieurs données

-----------------