Comparaison de 2 BD

[ivan27]

Bonjour à tous,

J'ai un problème de comparaison de BD à résoudre.

Dans le classeur joint si :

- La colonne A de la feuil1 est identique à la colonne B de la Feuil2
et
- La colonne N de la feuil1 est identique à la colonne C de la Feuil2

Alors on colorie les lignes correspondantes sur chaque feuille.

Merci d'avance pour vos propositions et bonne journée.

Ivan

 

[mplomion]

Re : Comparaison de 2 BD

Voila j'ai ce que tu attends je pense, j'ai juste ajouté 2 colonnes au bout de chaque feuille et une mise en forme conditionnelle. Si tu ne veux pas des ces colonnes je peux faire mieux mais à priori tu as le résultat attendu... Oups laisse moi un mail en MP car je n'arrive pas à mettre le fichier par le portail web.

 

[job75]

Re : Comparaison de 2 BD

Bonjour ivan27, mplomion,

1) Définir les noms :

- Tableau1 =DECALER(Feuil1!$A$1;;;EQUIV(9^9;Feuil1!$N:$N);16)

- Tableau2 =DECALER(Feuil2!$A$1;;;EQUIV(9^9;Feuil2!$C:$C);3)

- matrice1 =INDEX(Tableau1;;1)&INDEX(Tableau1;;14)

- matrice2 =INDEX(Tableau2;;2)&INDEX(Tableau2;;3)

2) MFC sur Feuil1!A =SOMMEPROD(-($A1&$N1=matrice2))

3) MFC sur Feuil2!A:C =SOMMEPROD(-($B1&$C1=matrice1))

Fichier joint.

A+

 

[mplomion]

Re : Comparaison de 2 BD

Pour ma part c'était un simple concatener puis un nb.si qui marchait aussi avec mise en forme conditionnelle dans la foulee. Je le poste ce midi le fichier ...

 

[job75]

Re : Comparaison de 2 BD

Re,

En fait c'est plus compliqué car en Feuil2 colonne B il y a des références concaténées comme 41796279/85106330.

Alors compliquons :

1) Définir les noms :

- Tableau1 =DECALER(Feuil1!$A$1;;;EQUIV(9^9;Feuil1!$N:$N);16)

- Tableau2 =DECALER(Feuil2!$A$1;;;EQUIV(9^9;Feuil2!$C:$C);3)

- matrice1 =INDEX(Tableau1;;1)&INDEX(Tableau1;;14)

- col =INDEX(Tableau2;;2)&"/"

- matrice2 =GAUCHE(col;TROUVE("/";col)-1)&INDEX(Tableau2;;3)

- matrice3 =SUBSTITUE(STXT(col;TROUVE("/";col)+1;99);"/";"")&INDEX(Tableau2;;3)

2) MFC sur Feuil1!A =SOMMEPROD(($A1&$N1<>"")*(($A1&$N1=matrice2)+($A1&$N1=matrice3)))

3) MFC sur Feuil2!A:C :

=SOMMEPROD((GAUCHE($B1;TROUVE("/";$B1&"/")-1)&$C1=matrice1)+(STXT($B1;TROUVE("/";$B1&"/")+1;99)&$C1=matrice1))

Fichier (2).

Noter que le calcul prend nettement plus de temps...

A+

 

[mplomion]

Re : Comparaison de 2 BD

Oui en effet ca complexifie le fichier mais ce n'était pas dans les consignes de départ ;-)
Je suis resté bête et discipliné!

 

[job75]

Re : Comparaison de 2 BD

Re,

Noter que le calcul prend nettement plus de temps...

Mais si l'on veut accélérer le calcul il suffit de limiter les plages où s'appliquent les MFC, voir ce fichier (3).

A+

 

[job75]

Re : Comparaison de 2 BD

Re,

Il fallait SUBSTITUE dans la définition de matrice3, j'ai corrigé les fichiers (2) et (3).

A+

 

[job75]

Re : Comparaison de 2 BD

Re,

En fait on peut laisser les MFC sur des plages non limitées :

- MFC sur Feuil1!A =SI($A1&$N1<>"";SOMMEPROD(($A1&$N1=matrice2)+($A1&$N1=matrice3)))

- MFC sur Feuil2!A:C :

=SI($B1&$C1<>"";SOMMEPROD((GAUCHE($B1;TROUVE("/";$B1&"/")-1)&$C1=matrice1)+(STXT($B1;TROUVE("/";$B1&"/")+1;99)&$C1=matrice1)))

C'est la fonction SI qui limite la zone du calcul matriciel.

Fichier (4).

A+