Coloration d'un onglet selon valeur.

[Igl0]

Bonjour à tous,
J'ai un classeur excel dans lequel la cellule AX9 renvoie une valeur.
Je cherche à faire une macro qui me colorierait l'onglet en vert si AX9 > 1 et en rouge si c'est = 0.
Pouvez-vous m'aider ?
Merci.

 

[tototiti2008]

Re : Coloration d'un onglet selon valeur.

Bonjour Captain,

La cellule AX9 est le résultat d'un calcul (formule) ?

 

[Igl0]

Re : Coloration d'un onglet selon valeur.

Oui, absolument.

 

[tototiti2008]

Re : Coloration d'un onglet selon valeur.

Re,

à mettre dans le code de la feuille concernée

Private Sub Worksheet_Calculate()
    With ActiveSheet.Tab
        .TintAndShade = 0
        If Range("AX9").Value >= 1 Then
            .Color = 5296274
        Else
            .Color = 255
        End If
    End With
End Sub

Edit : Oups, ça a tendance à mettre de la couleur pas forcément sur le bon onglet mais sur l'onglet actif
ça devrait être mieux comme ça :

Private Sub Worksheet_Calculate()
    With Range("AX9").Parent.Tab
        .TintAndShade = 0
        If Range("AX9").Value >= 1 Then
            .Color = 5296274
        Else
            .Color = 255
        End If
    End With
End Sub

 

[Staple1600]

Re : Coloration d'un onglet selon valeur.

Bonjour à tous

Si toutes les feuilles sont concernées
Tu peux aussi essayer ceci (à mettre dans ThisWorkBook)

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Sh.Tab.ColorIndex = IIf(Sh.[AX9] >= 1, 4, 3) 
End Sub

Tu peux choisir un autre événement si celui-là ne te convient pas.

 

[Staple1600]

Re : Coloration d'un onglet selon valeur.

Re,

Finalement, cela colle plus à tes critères

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If Not IsEmpty(Sh.[AX9]) Then
Sh.Tab.ColorIndex = Switch(Sh.[AX9] >= 1, 4, Sh.[AX9] = 0, 3)
End If
End Sub

Et pour le fun, tu peux aussi l'écrire ainsi

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If Not IsEmpty(Sh.[AX9]) Then
Sh.Tab.ColorIndex = 3 - (Sh.[AX9] >= 1)
End If
End Sub

 

[Igl0]

Re : Coloration d'un onglet selon valeur.

Que dire, si ce n'est un grand MERCI à vous ! Ca fonctionne exactement comme je l'espérai ! Merci encore à vous !

 

[Igl0]

Re : Coloration d'un onglet selon valeur.

Bonjour à tous, je me demandais si on pouvait adapter ce code de la manière suivante (toujours pour AX9) :
Si < -5 rouge, si entre 0 et - 5 orange et si positif vert.
Je pensais à adapter le code comme suit, mais ça n'a pas l'air de fonctionner.

Private Sub Worksheet_Calculate()
    With Range("AX9").Parent.Tab
        .TintAndShade = 0
        If Range("AX9").Value =< -5 Then
            .Color = 5296274
        Else
             If Range("AX9").Value < -4 And < 0 Then
            .Color = 49407
             End If
        Else
             .Color = 255
        End If
    End With
End Sub

Pouvez-vous m'indiquer ou est mon erreur svp ?

 

[Igl0]

Re : Coloration d'un onglet selon valeur.

Je sais que c'est au niveau du "And", mais je ne trouve pas comment faire...

 

[tototiti2008]

Re : Coloration d'un onglet selon valeur.

Bonjour à tous,

Peut-être, vois si les bornes sont correctes pour ton besoin

    With Range("AX9").Parent.Tab
        .TintAndShade = 0
        If Range("AX9").Value <= -5 Then
            .Color = 5296274
        ElseIf Range("AX9").Value > -5 And Range("AX9").Value < 0 Then
            .Color = 49407
        Else
             .Color = 255
        End If
    End With

 

[Igl0]

Re : Coloration d'un onglet selon valeur.

Merci beaucoup, les valeurs dans AX9 étant un pourcentage, j'ai adapté le code comme suit :

Private Sub Worksheet_Calculate()
       With Range("AX9").Parent.Tab
         .TintAndShade = 0
         If Range("AX9").Value <= -0.05 And Range("AX9").Value >= 0 Then
             .Color = 5296274
         ElseIf Range("AX9").Value > -0.05 And Range("AX9").Value < 0 Then
             .Color = 49407
         Else
              .Color = 255
         End If
     End With
End Sub

J'ai une dernière question. Je voudrais savoir comment faire pour appliquer la macro à l'ensemble du classeur et non plus à une seule feuille.
La je sèche complètement...
A bientôt !