Comment tester si un fichier Excel est ouvert ?

[marmotte18]

Bonjour,

Je souhaiterais connaître la procédure VBA qui permet de tester si un fichier Excel est ouvert.

• S'il est ouvert, fin de la procédure
• Sinon, ouvrir le fichier

Merci par avance

 

[bof]

Re : Comment tester si un fichier Excel est ouvert ?

Bonjour,
Ouvert par qui ? Par toi ou par quelqu'un d'autre sur le réseau ?
A+

 

[marmotte18]

Re : Comment tester si un fichier Excel est ouvert ?

Bonjour,
Ouvert par qui ? Par toi ou par quelqu'un d'autre sur le réseau ?
A+

Bonjour bof,

Je veux faire personnellement cela, sur mon propre ordinateur.

 

[gilbert_RGI]

Re : Comment tester si un fichier Excel est ouvert ?

Bonjour

regardez Ici

http://www.excel-downloads.com/forum/101216-tester-si-un-fichier-excel-est-deja-ouvert-post575119.html#post575119

 

[Efgé]

Re : Comment tester si un fichier Excel est ouvert ?

Bonjour marmotte18, bof

Une fonction qui renvoi l'état d'un classeur :

Function IsFileOpen(ByVal Filename As String) As String
'Récupération du statut d'un fichier
Dim filenum As Integer, Errnum As Integer
On Error Resume Next
filenum = FreeFile()
Open Filename For Input Lock Read As #filenum
Close filenum
Errnum = Err
On Error GoTo 0
Select Case Errnum
Case 0
IsFileOpen = "Fermé"
Case 53
IsFileOpen = "Absent"
Case 70
IsFileOpen = "Ouvert"
End Select
End Function

Pour l'utiliser, dans la macro principale:

Select Case IsFileOpen(Le_Chemin_Entier_Du_Classeur)
Case "Absent"
Rep = MsgBox("Le fichier " & vbLf & " n'a pas été trouvé pour la consolidation." & vbLf _
& "Le traitement est arrété.", vbNo + vbCritical, "Erreur")
Exit Sub
Case "Ouvert"
Rep = MsgBox("Merci de fermer le fichier " & vbLf & " avant de lancer le traitement" & vbLf _
& "Le traitement est arrété.", vbNo + vbCritical, "Erreur")
Exit Sub
End Select

Avec par exemple Le_Chemin_Entier_Du_Classeur = "C:\toto\titi\Mon_Classeur.xls"

Cordialement

EDIt Bonjour Gilbert_RGI

 

[bof]

Re : Comment tester si un fichier Excel est ouvert ?

Bonjour,
Pour faire court :

Function WbIsOpen(WbName As String) As Boolean
On Error Resume Next
WbIsOpen = Not Workbooks(WbName) Is Nothing
End Function

Pour tester :

Sub test()
If Not WbIsOpen("blabla.xls") Then Workbooks.Open ("blabla.xls")
End Sub

A+