Copier un fichier dans plusieurs répertoires

[asengs]

Bonjour,

je souhaiterais savoir si c'est possible à partir d'un macro excel de copier un fichier (modèle pdf) dans plusieurs répertoires?

J'ai un fichier pdf et 200 répertoires, et je souhaiterais avoir ce fichier pdf dans chacun des répertoires.

Merci

 

[Paritec]

Re : Copier un fichier dans plusieurs répertoires

bonjour asengs le forum
oui c'est possible de le copier mais il faut dresser la liste des répertoires et là c’est pas la même
tes répertoires sont à la racine de C ?
a+
papou

 

[asengs]

Re : Copier un fichier dans plusieurs répertoires

Non ils ne sont pas directement à la racine de C, ils sont sous un répertoire qui lui est à la racine de C...

Etant novice en vba, je ne sais pas du tout par où démarré

 

[JNP]

Re : Copier un fichier dans plusieurs répertoires

Bonjour le fil ,
A tester

Sub Test()
Dim Dossier As Object, Chemin As String, ACopier As String
Dim fd As FileDialog, fs As Object, f As Object
Set fd = Application.FileDialog(msoFileDialogFilePicker)
With fd
If .Show = -1 Then
If .SelectedItems.Count <> 1 Then Exit Sub
ACopier = .SelectedItems(1)
End If
End With
Set fd = Application.FileDialog(msoFileDialogFolderPicker)
With fd
If .Show = -1 Then
If .SelectedItems.Count <> 1 Then Exit Sub
Chemin = .SelectedItems(1)
End If
End With
Set fs = CreateObject("Scripting.FileSystemObject")
Set f = fs.getfolder(Chemin)
For Each Dossier In f.SubFolders
FileCopy ACopier, Dossier.Path & "\" & Split(ACopier, "\")(UBound(Split(ACopier, "\")))
Next
End Sub

Sélectionner d'abord le fichier à copier, puis le dossier qui contient les sous dossiers à remplir ...
Bon courage

 

[Paritec]

Re : Copier un fichier dans plusieurs répertoires

Bonjour Jean Noël Asengs
là c'est du grand Jean Noël et sans regex SVP!!!
amicalement
Papou

 

[JNP]

Re : Copier un fichier dans plusieurs répertoires

Salut Pascal ,

là c'est du grand Jean Noël et sans regex SVP!!!

Si tous les dossiers ont une forme reconnaissable par un masque, pourquoi pas faire une fonction récursive et un RegExp, si tu y tiens ...
Bonne soirée