Comptabilisé dans un label le nombre de cellule inférieur à 10

[SSIAP2]

Bonjour à tous je cherche une solution pour comptabilisé le nombre de label inférieur à 10 plus plusieur feuil.

j'ai donc un classeur ou ma base de donnée est étendu sur plusieur feuil commencant tous par SAS SAS1 SAS2 SAS3.....

dans la colonne G de chaque Feuil Apparais des valeur 3 ;10 ,20 ....

je cherche une macro qui recherche dans cette colonne à partir de G3 et comptabilise combien de fois il trouvent des valeur inférieure à 10 et me l'afficherais dans un label


es ce posible svp merci

autrement si c'est plus simple j'ai également une listview qui reprend ses mêmes cellule
l'item correspondant à la colonne G est 7

je reste a votre disposition pour des question éventuel.

merci d'avance de votre aide précieuse.

 

[phlaurent55]

Re : Comptabilisé dans un label le nombre de cellule inférieur à 10

Bonjour ssiap2,

pourrais-tu joindre un fichier avec explications un peu plus claires et précises pour nous aider à la compréhension de ton problème

à+
Philippe

 

[Robert]

Re : Comptabilisé dans un label le nombre de cellule inférieur à 10

Boujour SSIAP, Philippe, bonjour le forum,

Philippe a raison ça aurait été plus facile avec un fichier en pièce jointe... Je te propose la macro ci-dessous :

Sub Macro1()
Dim ong As Worksheet 'déclare la variable ong (ONGlet)
Dim nb As Integer 'déclare la variable nb (NomBre)
Dim cel As Range 'déclare la variable cel (CELlule)
 
nb = 0 'initialise le nombre nb
For Each ong In Sheets 'boucle 1 : sur tous les onglets du classeur
    If Left(ong.Name, 3) = "SAS" Then 'condition 1 : si les 3 premièrs caractères de l'onglet sont "SAS"
        With ong 'prend en compte l'onglet
            'boucle 2 : sur toutes les cellules éditées cel de la colonne G (en partant de la troisième)
            For Each cel In .Range("G3:G" & .Cells(Application.Rows.Count, 7).End(xlUp).Row)
                'si la valeur de la cellule est inférieure à 10, incrémente le nombre nb
                If cel.Value < 10 Then nb = nb + 1
            Next cel 'prochaine cellule de la boucle 2
        End With 'fin de la prise en compte de l'onglet
    End If 'fin de la condition 1
Next ong 'prochain onglet de la boucle 1
 
UserForm1.Label.Caption = nb 'affiche le nombre nb dans le label 'à adapter à ton cas...
End Sub

 

[SSIAP2]

Re : Comptabilisé dans un label le nombre de cellule inférieur à 10

Bonjour phlaurent et robert

Phlaurent tu as raison pour la PJ il est vrais que je le fais systématiquement mais je pensais etre clair et détailler désolé.

en revanche robert semble t'il m'avoir compris et ma proposé une solution complete et qui fonctionne parfaitement résoluant donc mon probléme merci à toi robert et Phlaurent à trés bientot
bon week end
SSIAP2