Bouton macro avec trois conditions

[tallia64]

Bonsoir le forum,
J'ai crée un bouton macro qui a plusieurs conditions. Je voudrai les rassembler dans une même macro. Je les ai séparé avec un "exit sub" mais ça ne fonctionne pas
Pourriez-vous m'aider s'il vous plait ? Je vous en remercie d'avance.
Tallia

Sub Rectangle70_QuandClic()
'CONDITION 1
If Range("B1").Value = "" Then MsgBox ("Veuillez saisir votre identité ci-dessus dans la cellule B1 merci.")
Exit Sub
'CONDITION 2
If Range("D5,D16,D26,D36,D46,D56").Value = "" Then MsgBox ("Attention vous n'avez pas répondu à toutes les questions")
Exit Sub
'CONDITION 3
If Range("Q8").Value = "3" Then wordini.Show
If Range("Q8").Value < "3" Then wordini.Show
If Range("Q8").Value > "3" Then worperf.Show
End Sub

 

[tototiti2008]

Re : Bouton macro avec trois conditions

Bonsoir tallia,

mais ça ne fonctionne pas

Explique nous ce qui ne fonctionne pas, c'est à dire précisément ce que tu veux que ça fasse dans les différents cas

 

[Pierrot93]

Re : Bouton macro avec trois conditions

Bonjour Talia, Toto

A priori, dans tous les cas tu vas sortir de la procédure au premier "exit sub".... essaye peut être comme suit :

If Range("B1").Value = "" Then 
MsgBox ("Veuillez saisir votre identité ci-dessus dans la cellule B1 merci.")
Exit Sub
End If

même punition pour le deuxième test... enfin si j'ai bien compris ton souci...

bonne journée
@+

 

[tallia64]

Re : Bouton macro avec trois conditions

Bonjour Tototiti2008 et Pierrot93 je vous remercie pour vos messages et votre aide.
En fait j'ai crée une feuille excel ou des personnes doivent mettre une réponse dans certaines cellules.
De ce fait quand je clique sur mon bouton macro je souhaiterai qu'il effectue un 1er test si la cellule "B1" n'est pas renseigné que le message suivant s'affiche "Veuillez saisir votre identité ci-dessus dans la cellule B1 merci."
Puis un second test si les ou une des cellules "D5,D16,D26,D36,D46,D56" ne sont pas renseignées que le message suivant s'affiche "Attention vous n'avez pas répondu à toutes les questions". Et en dernier test qu'il affiche soit le userform wordini si la valeur est = ou < à 3 ou wordperf si la valeur est > 3.
J'espère que mes explications seront assez claires...
Merci d'avance pour votre aide.
Bonne journée.
Tallia

Sub Rectangle70_QuandClic()
'CONDITION 1
If Range("B1").Value = "" Then MsgBox ("Veuillez saisir votre identité ci-dessus dans la cellule B1 merci.")
Exit Sub
'CONDITION 2
If Range("D5,D16,D26,D36,D46,D56").Value = "" Then MsgBox ("Attention vous n'avez pas répondu à toutes les questions")
Exit Sub
'CONDITION 3
If Range("Q8").Value = "3" Then wordini.Show
If Range("Q8").Value < "3" Then wordini.Show
If Range("Q8").Value > "3" Then worperf.Show
End Sub

 

[Pierrot93]

Re : Bouton macro avec trois conditions

Re,

je disais :

A priori, dans tous les cas tu vas sortir de la procédure au premier "exit sub"....

idem avec ton code post #4... tu n'iras jamais plus loin que le premier "exit sub"....

 

[ChTi160]

Re : Bouton macro avec trois conditions

Bonjour tallia64
Bonjour le Fil
Bonjour le Forum

Une approche , n'ayant pas de fichier pour tester

Sub test()
 Const Msg1 As String = "Veuillez saisir votre identité ci-dessus dans la cellule B1 merci."
 Const Msg2 As String = "Attention vous n'avez pas répondu à toutes les questions"
'CONDITION 1
With Worksheets("Feuil1")
If .Range("B1") = "" Then
        MsgBox Msg1
  Exit Sub
End If
'CONDITION 2
If Application.WorksheetFunction.CountA(.Range("D5,D16,D26,D36,D46,D56")) < 6 Then
        MsgBox Msg2
  Exit Sub
End If
'CONDITION 3
      Select Case .Range("Q8")
         Case Is <= "3"
           MsgBox "Coucou1"  'wordini.Show
         Case Is > 3
             MsgBox "Coucou2" 'worperf.Show
      End Select
End With
End Sub

Bonne journée
Amicalement
Jean Marie

 

[tototiti2008]

Re : Bouton macro avec trois conditions

Bonjour Tallia, Bonjour Pierrot, Bonjour Chti,

OK, j'ai enfin compris (Merci Pierrot)
Ou sans Exit Sub

Sub Rectangle70_QuandClic()
'CONDITION 1
If Range("B1").Value = "" Then 
MsgBox ("Veuillez saisir votre identité ci-dessus dans la cellule B1 merci.")
'CONDITION 2
ElseIf application.counta(Range("D5,D16,D26,D36,D46,D56")) <6 Then 
MsgBox ("Attention vous n'avez pas répondu à toutes les questions")
'CONDITION 3
ElseIf Range("Q8").Value <= 3 Then 
wordini.Show
elseIf Range("Q8").Value > 3 Then 
worperf.Show
end if
End Sub

 

[tallia64]

Re : Bouton macro avec trois conditions

Bonjour à vous tous,
Un grand merci pour votre aide et vos macros. J'ai pris la macro de tototiti200 et ça fonctionne parfaitement.
Encore un grand merci.
Bonne journée.
Tallia