Combinaison des fonction SI, ESTNUM et TROUVE

[godux60]

Bonjour,

Travaillant sur une base de donnée de toutes les FDS de l'entreprise ou je travaille, je rencontre un problème concernant une formule, excel me dit que la formule contient une erreur.

Voici la formule en question:

=SI(ESTNUM(TROUVE(40;AJ15));"cat.3";SI(ESTNUM(TROUVE(68;AJ15));"cat.3";SI(ESTNUM(TROUVE(62;AJ15));"cat.3";SI(ESTNUM(TROUVE(63;AJ15));"cat.3";SI(ESTNUM(TROUVE(45;AJ15));"cat.1/2";SI(ESTNUM(TROUVE(49;AJ15));"cat.1/2";SI(ESTNUM(TROUVE(46;AJ15));"cat.1/2";SI(ESTNUM(TROUVE(60;AJ15));"cat.1/2";SI(ESTNUM(TROUVE(61;AJ15));"cat.1/2";"NSP")))))))))

Merci d'avance de votre aide

 

[Tibo]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonsoir,

Ton problème est dû au nombre d'imbrications (7 niveaux maxi).

Essaye avec :

=SI(OU(ESTNUM(TROUVE(40;AJ15));ESTNUM(TROUVE(68;AJ15));ESTNUM(TROUVE(62;AJ15));
ESTNUM(TROUVE(63;AJ15)));"cat.3";SI(OU(ESTNUM(TROUVE(45;AJ15));ESTNUM(TROUVE(
49;AJ15));ESTNUM(TROUVE(46;AJ15));ESTNUM(TROUVE(60;AJ15));ESTNUM(TROUVE(61;
AJ15)));"cat.1/2";"NSP"))

Je te laisse tester (pas pu le faire puisque tu n'avais pas joint de fichier).

@+

 

[godux60]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonjour,

Un grand merci a toi, ça marche.

Merci beaucoup

 

[Tibo]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonjour,

Une version plus courte, à tester quand même :

=SI(SOMMEPROD((ESTNUM(TROUVE({"40";"68";"62";"52"};AJ15)))*1);"cat.3";SI(
SOMMEPROD((ESTNUM(TROUVE({"45";"46";"49";"60";"61"};AJ15)))*1);"cat.1/2";
"NSP"))

Je te laisse tester

@+

 

[godux60]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonjour,

Ton 2ème code ne marche pas.

J' ai un autre problème, concernant une autre formule

=SI(OU(ESTNUM(TROUVE("50/53";O130)));"R50/53";SI(OU(ESTNUM(TROUVE(45;O130));ESTNUM(TROUVE(
49;O130));ESTNUM(TROUVE(46;O130));ESTNUM(TROUVE(60;O130));ESTNUM(TROUVE(61;
O130)));"CMR cat.1/2";"Non Concerné"))

Le problème c'est que j'aimerais bien que quand la cellule O130 contient 50/53 et 45 ou 46 ou 49 ou 60 ou 61 il y ai de marqué R50/53 + CMR cat.1/2

Voila en espérant être claire, je vous joint le fichier excel.

Merci d'avance de votre aide.

Bonne après midi

 

[Tibo]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

re,

en S3, essaye avec :

=SUPPRESPACE(SUBSTITUE(SI(ESTNUM(TROUVE("50/53";N3));"R50/53 ";"")&SI(OU(ESTNUM(
TROUVE(45;N3));ESTNUM(TROUVE(49;N3));ESTNUM(TROUVE(46;N3));ESTNUM(TROUVE(60;N3))
;ESTNUM(TROUVE(61;N3)));" CMR cat.1/2";"Non Concerné");"  ";" + "))

Pour AJ3, sur la base de la formule proposée ce matin, une tentative d'adaptation :

=SI(SOMMEPROD((ESTNUM(TROUVE({"40";"68";"62";"52"};AH3)))*1);"cat.3";SI(
SOMMEPROD((ESTNUM(TROUVE({"45";"46";"49";"60";"61"};AH3)))*1);"cat.1/2";"NSP"))

Essaye et dis-nous

@+

 

[godux60]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonjour,

Les codes que vous m'avez donné marche bien, le seul hic c'est pour le 1er,
uand dans la cellule N3 il y a que R50/53 l'autre cellule m'affiche "R50/53 non concerné".

Je voudrais savoir si c'est possible d'enlever le non concerné dans cette configuration la.

Merci de prendre du temps pour m'aider

A plus

 

[Tibo]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonjour,

Peut-être en remplaçant "Non concerné" par ""

Sinon, donne nous quelques cas de figure avec les différents résultats attendus

@+

 

[godux60]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonjour,

Je te joint un fichier excel avec des commentaires.

Merci de prendre du temps pour résoudre mon problème.

A plus

 

[Tibo]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

re,

En T3, une tentative avec :

=SUPPRESPACE(SUBSTITUE(SI(ESTNUM(TROUVE("50/53";N3));"R50/53 "&SI(OU(ESTNUM(
TROUVE(45;N3));ESTNUM(TROUVE(49;N3));ESTNUM(TROUVE(46;N3));ESTNUM(TROUVE(60;
N3));ESTNUM(TROUVE(61;N3)));" CMR cat.1/2";"");"Non Concerné");"  ";" + "))

à recopier vers le bas

Je te laisse tester

@+

 

[godux60]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonsoir,

ça ne fonctionne pas, maintenant quand il y a R45 ou 46 ou 49 ou 60 ou 61 ça met "non concerné" au lieu de "CMR cat.1/2".

Ce que je voudrais c'est que:
- quand il y a 50/53 en N3 il faudrais que ça marque "R50/53" en T3
- quand il y a 45 ou 46 ou 49 ou 60 ou 61 il faudrais que ça marque "CMR cat.1/2" en T3
- quand il y a 50/53-45 (ou46/49/60/61) il faudrais que ça marque "R50/53 + CMR cat.1/2"
- quand il y a n'importe quelle autre chiffre (sauf 50/53-45-46-49-60-61) ou meme rien il faudrais que ça marque "Non Concerné"

En espérant avoir était plus claire.

Je vous remercie de vous casser la tete pour moi.

A plus

 

[Tibo]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

re,

Avec une autre approche :

en T3 :

=CHOISIR(ESTNUM(TROUVE("50/53";N3))*1+(SOMMEPROD((ESTNUM(TROUVE({45;46;49;60;61};
N3)))*1)>0)*2+1;"Non concerné";"R50/53";"CMR car.1/2";"R50/53 + CMR cat.1/2")

à recopier vers le bas

@+

 

[godux60]

Re : Combinaison des fonction SI, ESTNUM et TROUVE

Bonsoir,

Je te remercie les deux codes marche.

A plus.