Convertir une liste de lettres en chiffre

[mychance]

Bonjour,

J'essais de convertir des cotes en lettre (A+, B, C-, etc.) en leur équivalence en notes chiffrées. Je me suis débrouillé avec la formule suivante qui fonctionne bien:

=SI(A2="A+";98;SI(A2="A";91;SI(A2="B+";84;SI(A2="B";77;SI(A2="C+";70;SI(A2="C";63;SI(A2="d";46;SI(A2="E";28))))))))

...sauf qu'il me faudrait inclure quelques autres équivalences pour compléter l'ensemble des cotes (A-, B-, C-, D+, etc.) et je suis limité à un maximum de 8 imbrications avec la fonction SI. Je ne peux pas non plus utiliser de macros puisque les feuilles Excel sont utilisée principalement sous Pocket PC qui ne gère que les fonctions formules.

Y a-t-il une solution ?

Merci d'avance !

 

[jeanpierre]

Re : Convertir une liste de lettres en chiffre

Bonsoir mychance et Bienvenue sur XLD,

Ta chance pourrait résider sur un petit dépôt de fichier exemple de ce que tu as et de ce que tu souhaites....

Fichier au Format ZIP, stp..... (simple) Si tu ne sais pas faire avec windows, tu demandes....

A te lire.

Jean-Pierre

 

[mychance]

Re : Convertir une liste de lettres en chiffre

J'ai finalement trouvé !!! Voici comment on fait :

=SI(A3="A+";100)+SI(A3="A";95)+SI(A3="A-";90)+SI(A3="B+";85)+SI(A3="B";80)+SI(A3="B-";75)+SI(A3="C+";70)+SI(A3="c";65)+SI(A3="C-";60)+SI(A3="D+";55)+SI(A3="D";50)+SI(A3="E";40)

Fallait que je le demande,,,

 

[zeb33]

Re : Convertir une liste de lettres en chiffre

Salut Mychance,

Tu peux aussi définir tes équivalences dans un tableau et faire une RECHECHEV ou H ca dépend de ton tableau.
Vois fichier joint

Zeb

 

[Tibo]

Re : Convertir une liste de lettres en chiffre

Bonjour,

Une dernière solution, très proche de celle de mychance, plus courte :

=(A3="A+")*100+(A3="A")*95+(A3="A-")*90+(A3="B+")*85+(A3="B")*80+(A3="B-")*75+
(A3="C+")*70+(A3="c")*65+(A3="C-")*60+(A3="D+")*55+(A3="D")*50+(A3="E")*40

Plus besoin du SI

Excel fait le calcul du test entre parenthèses, retourne VRAI ou FAUX (soit 1 ou 0) puis multiplie par le nombre indiqué.

Bon WE

@+

 

[mychance]

Re : Convertir une liste de lettres en chiffre

Merci pour la rapidité de vos réponses. Vous êtes vraiment sympa

 

[mychance]

Re : Convertir une liste de lettres en chiffre

Salut Mychance,

Tu peux aussi définir tes équivalences dans un tableau et faire une RECHECHEV ou H ca dépend de ton tableau.
Vois fichier joint

Zeb

Cette solution semble vraiment la plus simple. Juste pour éclaircir la formule pour que je puisse la réutiliser à d'autres fins à l'avenir:

=RECHERCHEV(A3;F2:G13;2;FAUX)

Je comprends que A3 correspond à la cible de la donnée variable
Je comprends aussi que F2:G13 correspondrait à la plage de données de référence.

Que signifierait alors le 2 et le FAUX ?

Merci encore d'éclairer la lanterne à un pauvre néophyte

 

[Tibo]

Re : Convertir une liste de lettres en chiffre

Bonjour,

Pour éclairer ta lanterne :

le 2 : indique à Excel qu'il faut rechercher dans la 2ème colonne de la plage de cellules F2:G13

le FAUX (qu'on peut remplacer par 0) : indique à Excel qu'il faut chercher la correspondance exacte. Si pas indiqué (ou VRAI à la place de FAUX), Excel va rechercher la valeur la plus proche)

Voilou

@+