Compter les données mutiples de 60000

[cibleo]

Bonsoir le forum,

N'ayant pas trouvé de solutions dans mes recherches sur le forum, je fais une nouvelle fois appel aux formulistes.

Plutôt qu'un long discours, tout est expliqué dans la Feuil1 du fichier joint.

En C28, j'aimerais compter le nombre de valeurs qui sont multiples de 60000 dans la plage(C3:C26) soit 2 dans l'exemple cité.

J'espère que ma demande n'est pas si ridicule que çà , à première vue çà a l'air simple mais je n'y arrive pas.

En C29, j'ai bien trouvé une formule mais elle ne fait appel qu'à une cellule (C4), j'aimerais faire appel à toute la plage.

Merci de votre aide Cibleo

 

[Monique]

Re : Compter les données mutiples de 60000

Bonjour,

Fais un essai comme ça :

=SOMME(SI(ESTNUM(C3:C26);(MOD(C3:C26;60000)=0)*($B3:$B26="kms")))

Formule matricielle, à valider par ctrl, maj et entrée

 

[cibleo]

Re : Compter les données mutiples de 60000

Bonjour Monique et merci,

Ta formule fonctionne parfaitement, mais elle fait appel à la colonne B qui n'existe pas dans mon fichier initial.

J'avais placé la donnée "Kms" en B4, B12 et B20 seulement pour présenter mon problème .

Peux-tu remplacer ce critère dans ta formule afin d'obtenir le même résultat.

Cibleo

 

[chris]

Re : Compter les données mutiples de 60000

Bonjour

Si la colonne ne contient que des dates, kms et textes
=SOMME(SI(ESTNUM(C3:C26);(MOD(C3:C26;60000)=0)*1)) (toujours en matriciel)
devrait fonctionner, les dates étant en format nombre inférieures à 60000

 

[job75]

Re : Compter les données mutiples de 60000

Bonjour à tous,

Essayer en C28 :

=NB(1/(MOD(C3:C26;60000)=0))-NB.VIDE(C3:C26)-NB.SI(C3:C26;0)

ou mieux :

=NB(1/(MOD(C3:C26;60000)=0)/C3:C26)

Formules matricielles à valider par Ctrl+Maj+Entrée

A+

 

[Monique]

Re : Compter les données mutiples de 60000

Re,

Pour éliminer les 0 (en colonne G ou bien c’est une erreur ?)
=SOMME(SI(ESTNUM(C3:C26);(MOD(C3:C26;60000)=0)*(C3:C26>=60000)))

60000 = 08/04/2064, tu as de la marge

 

[cibleo]

Re : Compter les données mutiples de 60000

Bonjour chris et merci,

Bien vu, tu as contourné le problème.

Puisque tu dis :

les dates étant en format nombre inférieures à 60000

Heureusement que je n'ai pas choisi la valeur 40000 qui correspond au Lundi 06 juillet 2009, valeur qui pourrait éventuellement apparaître dans mon tableau en 2009.

Quant à 60000, cela correspond au mardi 08 avril 2064 donc pas de risque que cela soit aussi compté, sauf à allonger l'âge de départ en retraite

Encore merci et bonne soirée à tous.

Ps : Oui Monique, pour les zéros, c'était volontaire. Mais dans mon tableau initial, ils apparaissent, vois la formule (avec les index et Equiv) que j'ai mis dans le fichier attaché, elle génère ces fameux zéros.

Je sais que l'on peut les supprimer mais pas eu le temps d'analyser la chose.

Rends réponse un peu plus tard à toi Monique et à job75 pour vos nouvelles propositions.

A+ Cibleo

 

[cibleo]

Re : Compter les données mutiples de 60000

Re à tous,

Impeccable job75 pour le :

=NB(1/(MOD(C3:C26;60000)=0)/C3:C26)

Pour le fun, je lance un petit défi aux formulistes : je choisis la donnée 40000 et la date du lundi 06 juillet 2009 (soit 40000) apparait dans la plage (C3:C26) de mon tableau

Comment ignorer alors cette valeur ?

Cibleo

 

[cibleo]

Re : Compter les données mutiples de 60000

Re et re à tous,

Effectivement Monique, ta formule rectifie celle de chris qui comptait aussi les zéros, j'avais mal perçu ta nouvelle intervention .

Comme ça c'est tout bon, reçu 5 sur 5.

=SOMME(SI(ESTNUM(C3:C26);(MOD(C3:C26;60000)=0)*(C3 :C26>=60000)))

Amicalement Cibleo

 

[Monique]

Re : Compter les données mutiples de 60000

Re,

à essayer :

=SOMME(SI(ESTNUM(G$3:G$26);(MOD(G$3:G$26;40000)=0)*(G$3:G$26>=40000)*(MOD(LIGNE(G$3:G$26);8)=4)))

A condition que tous les petits tableaux soient identiques…

 

[cibleo]

Re : Compter les données mutiples de 60000

Bonsoir à tous,
Bonsoir chris, job75 et Monique,

Un petit retour sur le fil pour vous signaler que j'avais omis de vous préciser que mes plages pouvaient contenir des valeurs d'erreur (#N/A).
Je viens à l'instant de m'en apercevoir après test sur mon fichier original

Tout ça pour vous dire que la formule matricielle de job75, me renvoie #N/A.

=NB(1/(MOD(C3:C26;60000)=0)/C3:C26)

Par contre la formule de Monique me renvoie la bonne valeur.

=SOMME(SI(ESTNUM(C3:C26);(MOD(C3:C26;60000)=0)*(C3 :C26>=60000)))

D'autre part, j'ai testé ta dernière formule Monique, cela fonctionne mais seulement avec des plages identiques comme tu le précises bien.

C'était pour le fun, rien d'important

Bonne soirée à tous et encore merci.

Cibleo

 

[job75]

Re : Compter les données mutiples de 60000

Bonsoir cibleo,

Tout ça pour vous dire que la formule matricielle de job75, me renvoie #N/A.

Là je suis très surpris. Comment la fonction NB() peut elle renvoyer #N/A ? Elle étudie la matrice et compte les valeurs qui sont des nombres, elle renvoie donc a priori un nombre...

A+

Edit : dans votre tableau, j'ai mis des #N/A. La formule renvoie toujours des nombres. Peut-être avez-vous mal recopié la formule ?

 

[cibleo]

Re : Compter les données mutiples de 60000

Bonsoir le forum,
Bonsoir job75,

Autant pour moi, c'est tout bon, job75.

Une petite question comme ça.

J'ai voulu recopier ta formule matricielle par le Menu > Edition > Remplissage > A droite et j'ai obtenu le message suivant :Impossible de modifier une partie de la matrice.
Je n'arrivais plus à sortir d'Excel et j'ai cru que j'allais finir par planter mon fichier

Finalement, j'y suis arrivé mais à quoi correspond ce message, jamais vu auparavant.

Merci du renseignement,

Cibleo

 

[job75]

Re : Compter les données mutiples de 60000

Re Cibleo

Quand on valide une formule matricielle pour l'entrer en bloc dans toutes les cellules d'une plage, les cellules sont liées (par la formule) et on ne peut plus les effacer une par une (d'où le message).

Il faut alors resélectionner toute la plage pour pouvoir effacer les formules.

A+