Trouver le numéro d'une colonne avec deux conditions

Pierre42

XLDnaute Nouveau
Bonjour,

J'ai une feuille excel avec en ligne 2 des dates et en ligne 3 des formules. Ces formules me renvoi suivant certaines conditions soit une cellule vide "", soit une somme. Je souhaiterais par le biais d'index et d'equiv connaitre la première date pour laquelle la cellule est non vide et différent de 0.

J'ai utilisé cette formule mais je n'arrive pas à mettre deux conditions à la fonction equiv, ici seul la condition non vide est rempli :

Code:
=INDEX(C2:N2;EQUIV(VRAI;(C3:N3<>"");0))
Avez vous une solution ? Pour ma part je tourne en rond.

Je joint un fichier exemple.
 

Fichiers joints

R@chid

XLDnaute Barbatruc
Re : Trouver le numéro d'une colonne avec deux conditions

Bonjour @ tous,
Code:
=INDEX(C2:N2;MIN(SI((C3:N3>0)*(C3:N3<>"");COLONNE(C:N)-2)))
@ valider par Ctrl+Maj+Entree
@ + +
 

david84

XLDnaute Barbatruc
Re : Trouver le numéro d'une colonne avec deux conditions

Bonjour,
à tester :
Code:
=INDEX(C2:N2;EQUIV(MIN(SI((C3:N3<>"")*(C3:N3>0);COLONNE(C3:N3)));COLONNE(C3:N3);0))
Formule matricielle à valider par Ctrl, Maj et entrée.
A+
 

Dranreb

XLDnaute Barbatruc
Re : Trouver le numéro d'une colonne avec deux conditions

Bonsoir.
Cette formule, validée en matriciel (Ctrl+Maj+Entrée) à l'air de faire l'affaire:
Code:
=INDEX(C2:N2;EQUIV(VRAI;C3:N3+0>0;0))
Cordialement.
 

R@chid

XLDnaute Barbatruc
Re : Trouver le numéro d'une colonne avec deux conditions

Bonjour @ tous,
Bien vu Dranreb,
Apparemment, les dates seront classées par ordre chronologique, alors pourquoi pas,
Code:
=MIN(SI((C3:N3<>"")*(C3:N3>0);C2:N2))
@ valider en Matricielle ==> Ctrl+Maj+Entree
@ +
 

Pierre42

XLDnaute Nouveau
Re : Trouver le numéro d'une colonne avec deux conditions

merci à tous les trois ca fonctionne parfaitement
 

job75

XLDnaute Barbatruc
Re : Trouver le numéro d'une colonne avec deux conditions

Bonjour à tous,

Si les dates sont classées :

Code:
=MIN(SI(ESTNUM(LN(C3:N3));C2:N2))
Si elles ne sont pas classées :

Code:
=INDEX(C2:N2;EQUIV(VRAI;ESTNUM(LN(C3:N3));0))
Toujours avec validation matricielle.

Noter que la 1ère formule "pèse" 39 octets, la 2ème 36 octets...

A+
 

Créez un compte ou connectez vous pour répondre

Vous devez être membre afin de pouvoir répondre ici

Créer un compte

Créez un compte Excel Downloads. C'est simple!

Connexion

Vous avez déjà un compte? Connectez vous ici.

Haut Bas