Verifier que des combobox sont remplies

[biloute91]

Bonjour,

j'ai un USF avec 6 combobox et une textbox. Je souhaite rendre visible la textbox lorsque l'utilisateur a rempli l'ensemble des combobox.

Private Sub TextBox1_Change()
Dim Ctrl As Byte
For Ctrl = 1 To 6
If Controls("Combobox" & Ctrl).Value <>  "" Then
TextBox1.Visible = true
Else: TextBox1.Visible = false
End If
    Next Ctrl
    
End Sub

Le code ci-dessus ne fonctionne pas

Merci pour votre aide

 

[Minick]

Re : Verifier que des combobox sont remplies

Salut,

Tu t'es trompe d'evenement et de control.

Il faut verifier au changement des Combobox et pas de la TextBox

 

[Minick]

Re : Verifier que des combobox sont remplies

Re,
Avec un exemple

Option Explicit

Private Sub ComboBox1_Change()
    Call VerifCombo
End Sub

Private Sub ComboBox2_Change()
    Call VerifCombo
End Sub

Private Sub ComboBox3_Change()
    Call VerifCombo
End Sub

Private Sub ComboBox4_Change()
    Call VerifCombo
End Sub

Private Sub ComboBox5_Change()
    Call VerifCombo
End Sub

Private Sub ComboBox6_Change()
     Call VerifCombo
 End Sub

Sub VerifCombo()
    Dim Ctrl As Byte
    Dim Afficher As Boolean
    
    Afficher = True
    For Ctrl = 1 To 6
        If Controls("ComboBox" & Ctrl).ListIndex = -1 Then
            Afficher = False
            Exit For
        End If
    Next Ctrl
    
    Me.TextBox1.Visible = Afficher
End Sub

 

[biloute91]

Re : Verifier que des combobox sont remplies

Merci Minick, cela fonctionne

Bonne journée

 

[Cousinhub]

Re : Verifier que des combobox sont remplies

Bonsoir,

juste pour le fun...

un petit fichier, avec un module de classe...

si les 6 comboboxs remplis, le textbox visible, sinon, invisible...

Bonne soirée

Edit, changement du fichier, une petite erreur....