compter le nombre d'opérations / mois

[nickcold]

Bonjour je dispose d'un tableur où je renseigne toutes mes opérations journalières
j'inscrit la date de chaque opération dans une colonne

je souhaite compter le nombre d'opération que j'effectue chaque mois

je pense commencer par une formule logique SI mais je ne trouve pas la suite...


pour février par exemple

si(selection de cellules contient "/02/2008"; compter le nombre de cellule; "")

merci d'avance

 

[fanfan38]

Re : compter le nombre d'opérations / mois

Bonjour
=SOMMEPROD((MOIS($A$1:$A$18)=2)*1) pour le mois de fevrier...

A+ François

 

[Monique]

Re : compter le nombre d'opérations / mois

Bonjour,

Un petit truc à ajouter à cause du mois de janvier :
=SOMMEPROD((MOIS($A$1:$A$18)=1)*ESTNUM($A$1:$A$18))

ou bien :
=SOMMEPROD((MOIS($A$1:$A$18)=1)*($A$1:$A$18<>""))

Une cellule vide est considérée comme contenant 0 donc le 00 janvier 1900 donc janvier...

 

[nickcold]

Re : compter le nombre d'opérations / mois

Bonjour
=SOMMEPROD((MOIS($A$1:$A$18)=2)*1) pour le mois de fevrier...

A+ François

merci bcp ca fonctionne nickel

mais c'est lourd en calcul... car j'ajoute plusieurs paramètres

 

[nickcold]

Re : compter le nombre d'opérations / mois

Bonjour, j'ai la formule suivante mais je ne trouve pas la fin....
lorsque D..=param1
et J..=1
et F..=param2
et G..<> de rien "" (ce sont des valeurs en € dans ces cases)


=SUMPRODUCT((('[fichier.xls]onglet'!$D$2:$D$1000)="param1")*1;(('[fichier.xls]onglet'!$J$2:$J$1000)=1)*1;(('[fichier.xls]onglet'!$F$2:$F$1000)="param2")*1;(('[fichier.xls]onglet'!$G$2:$G$1000)<>"")*...............


je souhaite obtenir la somme des cases G
merci d'avance

 

[Jocelyn]

Re : compter le nombre d'opérations / mois

Bonjour le forum,
Bonjour nickcold, fanfan38, Monique,

A tester :

=SUMPRODUCT(('[fichier.xls]onglet'!$D$2:$D$1000="param1")*('[fichier.xls]onglet'!$F$2:$F$1000="param2")*('[fichier.xls]onglet'!$G$2:$G$1000<>"param3")*plage GG à sommer)

Tu peux mettre jusqu'a 30 criteres

Jocelyn

 

[nickcold]

Re : compter le nombre d'opérations / mois

Bonjour le forum,
Bonjour nickcold, fanfan38, Monique,

A tester :

=SUMPRODUCT(('[fichier.xls]onglet'!$D$2:$D$1000="param1")*('[fichier.xls]onglet'!$F$2:$F$1000="param2")*('[fichier.xls]onglet'!$G$2:$G$1000<>"param3")*plage GG à sommer)

Tu peux mettre jusqu'a 30 criteres

Jocelyn

non ca ne fonctionne pas et qu'est-ce que le param3 ?? car moi c'est "" que je mets..

 

[Jocelyn]

Re : compter le nombre d'opérations / mois

re,

Par parametre il faut comprendre les critères en gros quand tu as plusieurs critére avant de faire une somme la fonction s'écrit de cette façon

=SOMMEPROD((critère1)*(critère2)*(critère3)*plage a sommer)

par exemple

=SOMMEPROD((A1:A20="oui")*(B1:B20="")*(C1:C20=7)*G1:G20)

Voila j'espère que c'est plus clair

Jocelyn

 

[nickcold]

Re : compter le nombre d'opérations / mois

re,

Par parametre il faut comprendre les critères en gros quand tu as plusieurs critére avant de faire une somme la fonction s'écrit de cette façon

=SOMMEPROD((critère1)*(critère2)*(critère3)*plage a sommer)

par exemple

=SOMMEPROD((A1:A20="oui")*(B1:B20="")*(C1:C20=7)*G1:G20)

Voila j'espère que c'est plus clair

Jocelyn

Oui c'est clair mais si je * par la plage à sommer je somme des nombre et cette somme je la multiplie…
ce qui me fait un nombre conséquent…

alors que j'ai besoin de récuperer uniquement la somme de chaque critère filtré et pas une multiplication par la somme des critères filtrés


=SOMMEPROD((critère1)*(critère2)*(critère3))

là tous mes critères sont filtrés et j'ai besoin de les sommer par leur critère (ce sont valeurs €) en colonne G



j'espere être clair

 

[Jocelyn]

Re : compter le nombre d'opérations / mois

re,

Bon je ne te comprend pas soit tu ne me comprend pas alors voila une exemple simple qui montre que l'écriture

=SOMMEPROD((critère1)*(critère2)*(critère3)*plage a sommer)

Fait bien la somme de la dernière plage et pas une multiplication

en gros excel colle 1 a tourtes les lignes qui correspondent au 3 critère et additionne ensuite les lignes en les multipliant par 1

Si jamais ce n'est pas ca dis exactement ce qui ne va pas

Jocelyn

 

[Monique]

Re : compter le nombre d'opérations / mois

Bonjour,

Comme ça c’est plus fiable
=SOMMEPROD((A2:A25=F2)*(B2:B25=G2)*(C2:C25=H2);D2 : D25)

 

[nickcold]

Re : compter le nombre d'opérations / mois

Bonjour,

Comme ça c’est plus fiable
=SOMMEPROD((A2:A25=F2)*(B2:B25=G2)*(C2:C25=H2);D2 : D25)

ok merci cela fonctionne parfaitement
en fait je sommais D225 par la fonction SOMME .... d'où le problème !
bonne journée

 

[nickcold]

Re : compter le nombre d'opérations / mois

bonjour,

je dispose d'une colonne où sont inscrits différents article
des fois 1 seul article (ex : B216) est inscrit dans la case ou alors une série d'article (B216 B217 B218) est inscrite..
seul, un ESPACE sépare les articles dans la série d'article

je souhaite retrouver la fréquence d'utilisation de ces articles, par exemple pour l'article 216

=SUMPRODUCT(((CA!$G$4:$G$10078)="B216")*1)

mais cela me compte uniquement l'article inscrit 1 seule fois
lorsque l'article fait partie d'uné série, il n'est pas compté...

comment procéder ?
merci

 

[Jocelyn]

Re : compter le nombre d'opérations / mois

Bonjour,

a tester

=sommeprod((estnum(trouve("B216";CA!$G$4:$G$10078)))*1)

Jocelyn

 

[nickcold]

Re : compter le nombre d'opérations / mois

good !
merci beaucoup