Changement de feuille en VBA

[Sanegone]

Bonjour à tous,

Voilà je rencontre un problème que je n'arrive pas à résoudre :

Private Sub CommandButton1_Click()
Var_Chemin = "I:\****\****\TTIS.xls"
Workbooks.Open Var_Chemin, 0, ReadOnly:=False
Workbooks("TTIS.xls").Sheets("Feuil1").Copy Before:=Workbooks("test.Mikael.xls").Sheets("test.Mikael")
Workbooks("TTIS.xls").Close
Worksheets("Feuil1").Select
Range("A2").Select
End Sub

Pas moyen d'avoir ma cellule A2 alors que si je remplace Worksheets("Feuil1").Select
par
Worksheets("test.Mikael").Select

La pas de problème la cellule est sélectionnée.

Je comprend pas quelqu'un as une idée ?

 

[Guest]

Re : Changement de feuille en VBA

Bonjour,

Essai de mettre un ThisWorkbook.Activate avant ton Select

A+

 

[Sanegone]

Re : Changement de feuille en VBA

Private Sub CommandButton1_Click()
Var_Chemin = "I:\****\****\TTIS.xls"
Workbooks.Open Var_Chemin, 0, ReadOnly:=False
Workbooks("TTIS.xls").Sheets("Feuil1").Copy Before:=Workbooks("test.Mikael.xls").Sheets("test.Mikael")
Workbooks("TTIS.xls").Close
Worksheets("Feuil1").Select
ThisWorkbook.Activate
Range("A2").Select
End Sub

Toujours pareil Erreur "1004" la méthode de Select de la classe range a échoué

 

[Guest]

Re : Changement de feuille en VBA

Re,

sans le classeur difficile de te répondre. Mais je suggérais de place le ThisWorkBook.Activate avant la sélection de la feuille.

Autre idée: Application.Goto sheets("Feuil1").range("A2")

A condition que ta feuille s'appelle bien Feuil1 et non pas "test.Mikael"

A+

 

[Sanegone]

Re : Changement de feuille en VBA

Je ne peux malheureusement pas transmettre le classeur qui contient des informations soumise au secret professionnel de mon emploi. ( Banque )

Je vais quand meme expliquer rapidement ce qui est censer être fait par la macro ça sera sans doute plus clair :


J'ai un classeur A qui est régulièrement mit à jour.

J'ai un classeur B qui est un extraction de parc machine.

Ma macro doit importer le classeur A ( qui ne contient qu'une feuille ) dans une nouvelle feuille du classeur B, nous nommerons cette feuille FeuilA et les informations d'origine de classeur B FeuilB.

Je dois ensuite comparer la colone A de FeuilA à la colone A de FeuilB et supprimer tout les occurrence identiques.

En soit ça n'as pas l'air très compliqué mais comme je n'arrive pas a sélectionner quoi que ce soit dans ma FeuilA la tache devient beaucoup plus compliquée ^^


EDIT : Merci pour la solution du Goto elle fonctionne parfaitement

 

[Guest]

Re : Changement de feuille en VBA

Bonsoir,

Voici comment j'écrirais une macro d'importation. Quand il y a problème, il vaut mieux mettre le maximum de chose et d'objet en variable.

Public Sub Importation()
    Dim wkSource As Workbook
    Dim sh As Worksheet
    Dim Var_Chemin As String
 
    Var_Chemin = "I:\****\****\TTIS.xls"
    Set wkSource = Workbooks.Open(Var_Chemin)
    wkSource.Sheets("Feuil1").Copy Before:=ThisWorkbook.Sheets("Feuil1")
    '
    'La feuille destination (importée) devient la feuille active
    'conserver sa référence dans une variable
    '
    Set sh = ActiveSheet
    '
    'Fermeture du classeur source
    '
    wkSource.Saved = True    'évite l'éventuellement demande d'enregistrement
    wkSource.Close
    'aller en A2 de la feuille importée
    Application.Goto sh.Range("A2")
End Sub

Mais je réitère: sans classeur(s) exemple(s)....... ce sera ma dernière intervention

A+