condition entre telle et telle date

[stephi]

bonjour

certainement un truc bête

j ai une cellule date par ex: 15/02/2010

je voudrais dire: si la date est comprise entre le 1 janvier et le 30 juin, alors ...mettre dans la cellule a5, 100 sinon 200

comment écrire cette condition?

je connais les conditions habituelles mais la sur les dates, ça bloque et je n'ai pas la bonne réponse.

quelqu un aurait il une idée. ce serait sympa

merci stephi

 

[jeanpierre]

Re : condition entre telle et telle date

Bonjour stephi,

=SI(A1="";"";SI(ET(A1>="01/01/2010"*1;A1<="30/06/2010"*1);100;200))

Bonne soirée.

Jean-Pierre

 

[stephi]

Re : condition entre telle et telle date

salut Jean pierre.

impec, il me manquait en fait les "" entre les dates.

petite question subsidiaire:

si je ne veux pas préciser dans ma formule l'année c est a dire c est toujours 100 si je suis entre le 1 janvier x et le 30 juin y quelque soit l année que je rentre en A1 car ça m'oblige à modifier ma formule chaque année sinon?

si c est pas trop abuser de toi

mercie

stephi

 

[Tibo]

Re : condition entre telle et telle date

Bonsoir,

Dans ce cas, essaye avec :

=SI(A1="";"";SI(ET(A1>=DATE(ANNEE(A1);1;1);A1<=DATE(ANNEE(A1);6;30));100;200))

@+

 

[stephi]

Re : condition entre telle et telle date

salut Tibo

ça marche

6 je pense pour juin et 30 le jour donc si je voulais dire avant le 15 mai, ce serait 5;15.

et si c 'était du 10 février au 15 mai. comment dire 10 février?

voila si t'as le temps car tu mas bien aidé

stéphi

 

[Tibo]

Re : condition entre telle et telle date

re,

La fonction DATE s'utilise ainsi :

=DATE(Année;Mois;Jour)

Donc, le 10 février, ça donne :

=DATE(ANNEE(A1);2;10)

Voilou

@+

 

[Tibo]

Re : condition entre telle et telle date

re,

Pour en revenir au test proposé un peu plus haut, s'il s'agit de tester du 1er jour d'un mois au dernier jour d'un mois, on peut alors limiter le test sur les mois, ce qui donne pour la période du 1er janvier au 30 juin :

=SI(A1="";"";SI(ET(MOIS(A1)>=1;MOIS(A1)<=6);100;200))

voire même, pour le cas de janvier (1er mois) :

=SI(A1="";"";SI(MOIS(A1)<7;100;200))

@+

 

[stephi]

Re : condition entre telle et telle date

génial

merci Tibo et jean pierre.

bon wek end

stephi

 

[stephi]

Re : condition entre telle et telle date

re
Une question à Jean Pierre.

ta formule est ok mais je pige pas à quoi sert le *1 ?

peux tu m'éclairer?

merci

stephi

 

[jeanpierre]

Re : condition entre telle et telle date

Bonjour stephi, Tibo,

Simplement parce que, dans la formule, j'ai traité les dates en "dur", mais en texte et que l'on ne peut pas comparer des valeurs en texte avec des valeurs numériques. Le *1 les rend numériques et, donc, par suite comparables à la valeur de A1.

Bonne journée.

Jean-Pierre