Combobox avec toutes les options

[Christine]

Bonjour,

Thierry m'a aidé à corriger mon problème avec mes combobox. Suite à des modifs perso j'ai constaté que dans le 3e combobox il me donne toutes les possibilités qui se trouvent dans la colonne de référence.

J'aimerais qu'il n'y est seulement que les possibilités en fonction des choix dans les combobox1 et 2. Cela devrais me donner seulement 3 ou 4 choix et non +20 tel que présentement. Sont code fontionne bien mais avec plus de 4500 lignes sur 10 colonnes ...

J'ai pris son fichier, coller mes données et le même problème apparait.

J'inclus le fichier the Thierry.

Merci [file name=Combobox_20050811170929.zip size=15986]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/Combobox_20050811170929.zip[/file]

 

[_Thierry]

Bonjour Christine, le Forum

Ah oui dans ce cas là c'est exact, la ComboBox suivante n'est tributaire que de la ComboBox Précédente... C'était en fait pour répondre initialement à une demande bien précise où les sous-catégories ne pouvaient se chevaucher.

Oriente toi sinon dans ce Fil où mon copain DidierMDF est venu à la rescousse de Yanou qui avait semble-t'il le même problème sur la même démo.

=> Lien supprimé

Bonne Fin de Journée

[ol]@+Thierry[/ol]

 

[Christine]

Bonjour Thierry, le forum,

J'ai visité la page suggérée et ai apporté les modification selon mes critères.

Tout fonctionne bien sauf que j'ai des doublons dans le combobox2 et 3 ?

Pourquoi?

Quelles sont mes erreurs ?

Merci de votre aide. [file name=Sansdoublon.zip size=17164]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/Sansdoublon.zip[/file]

 

[_Thierry]

Bonsoir Christine, le Forum

Je reviens juste d'une journée en enfer et ça a été presque comme ça toute la semaine.

Le programme étant de mon copain DidierMDF et de plus m'étant promis de ne plus voir aucun module de codes pour ce soir, je repasserai ce week end sur ce fil si personne n'est intervenu.

Bonne Nuit
[ol]@+Thierry[/ol]

 

[Christine]

Bonne nuit Thierry, le forum,

Merci.

 

[_Thierry]

Bonjour Christine, le Fil, le Forum

Comme promis j'ai regardé ton problème...

Voilà comment tu devrais t'y prendre :

Option Explicit
Private Tablo As Variant

Private Sub UserForm_Initialize()
Dim i As Integer
Dim ColCombo As New Collection

With Feuil2
Tablo = .Range('A2:K' & .Range('A35000').End(xlUp).Row)
End With

      For i = 1 To UBound(Tablo, 1)
          On Error Resume Next
              ColCombo.Add CStr(Tablo(i, 1)), CStr(Tablo(i, 1))
          On Error GoTo 0
      Next i

    For i = 1 To ColCombo.Count
        ComboBox1.AddItem ColCombo.Item(i)
    Next i
End Sub
Private Sub ComboBox1_Click()
Dim i As Integer
Dim ColCombo As New Collection
ComboBox2.Clear

    For i = 1 To UBound(Tablo, 1)
        If ComboBox1 = Tablo(i, 1) Then
            On Error Resume Next
                ColCombo.Add CStr(Tablo(i, 2)), CStr(Tablo(i, 2))
            On Error GoTo 0
        End If
    Next i
   
    For i = 1 To ColCombo.Count
        ComboBox2.AddItem ColCombo.Item(i)
Next i
End Sub
Private Sub ComboBox2_Change()
Dim i As Integer
Dim ColCombo As New Collection
ComboBox3.Clear

For i = 1 To UBound(Tablo, 1)
  If ComboBox1 & ComboBox2 = Tablo(i, 1) & Tablo(i, 2) Then
        On Error Resume Next
            ColCombo.Add CStr(Tablo(i, 3)), CStr(Tablo(i, 3))
        On Error GoTo 0
  End If
Next i

For i = 1 To ColCombo.Count
    ComboBox3.AddItem ColCombo.Item(i)
Next i
End Sub

Bon Long Week End
[ol]@+Thierry[/ol]

 

[Christine]

Bonsoir Thierry, le forum,

MERCI cela fonctionne merveilleusement bien.

MERCI encore