XL 2013 Désélectionner suite tri vba

[zizan]

Bonjour,
D'une feuille nommée "donnée" je transfère les saisies vers un tableau en générant un tri sur une colonne.
Le problème est que la zone reste sélectionnée.
Je voudrais que se soit la dernière ligne vide et cela sur toutes les feuilles sauf la feuille "donnée"
voir fichier joint

Merci

 

[sylvanu]

Bonjour Zizan,
Une solution simple en sélectionnant la première cellule vide de la feuille concernée:

...
...
End With
Application.ScreenUpdating = False
Sheets(f.[B7].Value).Activate
Range("A" & Application.CountA(Range("A:A")) + 1).Select
Sheets("Donnée").Activate
...
...

 

[zizan]

Bonjour,

ça marche merci
Mais pour un néophyte, comme moi c'était pas si simple.

Cordialement

 

[job75]

Bonjour zizan, salut sylvanu,

J'ai fait un sérieux ménage dans votre fichier, son poids passe de 944 Ko à 53 Ko...

D'abord voyez ce code qui ne sélectionne rien du tout :

Sub Ajouter_trier()
Dim f As Worksheet
Set f = Sheets("Donnée")
On Error Resume Next 'si la feuille n'existe pas
With Sheets(f.[B7].Value)
    .Cells(Rows.Count, 1).End(xlUp)(2).Resize(, 7) = f.[A2:G2].Value
    With .[A1].CurrentRegion.Offset(2)
        With .Resize(.Rows.Count - 2)
            .Sort .Cells(1), xlAscending, Header:=xlNo
            .Columns(8) = "=IF(A3="""","""",N(H2)+G3-F3)" 'formule du cumul en colonne H
        End With
    End With
End With
f.[B7,B10,D10,B14,D14,F14,B18,D18] = Empty
End Sub

Il entre en même temps la formule de cumul en colonne H, ce qui est quand même mieux que de l'entrer sur plus de 30 000 lignes comme vous l'aviez fait !!!

Ensuite si vous tenez à sélectionner la 1ère cellule vide placez ce code dans ThisWorkbook :

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If Sh.Name <> "Donnée" Then Application.Goto Sh.[A:A].Find("", , xlValues)
End Sub

A+

 

[zizan]

Bonjour,

Fascinant, je n'en demandais pas tant.
pourriez vous m'expliquer step by step votre code.
J'ai créé ce fichier, comme un débutant en prenant des codes par ci par là des codes.
cela fonctionne, mais j'avoue c'est un lourd.

Merci

 

[job75]

pourriez vous m'expliquer step by step votre code.

J'ai mis des commentaires...

Etudiez le code ligne par ligne et dites ce que vous ne comprenez pas.

 

[zizan]

bonjour,

je viens d'essayer votre code.
il ne réponds pas à mes attentes.
lorsque je rentre une ligne avec une date quelconque, il doit la classer dans ce tableau.
chose qui ne fonctionne pas.

merci

 

[job75]

lorsque je rentre une ligne avec une date quelconque, il doit la classer dans ce tableau.
chose qui ne fonctionne pas.

Je comprends bien que vous débutez mais si vous ne savez même pas tester je ne peux rien faire.

Il ne faut pas oublier d'entrer le Compte en B7...

 

[job75]

Ah il y avait une coquille au post #4, le (2) dans End(xlUp)(2) avait été effacé.

J'ai corrigé la macro et le fichier.

 

[job75]

Dans le fichier du post #4 je viens de modifier aussi les MFC (mises en forme conditionnelles).

 

[job75]

Bonjour zizan, le forum,

Dans ce fichier (2) les tableaux sont sous forme de tableaux structurés (menu Insertion-Tableau).

Ils s'agrandissent automatiquement avec formule et MFC et le code est plus simple :

Sub Ajouter_trier()
Dim f As Worksheet
Set f = Sheets("Donnée")
On Error Resume Next 'si la feuille n'existe pas
With Sheets(f.[B7].Value)
    .Cells(Rows.Count, 1).End(xlUp)(2).Resize(, 7) = f.[A2:G2].Value
    With .ListObjects(1).Range 'tableau structuré
        .Sort .Cells(1), xlAscending, Header:=xlYes
        .Cells(2, 8) = "=IF(A3="""","""",N(H2)+G3-F3)" 'sécurité, formule en colonne H
    End With
End With
f.[B7,B10,D10,B14,D14,F14,B18,D18] = Empty
End Sub

A+