Microsoft 365 Condition SI avec plusieurs conditions

[looky62]

Hello la team

Qui peut m'aider sur ma condition SI , j'étais partie la dessus mais ça ne marche pas

=SI(ET(B2=76;50;61;27;14);"Normandie";SI(ET(B2=59;62);"NPDC";SI(P7=80;02;60;"PICARDIE")))

=SI.CONDITIONS(b3=76;b3=50;b3=27;"NORMANDIE";b3=59;b3=62;"NPDC";b3=60;b3=80;b3=02;"PICARDIE")

=SIERREUR(CHOISIR(EQUIV(B3;{50;27;14;61});"NORMANDIE";"")

 

[Hasco]

Bonjour,

Dans la première formule :

ET(B2=76;50;61;27;14)

B2 ne peut pas être égale à la fois à 76 et 50 et 61 et 27 et 14 !
Donc la condition est OU et devrait être écrite comme ceci :

OU(B2=76;B2=50;B2=61;B2=27;B2=14)

Autre possibilité

ESTNUM(Equiv(B2;{76;50;61;27;14};0))

Equiv va renvoyer soit #NA! si B2 n'est pas dans la liste soit l'index de position où il l'a trouvé.
ESTNUM dira si le resultat de Equiv est un numérique (c'est ok) soir autre chose (erreur)

Avec choisir il vous faudrait un tableau d'autant de "NORMANDIE" qu'il y a de valeurs dans le tableau {...}

CHOISIR(EQUIV(B3;{50;27;14;61});"NORMANDIE"

Doit s'écrire :

CHOISIR(EQUIV(B3;{50;27;14;61};0);"NORMANDIE";"NORMANDIE";"NORMANDIE";"NORMANDIE")

 

[fanfan38]

Bonjour

=SIERREUR(SI.CONDITIONS(OU(B3=59;B3=62);"NPDC";OU(B3=76;B3=50;B3=61;B3=37;B3=14);"Normandie";OU(B3=60;B3=80;B3=2);"Picardie");"")

A+ François

 

[mutzik]

bonjour
je ne comprends pas ce que tu veux dire avec
ET(B2=76;50;61;27;14)

 

[Orson83]

Bonjour looky62,
Peux-tu envoyer un fichier Excel en exemple ?

 

[looky62]

Merci J'ai pris la réponse de FANFAN38
=SIERREUR(SI.CONDITIONS(OU(B2=59;B2=62);"NPDC";OU(B2=76;B2=50;B2=61;B2=37;B2=14;B2=27);"Normandie";OU(B2=60;B2=80;B2=2);"Picardie");"")


En ma colonne B sont des départements! et je dois les classer en secteur Normandie Nord pas de calais, Picardie,

Si vous avez une autre formule moins longue je suis preneuse!

Le CHOISIR(EQUIV avec 3 régions c possible de combiner?

 

[Hasco]

Re

Ou comment ne rien apprendre !

 

[looky62]

Re

Ou comment ne rien apprendre !

Ben si j'ai compris mon erreur!! et je l'ai conservé afin de pouvoir le dupliquer sur d'autres cas similaires!

Je demandais avec Choisir Equiv, avec plusieurs choix comment le combiné, dsl je suis novice!!!

 

[Hasco]

e demandais avec Choisir Equiv, avec plusieurs choix comment le combiné,

Il faudrait qu'une cellule de test. Hors dans vos exemples du post 1 vous testez B2 et ensuite P7

Avec B2 uniquement Pour NORMANDIE et NPDC:

CHOISIR(EQUIV(B2;{50;27;14;61;59;62};0);"NORMANDIE";"NORMANDIE";"NORMANDIE";"NORMANDIE";"NPDC";"NPDC")

CHOISIR (CHOISIR, fonction) - Support Microsoft

Cet article décrit la syntaxe de formule et l’utilisation de la fonction CHOOSE qui utilise index_num pour retourner une valeur à partir de la liste des arguments de valeur. Utilisez la fonction CHOISIR pour sélectionner l’une des 254 valeurs possibles à partir du rang donné par l’argument no_index.

support.microsoft.com

Mais suivant le cas, que nous n'avons toujours pas, une table d'équivalences et les fonctions Index/Equiv ou Filtre ou.... tant d'autres possibilités qui ne pourraient être exposées qu'avec un cas concret.

 

[sylvanu]

Bonjour Looky, Hasco, Fanfan, Mutzik, Orson,
Un ex en PJ plus global avec une liste N° dpts, dpts, régions.
La recherche est simple :

=RECHERCHEV($C$6;Dpts!$A:$D;4)

 

[looky62]

Il faudrait qu'une cellule de test. Hors dans vos exemples du post 1 vous testez B2 et ensuite P7

Avec B2 uniquement Pour NORMANDIE et NPDC:




Mais suivant le cas, que nous n'avons toujours pas, une table d'équivalences et les fonctions Index/Equiv ou Filtre ou.... tant d'autres possibilités qui ne pourrait être exposées qu'avec un cas concret.

Merci , j'ai utilisé celle ci =CHOISIR(EQUIV(B2;{50;27;14;61;76;59;62;80;2;60};0);"NORMANDIE";"NORMANDIE";"NORMANDIE";"NORMANDIE";"NORMANDIE";"NPDC";"NPDC";"PICARDIE";"PICARDIE";"PICARDIE")

 

[looky62]

Bonjour Looky, Hasco, Fanfan, Mutzik, Orson,
Un ex en PJ plus global avec une liste N° dpts, dpts, régions.
La recherche est simple :

=RECHERCHEV($C$6;Dpts!$A:$D;4)

Merci @tous

 

[Hasco]

Re,

Merci du retour.

 

[Dranreb]

Bonsoir.
Il y aurait eu ça, éventuellement :

=CHOISIR(EQUIV(EQUIV(B2;{50;27;14;61;76;59;62;80;2;60};0);{1;6;8};1);"NORMANDIE";"NPDC";"PICARDIE")

 

[looky62]

Bonsoir.
Il y aurait eu ça, éventuellement :

=CHOISIR(EQUIV(EQUIV(B2;{50;27;14;61;76;59;62;80;2;60};0);{1;6;8};1);"NORMANDIE";"NPDC";"PICARDIE")

Oh oui effectivement plus court ! Merci