Calculer plusieur tranche d'heures

[creolia]

Bonjour à tous j'essais en vain de calculer plusieur tranche d'heure journalier pour avoir un total mensuel en M3.

j'utilise cette formule pour le calcule d'une tranche d'heures mais je dois en calculer autant de tranche que de jour dans le mois.

=SI(A8<>"";MOD(D7-C7;1);"")

sa c'etais ma premiere question

ma seconde QUESTION

en N3 comment puis je faire pour qu'il me dit combien de tranche de 24 heures sont present dans la totalité des heures fais dans le mois svp je vous remercie pour votre aide


PS:Si en formule sa se fais pas je prend volontier une macro

 

[job75]

Re : Calculer plusieur tranche d'heures

Bonjour creolia,

Les heures des colonnes paires doivent toujours être postérieures au heures des colonnes impaires.

M3 => =SI(A3="";"";SOMMEPROD(MOD(COLONNE(A3:K3);2);B3:L3-A3:K3))

N3 => =ENT(M3)

O3 => =ENT(2*M3)

Colonne M au format [h]:mm:ss

Fichier joint.

A+

 

[job75]

Re : Calculer plusieur tranche d'heures

Re,

Si l'on veut pouvoir insérer des colonnes (entre les colonnes L et M) sans avoir à modifier les formules :

=SI(A3="";"";SOMMEPROD(MOD(COLONNE(A3:DECALER(M3;;-2));2);B3:DECALER(M3;;-1)-A3:DECALER(M3;;-2)))

Fichier (2).

A+

 

[creolia]

Re : Calculer plusieur tranche d'heures

Bonjour Job75 pour ton aide et ta solution comme souvent exelente en revanche dans ton fichier y a un petit bug que j'arrive pas à résoudre si je met en debut 06:00 et la fin le lendemain 6:00 (planning de secours ont bosse souvent en 24h) et bien en total j'ai 00:00 et si je met 6:00 en debut et en fin disons 05:00 sa me fait ############ y a t'il possibilité de corrigé cela svp.

 

[job75]

Re : Calculer plusieur tranche d'heures

Bonjour creolia, le forum,

Si l'heure FIN peut être inférieure à l'heure DEBUT utiliser :

=SI(A3="";"";SOMMEPROD(MOD(COLONNE(A3:K3);2);MOD(B3:L3-A3:K3;1)))

Voir le fichier (3) avec l'heure en L3.

Noter qu'en L3 on peut aussi taper 30:00:00 (24h ajoutés), alors la fonction MOD n'a plus d'utilité.

A+

 

[job75]

Re : Calculer plusieur tranche d'heures

Re,

Cette formule est plus complète :

=SOMMEPROD(MOD(COLONNE(A3:K3);2);ESTNUM(A3:K3)*ESTNUM(B3:L3)*(MOD(B3:L3-A3:K3;1)+(A3:K3=B3:L3)))

- si DEBUT ou FIN est vide l'autre heure n'est pas prise en compte

- si DEBUT = FIN (6:00:00 en K3 et L3) 24 heures (i.e. 1) sont ajoutées.

Fichier (4).

Edit : finalement j'ai enlevé le test SI(A3=""... au début, il ne sert à rien.

A+

 

[creolia]

Re : Calculer plusieur tranche d'heures

Re bonjour job75 merci pour tout ton temps et la rapidité de tes réponses.

je vais faire un mixe de tous ce que tu ma donnée car entre je pense inserer une colonne suplementaire pour chaque tranche d'heure pour les commentaires donc utiliser la solution decaler que tu ma proposer en tous cas je te remercie pour tous je vais mettre tous sa en application à trés bientot

Ps: j'avais pas vue ton dernier message je vais le lire

 

[creolia]

Re : Calculer plusieur tranche d'heures

Re bonjour Help me please

j'ai fais quelque changement tous semble ok mais il calcule plus les heures sa viendrais d'ou j'ai tous bien fais pourtant.

 

[job75]

Re : Calculer plusieur tranche d'heures

Re,

Il suffit d'adapter le test de parité des colonnes : COLONNE(F7:BN7) => COLONNE(G7:BO7)

=SOMMEPROD(MOD(COLONNE(G7:BO7);2);ESTNUM(F7:BN7)*ESTNUM(G7:BO7)*(MOD(G7:BO7-F7:BN7;1)+(F7:BN7=G7:BO7)))

Bonne nuit.

A+

 

[creolia]

Re : Calculer plusieur tranche d'heures

Bonjour Job75 tous est parfait merci encore pour tous

 

[creolia]

Re : Calculer plusieur tranche d'heures

Bonjour à tous

je me permet de vous demander un complement de renseignement sur la formule de job75

j'ai ajouter en C une colonne vacation.

ma formule en D deviens donc celle ci:

=SOMMEPROD(MOD(COLONNE(H7:BP7);2);ESTNUM(G7:BO7)*ESTNUM(H7:BP7)*(MOD(H7:BP7-G7:BO7;1)+(G7:BO7=H7:BP7)))

j'ai bien respecter la parité comme conseiller par Job75. et rien ne se passe quelqu'un pourais t'il jeter un oeil svp merci

 

[job75]

Re : Calculer plusieur tranche d'heures

Bonsoir creolia,

j'ai bien respecter la parité comme conseiller par Job75

Ben non...

=SOMMEPROD(MOD(COLONNE(G7:BO7);2);ESTNUM(G7:BO7)*ESTNUM(H7:BP7)*(MOD(H7:BP7-G7:BO7;1)+(G7:BO7=H7:BP7)))

Il y avait une chance sur 2 de se planter mais pourquoi ne pas avoir testé l'autre possibilité

A+

 

[job75]

Re : Calculer plusieur tranche d'heures

Re creolia,

Juste 2 remarques.

1) La colonne D doit être mise au format [hh]:mm:ss et non pas hh:mm:ss.

2) SOMMEPROD accepte bien plus de 2 arguments et on peut donc écrire :

=SOMMEPROD(MOD(COLONNE(G7:BO7);2);ESTNUM(G7:BO7)*ESTNUM(H7:BP7);MOD(H7:BP7-G7:BO7;1)+(G7:BO7=H7:BP7))

La formule occupe ainsi 2 octets de moins en mémoire.

A+

 

[creolia]

Re : Calculer plusieur tranche d'heures

Bonjour et merci Job75 pour ton intervention je vais bien regarder cela encore merci pour tes explication