Dernière cellule pleine

[TICO]

Bonjour à tous,
Pouvez vou m'aider, je cherche une macro qui me permettrait de corriger les chiffres de la dernière cellule pleine de la dernière colonne. Ci joint un fichier avec plus d'information. Avec mes remerciements à chacun de vous pour votre talent et votre amabilité. A bientôt. TICO

 

[Robert]

Re : Dernière cellule pleine

Bonjour Tico, bonjour le forum,

Je te propose cette macro que tu devras affecter à ton bouton :

Sub Macro1()
Dim nv As String 'déclare la variable nv (Nouvelle Valeur)
Dim p As Range 'déclare la variable p (Plage)
Dim cel As Range 'déclare la variable cel (CELlule)
Dim col As Byte 'déclare la variable col (COLonne)
Dim PGcol As Byte 'déclare la variable PGcol (Plus Grande COLonne)
 
nv = InputBox("Tapez la nouvelle valeur à attribuer", "Nouvelle Valeur") 'définit la variable nv
Set p = Range("A3:A" & Range("A65536").End(xlUp).Row) 'définit la variable p
 
For Each cel In p 'boucle sur toutes les cellules de la plage p
    col = Cells(cel.Row, 256).End(xlToLeft).Column 'définit la variable col
    If col > PGcol Then PGcol = col 'si la variable col est supérieure à PGcol, redéfinit PGcol
Next cel 'prochaine cellule de la plage P
 
For Each cel In p.Offset(0, PGcol - 1) 'boucle sur toutes les cellules de la plage p décalée de (PGcol-1) colonnes
    If cel.Value <> "" Then cel.Value = CInt(nv) 'si la cellule n'est pas vide, elle prend la nouvelle valeur
Next cel 'prochaine cellule de la plage p décalée de (PGcol-1) colonnes
 
End Sub

 

[TICO]

Re : Dernière cellule pleine

Un grand remerciement Robert c'est justement la reponse sur mesure, cela marche sans pb, on ne saura jamais vous remercier assez de votre générosité et votre dévouement. A bientôt dans ce Forums TICO