Affichage des 0

[Thoms tanauteva]

Bonjour.

J'ai des donnés sous se format 1.1,0E ou 1.10,5E ou 10.1,0E par exemple seulement j'aimerais afficher un format standard qui est le suivant:

00.00,0E soit pour exemple 01.01,0E
Se sont des données GPS.

Il y aurait il une petite solution sans passer par des macros!??

Merci

 

[Thoms tanauteva]

Re : Affichage des 0

J'ai beau chercher dans les formats et je ne trouves rien un petit coup de pouce please

 

[tototiti2008]

Re : Affichage des 0

Bonjour,

si le code GPS est en A1, formule à tester :

=TEXTE(GAUCHE(A1;CHERCHE(".";A1)-1);"00")&"."&TEXTE(STXT(A1;CHERCHE(".";A1)+1;CHERCHE(",";A1)-CHERCHE(".";A1)-1);"00")&DROITE(A1;NBCAR(A1)-CHERCHE(",";A1)+1)

 

[mromain]

Re : Affichage des 0

bonjour,

autre formule testée avec tes 3 exemple:

=SI(TROUVE(".";A1;1)=2;"0"&STXT(A1;1;1);STXT(A1;1;2))&"."&SI(NBCAR(STXT(A1;(TROUVE(".";A1;1)+1);TROUVE(",";A1;1)-(TROUVE(".";A1;1)+1)))=1;"0"&STXT(A1;(TROUVE(".";A1;1)+1);TROUVE(",";A1;1)-(TROUVE(".";A1;1)+1));STXT(A1;(TROUVE(".";A1;1)+1);TROUVE(",";A1;1)-(TROUVE(".";A1;1)+1)))&","&STXT(A1;(TROUVE(",";A1;1)+1);NBCAR(A1)-TROUVE(",";A1;1))

un peu barbare, mais ça a l'air de fonctionner du moins sous 2007

 

[Thoms tanauteva]

Re : Affichage des 0

Merci

Mais hélas j'ai un retour #NAME? quelque soit le type de format
1.10,0E ou 1.1,0E ou 10.1,0E cela ne marche pas.

 

[Tibo]

Re : Affichage des 0

Bonjour,

Il fallait préciser que tu avais une version Anglaise.

Dans la formule de tototiti (que je salue ici), remplace :

TEXTE par TEXT
GAUCHE par LEFT
CHERCHE par SEARCH
STXT par MID
DROITE par RIGHT
NBCAR par LEN

Je crois que j'ai fait le tour

@+

 

[tototiti2008]

Re : Affichage des 0

Bonjour mromain,
Bonjour Tibo,

Voilà, y a plus qu'à traduire

 

[Thoms tanauteva]

Re : Affichage des 0

Merci beaucoup beaucoup beaucoup pour votre aide!

Voici la formule en anglais on ne sais jamais ça peux aider.
=IF(FIND(".";A1;1)=2;"0"&MID(A1;1;1);MID(A1;1;2))&"."&IF(LEN(MID(A1;(FIND(".";A1;1)+1);FIND(",";A1;1)-(FIND(".";A1;1)+1)))=1;"0"&MID(A1;(FIND(".";A1;1)+1);FIND(",";A1;1)-(FIND(".";A1;1)+1));MID(A1;(FIND(".";A1;1)+1);FIND(",";A1;1)-(FIND(".";A1;1)+1)))&","&MID(A1;(FIND(",";A1;1)+1);LEN(A1)-FIND(",";A1;1))

Cordialement

 

[tototiti2008]

Re : Affichage des 0

Re,

Donc je suppose que tu n'as pas testé :

=TEXT(LEFT(A1;SEARCH(".";A1)-1);"00")&"."&TEXT(MID(A1;SEARCH(".";A1)+1;SEARCH(",";A1)-SEARCH(".";A1)-1);"00")&RIGHT(A1;LEN(A1)-SEARCH(",";A1)+1)

c'est un peu plus court...