Choix de couleure dans une cellule sur clic

[Cefiroth]

Bonjour le forum,

J'ai un petit problème :
J'ai un tableau excel, j'aimerai que suite à un double clic la case devienne verte, sur un second clic dans la même case, la case devienne orange puis rouge.
Pour l'instant j'utilise le code suivant pour remplir la case uniquement en rouge :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Cancel = True
If Not Application.Intersect(Target, [D8:AY43]) Is Nothing Then Target.Interior.ColorIndex = IIf(Target.Interior.ColorIndex = 3, xlNone, 3)
End Sub

Comment faire pour pouvoir avoir 3 couleurs différentes ?

(Ne peut-on pas simplement avoir une liste déroulante sut chaque cellule qui permette de choisir la couleure de la cellule ?)

Merci d'avance !

Cef

 

[Efgé]

Re : Choix de couleure dans une cellule sur clic

Bonjour Cefiroth,
Une proposition:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Cancel = True
If Not Application.Intersect(Target, [D8:AY43]) Is Nothing Then
    Select Case Target.Interior.ColorIndex
        Case xlNone
            Target.Interior.ColorIndex = 35
        Case 35
            Target.Interior.ColorIndex = 3
        Case 3
            Target.Interior.ColorIndex = xlNone
    End Select
End If
End Sub

Cordialement

 

[Cefiroth]

Re : Choix de couleure dans une cellule sur clic

Ca marche nickel !

Merci Efgé !

 

[tototiti2008]

Re : Choix de couleure dans une cellule sur clic

Bonjour Cefiroth, Bonjour Efgé

Bon, je l'ai fait alors :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim TabloCoul, Rang As Long
    Cancel = True
    TabloCoul = Array(xlNone, 43, 44, 3)
    If Not Application.Intersect(Target, [D8:AY43]) Is Nothing Then
        Rang = Application.Match(Target.Interior.ColorIndex, TabloCoul, 0) - 1
        If Rang = UBound(TabloCoul) Then Rang = -1
        Target.Interior.ColorIndex = TabloCoul(Rang + 1)
    End If
End Sub

 

[Cefiroth]

Re : Choix de couleure dans une cellule sur clic

Merci tototiti2008, toujour partant pour s'occuper de mes problèmes toi ! ^^

 

[Efgé]

Re : Choix de couleure dans une cellule sur clic

Re Cefiroth, Bonjour Tototiti ,
J'ai retrouvé l'artillerie lourde.
Inutile de préciser que ce n'est pas de moi, j'y trouve même un coté "magique" assez inexplicable .
Double click dans la zone...
Bonne lecture
Cordialement

 

[Fo_rum]

Re : Choix de couleure dans une cellule sur clic

Bonsoir,

@Efgé : artillerie légère à essayer

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
  If Application.Intersect(Target, [D8:AY43]) Is Nothing Then Exit Sub
  Application.Dialogs(xlDialogPatterns).Show
End Sub

sans rien d'autre !

 

[Efgé]

Re : Choix de couleure dans une cellule sur clic

Re à Tous, Bonsoir Fo_rum
@ Fo_rum
Merci, je vais voyager plus légé.
En plus ça m'est quand même plus compréhensible .
Cordialement