convertisseur format heures..

[Richard]

bjr
je bute.
comment faire pour diviser un résultat sous forme de nombre d'heures (ex/ 450:56:34) par 2'.. de façon a obtenir un résultat en nombre de jours ET nombre d'heures ET nombre de mn etc.... C'est le principe du décompte horaire mais appliqué sur une tranche supérieure à 24 heures.
Je calcul l'espace temps entre 2 dates données et je veux afficher ce résultat en nombre d ejours etc...
Merci
RL

 

[Pascal76]

Bonjour

en A1 la date et l'heure de départ
en B1 la date et l'heure de fin

la formule

=(ENT(B1-A1)&" jours "&HEURE(MOD(B1-A1;1))&":"&MINUTE(MOD(B1-A1;1))&":"&SECONDE(MOD(B1-A1;1)))

Bon courage

Pascal

 

[Monique]

Bonjour,

Celle-ci gère les pluriels et l'absence soit de jours, soit d'heures, soit de minutes soit de secondes.
=SI(ENT(B1-A1)>0;ENT(B1-A1)&" jour"&SI(B1-A1>=2;"s ";" ");"")&SI(HEURE(B1-A1)>0;HEURE(B1-A1)&" heure"&SI(HEURE(B1-A1)>1;"s ";" ");"")&SI(MINUTE(B1-A1)>0;MINUTE(B1-A1)&" minute"&SI(MINUTE(B1-A1)>1;"s ";" ");"")&SI(SECONDE(B1-A1)>0;SECONDE(B1-A1)&" seconde"&SI(SECONDE(B1-A1)>1;"s";" ");"")

D'accord, on peut faire mieux, avec des virgules, un "et" avant le dernier nombre et un point à la fin.

 

[Pascal76]

Re

Ci-joint un exemple de fichier

Pascal

 

[Monique]

Re,

Pascal, on n'a pas besoin de la fonction MOD(fin-début;1)
Mod est utile quand l'heure de fin est < à l'heure de début, mais seulement si on n'a pas le jour
Travail de nuit de 22:00 à 6:00, 6 heures moins 22 heures, le compte n'y est pas et là, on utilise Mod()

On obtient le même résultat avec :
=ENT(B1-A1)&" jours "&HEURE(B1-A1)&":"&MINUTE(B1-A1)&":"&SECONDE(B1-A1)
ou bien :
=ENT(B1-A1)&" jours "&TEXTE(B1-A1;"hh:mm:ss")
Elle devient tellement courte qu'on peut se permettre de gérer le pluriel de "jour" :
=ENT(B1-A1)&" jour"&SI(B1-A1>1;"s ";" ")&TEXTE(B1-A1;"hh:mm:ss")
Et puis c'est encore court, alors on peut continuer...

 

[Pascal76]

bonjour Monique

Et oui maintenant que tu le dis, ça parait evident

Je suis parti de l'idée "je retire les jours pour traiter les heures minutes secondes" alors qu'en fait ce n'est pas nécessaire Excel sait que cela se trouve après la virgule

Merci pour le cours gratuit

Pascal

 

[Pascal76]

Bonjour Richard

Voici ton fichier modifié que tu m'as envoyé dans ma BAL. Il tient compte des remarques de Monique sur l'inutilité du MOD

Bonne journée

Pascal

 

[Pascal76]

Oups le fichier

Pascal

 

[Richard]

Merci pour le fichier (et les conseils)
La formule passe

Même si je ne suis pas encore expert dans la cratéion et la gestion des formules... j'aurais du m'apercevoir que les cellules étaient à renommer.

Bonne journée

RL