Donner une valeur à une cellule en fonction de sa couleur????

[memene]

Bonjour à tous,

Sur ma feuille, quand je double-clique sur une cellule, elle se colore en rouge.
Prenons mon exemple: si je double-clique sur B29, cette cellule devient rouge.
Je souhaiterai que le contenu (un nombre) de B29 se recopie alors automatiquement en G25 puisqu'elle est rouge.
Si je double-clique sur B32, B32 devient rouge, B29 redevient blanc et G25 prend alors la valeur de B32.
Si je double-clique sur E35, E352 devient rouge, B32 redevient blanc et G25 prend alors la valeur de E35.
Etc.
Je vous mets en PJ mon document. (Les données que je vous donne plus haut sont celles réelles de mon doc)
Merci pour vos réponses.

Autre question: le code VBA que j'ai entré pour rendre rouge la cellule double-cliquée s'applique à toutes les cellules de la feuille. Je voudrais que cela ne s'applique qu'aux cellules entre B29:H35. Merci encore.

Memene

 

[JNP]

Re : Donner une valeur à une cellule en fonction de sa couleur????

Bonsoir Memene ,
A tester

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Count > 1 Then Exit Sub
If Intersect(Range("B29:H35"), Target) Is Nothing Then Exit Sub
If numcel = 0 Then drapeau = False Else drapeau = True
If drapeau = True Then Range(ref_cel).Interior.ColorIndex = -4142
drapeau = True
Target.Interior.ColorIndex = 3
ref_cel = Target.Address
numcel = 1
Range("G25") = Target
Cancel = True
End Sub

Bon WE
Ajout : Une cigogne qui grille un neurone, c'est une première ... Salut Robert

 

[Robert]

Re : Donner une valeur à une cellule en fonction de sa couleur????

Bonjour Memene, bonjour le forum,

En pièce jointe ton fichier modifié avec le code ci-dessous :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim pl As Range 'déclare la variable pl (Plage)
 
Set pl = Range("B29:H35") 'définit la plage pl
'si le doucle-clic a lieu ailleurs que dans la plage pl, sort de la proocédure
If Application.Intersect(Target, pl) Is Nothing Then Exit Sub
Cancel = True 'annule le mode édition lié au double-clic
pl.Interior.ColorIndex = xlNone 'supprime la couleur danws toute la plge pl
Target.Interior.ColorIndex = 3 'colore la cellule double-cliquée en rouge
Range("G25").Value = Target.Value 'place la valeur de la cellule double-cliquée dans G25
End Sub

[Édition]
Grillé par une cigogne Arf... Salut Jnp

 

[memene]

Re : Donner une valeur à une cellule en fonction de sa couleur????

Super! Merci à vous 2

A+
Memene