Calcul de dates : date + x jours + aller au jeudi suivant

[gweny]

Bonjour,

J'ai fait un retroplanning qui calcule en jours ouvrables (avec SERIE.JOUR.OUVRE) : tableau avec une colonne "nombre de jours nécessaires à l'étape, et une colonne "date d'échéance obtenue".

Jusque-là tout va bien, mais sur une étape donnée j'ai besoin que la date obtenue, en plus d'avoir intégré le nombre de jours nécessaires à l'étape, tombe un jour fixe de la semaine (car c'est ce jour là de la semaine qu'a lieu la réunion de validation).
Autrement dit, je cherche la formule qui ferait la chose suivante :
date initiale + nombre de jours à ajouter + aller au jeudi suivant si la date obtenue n'est pas tombée un jeudi.

J'ai essayé avec la fonction mod, mais je n'ai pas réussi.
Ci-joint le tableau pour y voir plus clair (J'essaye dans un 1er temps avec une formule sans la fonction SERIE.JOUR.OUVRE pour ne pas compliquer)

Merci de votre aide.
Cordialement.

 

[Dranreb]

Re : Calcul de dates : date + x jours + aller au jeudi suivant

Bonjour.
Cette formule a l'air de faire l'affaire:

=SERIE.JOUR.OUVRE(C8;$B9;liste_fériés)+MOD(3-JOURSEM(SERIE.JOUR.OUVRE(C8;$B9;liste_fériés);3);7)

Edit: non erreur en reprenant la formule de dessus. C'est :

=SERIE.JOUR.OUVRE(C9;$B10;liste_fériés)+MOD(3-JOURSEM(SERIE.JOUR.OUVRE(C9;$B10;liste_fériés);3);7)

Cela dit personnellement je décomposerais en 2 lignes, une pour l'ajout du nombre de jours ouvrés, une autre pour l'ajustement au jour de la semaine.
Avec la possibilité de taper un nom de jour en colonne B, ça pourrait donner ça en B7 :

=SI(ESTNUM($B7);SERIE.JOUR.OUVRE(DECALER(C7;-1;0);$B7;liste_fériés);DECALER(C7;-1;0)+MOD((CHERCHE(GAUCHE($B7;3);"lunmarmerjeuvensamdim")-1)/3-JOURSEM(DECALER(C7;-1;0);3);7))

 

[gweny]

Re : Calcul de dates : date + x jours + aller au jeudi suivant

ouah çà marche, merci beaucoup Dranreb

Mais je suis peiné de ne pas avoir compris comment vous avez fait
Moi j'avais écrit la formule du type : =C11+MOD((C11-5),7)
Vous, vous avez écrit =C11+MOD((3-JOURSEM(C11,3),7)

Je n'ai pas compris le "3-JOURSEM". Pourquoi le "3-"?

Merci encore.

 

[Dranreb]

Re : Calcul de dates : date + x jours + aller au jeudi suivant

La fonction JOURSEM avec 3 en second paramètre rend 0 pour lundi, 6 pour dimanche et donc 3 pour jeudi. C'est donc juste si la date tombe déjà un jeudi, et sinon il faudrait bien y soustraire le jour de la semaine pour avoir en complément ce qui manquerait jusqu'à un autre jeudi. La fonction MOD d'Excel rend toujours intelligemment un reste positif.

 

[gweny]

Re : Calcul de dates : date + x jours + aller au jeudi suivant

Merci pour tout Dranreb (le ésultat et les explications en plus )
TB journée