construction date + heure à partir de 2 cellules (non reconnu après formule)

[jojo2006]

bonjour à tous,



je dispose d'un fichier avec une colonne avec l'année le jour et le mois et une autre colonne avec l'heure. Pour reconstruire temporellement des graphiques, je souhaiterais reconstruire proprement au format date la date avec le jour le mois l'année heure minute seconde.



La longueur des caractères de l'heure peut varier (6-5-4-3).

exemple 135432 = 13h54min32sec



1913=0h19min13sec



J'ai essayé avec des formules concatener gauche droite mais le format au final (après avoir copié collé la valeur de la formule ) n'est pas reconnu au format date (même en forçant le format)


Pourriez vous s'il vous plaît jeter un oeil au fichier attaché ?



Merci d'avance pour votre aide



jojo

 

[vgendron]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

Hello

Une réponse dans ton fichier en retour

j'ai laissé les formules sur plusieurs colonnes pour que tu voies la construction
regarde également les formats personnalisés affectés.

 

[Hieu]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

Salut,

Le résultat d'une concaténation est un texte. Or, une date est un nombre.
Pour forcer le nombre, tu multiplies par 1 et ça marche !

En exemple.

Je n'ai pas vérifié ta formule, j'ai vu qu'il y a des erreurs.

++
Hieu

 

[JHA]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

Bonjour à tous,

A essayer en "B2"

=CONCATENER(GAUCHE(A2;4);"-";DROITE(GAUCHE(A2;6);2);"-";DROITE(A2;2);" ";SI(NBCAR(B2)=6;CONCATENER(GAUCHE(B2;2);":";STXT(B2;3;2);":";DROITE(B2;2));SI(NBCAR(B2)=5;CONCATENER("0";GAUCHE(B2;1);":";STXT(B2;2;2);":";DROITE(B2;2));SI(NBCAR(B2)=4;CONCATENER("00:";GAUCHE(B2;2);":";DROITE(B2;2))))))*1

Format personnalisé: aaaa/mm/jj hh:mm:ss

JHA

 

[ROGER2327]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

Bonjour à tous.

Allégeons :​

=DATE(GAUCHE(A2;4);STXT(A2;5;2);DROITE(A2;2))
+((DROITE(B2;2)/60+GAUCHE(DROITE("0000"&B2;4);2))/60+GAUCHE(DROITE("000000"&B2;6);2))/24

Bonne journée.


ℝOGER2327
#8255

Samedi 21 Palotin 143 (Occultation de Sa Magnificence le Dr Sandomir - fête Suprême Quarte)
21 Floréal An CCXXIV, 5,7449h - staticé
2016-W19-2T13:47:16Z

 

[JHA]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

Bonjour à tous,
Bonjour Roger2327

Pas mal l'astuce "DROITE("000000"&B2;6)" pour avoir toujours le même nombre de caractères.

JHA

 

[Modeste geedee]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

Bonsour®

=(1*TEXTE(A2;"0000\/00\/00"))+(1*TEXTE(B2;"00"":""00"":""00"))

format de cellule :
jj mmmm aaaa hh:mm:ss


ou bien tout autre format de date heure valide

 

[ROGER2327]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

(...)

=(1*TEXTE(A2;"0000\/00\/00"))+(1*TEXTE(B2;"00"":""00"":""00"))

format de cellule :
jj mmmm aaaa hh:mm:ss


ou bien tout autre format de date heure valide
Regarde la pièce jointe 363763

Joli !

Allégeons :​

=TEXTE(A2;"0000\/00\/00")+TEXTE(B2;"00"":""00"":""00")

Bonne nuit.


ℝOGER2327
#8256

Samedi 21 Palotin 143 (Occultation de Sa Magnificence le Dr Sandomir - fête Suprême Quarte)
21 Floréal An CCXXIV, 8,9826h - staticé
2016-W19-2T21:33:30Z

 

[jojo2006]

Re : construction date + heure à partir de 2 cellules (non reconnu après formule)

Bonjour,

je tiens à vous remercier tous pour vos propositions et vos commentaires.
Cela m'a permis de faire ce que je voulais faire.

Un grand Merci à tous !!!!