cacher la fenêtre d'un seul classeur

[RONIBO]

Bonjour le forum,

J'aimerai cacher la fenêtre d'un classeur excel, faire en sorte que l'userform s'ouvre au démarrage du fichier excel, par contre des que j'ouvre un autre fichier excel la fenêtre réapparait.

Ou le contraire, dès que j'ai un classeur j'ai un classeur ouvert, puis j'applique application.visible=false, tout est masqué.

Comment utiliser Application.visible=false pour un seul classeur?

merci d'avance

 

[PMO2]

Re : cacher la fenêtre d'un seul classeur

Bonjour,

Essayez avec

Private Sub CommandButton1_Click()
ThisWorkbook.Windows(1).Visible = True
End Sub


Private Sub Workbook_Open()
ThisWorkbook.Windows(1).Visible = False
UserForm1.Show 0
End Sub

 

[RONIBO]

Re : cacher la fenêtre d'un seul classeur

Bonjour,

Merci pour la proposition, mais ça ne fonctionne pas, la fenêtre reste afficher mais les menu grisés

 

[RONIBO]

Re : cacher la fenêtre d'un seul classeur

Re,

Vous avez pas d'idée ?

 

[PMO2]

Re : cacher la fenêtre d'un seul classeur

Bonjour,

Ce n'est pas aussi simple qu'il y paraît.
On est obligé de passer par une usine à gaz pour détruire un processus persistant d'Excel (voir le gestionnaire des tâches).

Voilà la démarche qui fonctionne chez moi :

1) Créez un module de classe Classe1 et copiez le code suivant dans sa fenêtre de code

Public WithEvents AppXL As Application

Private Sub AppXL_WorkbookBeforeClose(ByVal Wb As Workbook, Cancel As Boolean)
If Application.Workbooks.Count = 2 Then
  Application.Visible = False
  If UserFormVisible = False Then UserForm1.Show vbModeless
Else
  ThisWorkbook.Windows(1).Visible = False
End If
End Sub

2) Copiez le code suivant dans un module Standard

Public AppClass As New Classe1
Public UserFormVisible As Boolean

3) Copiez le code suivant dans la fenêtre de code de ThisWorkbook

Private Sub Workbook_Open()
Set AppClass.AppXL = Application
If Application.Workbooks.Count = 1 Then
  Application.Visible = False
Else
  ThisWorkbook.Windows(1).Visible = False
End If
UserForm1.Show vbModeless
End Sub

4) Dans UserForm1 (avec 3 CommandButton 1,2,3), copiez le code suivant

Private Sub UserForm_Initialize()
UserFormVisible = True
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
Dim Rep%
'---
If Application.Workbooks.Count = 1 Then
  If Application.Visible = False Then
    Rep% = MsgBox(prompt:="La fermeture du UserForm implique que l'application Excel soit fermée." & vbLf & _
    "Voulez-vous réellement fermer l'application Excel ?", Buttons:=vbOKCancel)
    If Rep% = vbOK Then
      If Not AppClass Is Nothing Then Set AppClass = Nothing
      ThisWorkbook.Save
      Application.Quit
    Else
      Cancel = True
    End If
  End If
Else
  UserFormVisible = False
End If
End Sub

Private Sub CommandButton1_Click()
Application.Visible = True
ThisWorkbook.Windows(1).Visible = True
End Sub

Private Sub CommandButton2_Click()
If Application.Workbooks.Count = 1 Then
  Application.Visible = False
Else
  ThisWorkbook.Windows(1).Visible = False
End If
End Sub

Private Sub CommandButton3_Click()
Unload Me
End Sub

Ouvrez le classeur et plusieurs autres classeurs pour voir ce qui se passe.

 

[RONIBO]

Re : cacher la fenêtre d'un seul classeur

Bonsoir, merci pour le travail que tu as fait
J'ai pas eu l'occasion de tester à fond, dès que je trouve un petit moment, je reviens vers toi

Merci encore

A+

 

[mapomme]

Re : cacher la fenêtre d'un seul classeur

Bonjour RONIBO, PMO2,

Un essai (Excel 2010) en masquant ou affichant les fenêtres.