convertir note en appréciation

[thor81]

Bonjour à tous,

J'ai fait un tableau qui consiste à calculer les moyennes de mes élèves et de les mettre en forme pour sortir directement le bulletin.

Je voudrais à présent convertir ces notes en appréciation du genre :

10<note<8 alors : "acquis" ; 8<note<5 : compétence à renforcer
5<note<0 : non acquis

Est ce que vous connaissez une formule capable de faire ça ?

Cordialement,

Sébastien

 

[Efgé]

Re : convertir note en appréciation

Bonjour thor81,
Une proposition, mais il y a peut être mieux...
Si votre note est en A1:

=SI(A1="";"";SI(A1>=8;"acquis";SI(ET(A1<8;A1>=6);"Compétence à renforcer";SI(A1<6;"Non acquis";""))))

Cordialement

 

[Dull]

Re : convertir note en appréciation

Salut thor81, le Forum

peut-être avec une formule du style

Note en A1, Appréciation en B1

=SI(OU(A1>10;A1="";A1<0);"";SI(ET(A1>=8;A1<=10);"Acquis";SI(ET(A1<8;A1>=5);"Compétence à renforcer";"Non Acquis")))

Fichier Joint avec en plus une Mise en Forme Conditionnelle

EDITION :Salut Fred0o

RE Edith: Mêmepasvul'amiFG
Bonne Journée

 

[Fred0o]

Re : convertir note en appréciation

Bonjour Thor,

Si ta note est dans la cellule C1 par exemple, tu peux utiliser cette formule :

=SI(C1>=8;"Acquis";SI(C1>=5;"Compétence à renforcer";"Non acquis"))

sinon, tu remplaces le C1 de la formule par l'adresse de la première cellule de ton tableau puis tu tires la formule vers le bas jusqu'à la fin de ton tableau.

A+

EDIT : Oups, bonjour Dull.

 

[ROGER2327]

Re : convertir note en appréciation

Bonjour à tous

Avec les conditions données, je ne vois pas l'intérêt du problème (10<note<8 ; 8<note<5 : 5<note<0 renvoyant toujours FAUX).
En supposant que la note soit en A1 et que les conditions soient 0<=note<5
5<=note<8
8<=note<=10 :

[COLOR="DarkSlateGray"][B]=SI(ESTNUM(A1);INDEX({"";"non acquis";"compétence à renforcer ";"acquis";""};EQUIV(A1;{-999999;0;5;8;10.000000001}));"")[/B][/COLOR]

ROGER2327
#4411

Mardi 24 Haha 138 (Saint Claude Terasse, musicien des Phynances, SQ)
8 Brumaire An CCXIX
2010-W43-5T08:27:25Z

 

[hoerwind]

Re : convertir note en appréciation

Bonjour, salut les autres,

Il y a aussi :
=CHOISIR(EQUIV(A1;{0;5;8});"Non acquis";"Compétence à renforcer";"Acquis")

 

[thor81]

Re : convertir note en appréciation

Merci à tous pour vos réponses je vais essayer tout ça !!!!

 

[thor81]

Re : convertir note en appréciation

J'aime bien ta formule hoerwind

=CHOISIR(EQUIV(A1;{0;5;8});"Non acquis";"Compétence à renforcer";"Acquis")

mais quand il n'y a pas de valeurs elle indique N/A y'at-il moyen de faire en sorte que lorqu'il n'y a pas de valeurs elle indique une case vierge ?

 

[Dull]

Re : convertir note en appréciation

Re le Fil

Sauf si Hoerwind s'est caché

Peut-être en ajoutant une condition

=[B]SI(A1="";"";[/B]CHOISIR(EQUIV(A1;{0;5;8});"Non acquis";"Compétence à renforcer";"Acquis"))

EDITION: Merci Roger de te pencher sur "LES Solutions" mais comme dit l'adage... les coups et les douleurs

Bonne Journée

 

[ROGER2327]

Re : convertir note en appréciation

Re...

Prenez la peine d'essayer les différentes formules proposées : je suis presque sûr qu'il y en a bien une ou deux qui font le boulot...​

ROGER2327
#4413

Mardi 24 Haha 138 (Saint Claude Terasse, musicien des Phynances, SQ)
8 Brumaire An CCXIX
2010-W43-5T12:13:42Z

 

[hoerwind]

Re : convertir note en appréciation

Bonjour,

Heureux que cela te plaise.

Chez moi, quand il n'y a pas de valeur en A1 la formule renvoie "Non acquis"

Par contre si A1 contient une formule qui renvoie "", alors j'obtiens aussi N/A
"" n'est pas égal à vide, Excel considère cette cellule comme contenant du texte, d'où message d'erreur.
Si c'est le cas, c'est que ma boule de cristal fonctionne encore bien.
Dès lors il te suffit d'ajouter une condition préliminaire :
=SI(A1="";"";la formule proposée)

Edition : salut Dull et Roger.

 

[Dull]

Re : convertir note en appréciation

Re le Fil

Un Fichier avec les divers solutions proposées

Bonne Journée

 

[Efgé]

Re : convertir note en appréciation

Re, Bonjour Roger, hoerwind,
Merci Dull de la récap.
Il semblerai que je sois le plus dur en notation : A 5 tous le monde met Compétence à renforcer alors que je reste à Non acquis .
Cordialement

 

[ROGER2327]

Re : convertir note en appréciation

Bonjour à tous

Mon classeur de travail.​

ROGER2327
#4414

Mardi 24 Haha 138 (Saint Claude Terasse, musicien des Phynances, SQ)
8 Brumaire An CCXIX
2010-W43-5T13:39:23Z

 

[thor81]

Re : convertir note en appréciation

Merci tout le monde super boulot. Comment faire si je veux rajouter une condition :

Non acquis / en cours d'acquisition / A CONSOLIDER / acquis ?

Merci d'avance