trop de "si" dans ma formule??

[PtitBichon]

Bonjour,
j'ai un ptit souci avec une formule "si" et malgré les premières indications que j'ai pu trouver sur les précédents posts, je n'ai pas réussi à trouver la solution à mon problème...

Bon, voici ma formule qui devrait me permettre dans un tableau de bord de comparer, au fil des mois la dernière valeur saisie avec celle du mois précécent, pour donner une tendance. J'ai créé une colonne masquer qui me permet de compter les cellules non vide ( et de ce fait savoir lesquelles comparer). Cela marche trs bien pour les trimestres, mais qd j'en rajoute pour faire tous les mois de l'année, ca bug ...

Voici la formule :
=SI(E12=15;SI(T12>S12;"+";"-");SI(E12=14;SI(S12>R12;"+";"-");SI(E12=13;SI(R12>Q12;"+";"-");SI(E12=12;SI(Q12>P12;"+";"-");SI(E12=11;SI(P12>O12;"+";"-");SI(E12=10;SI(O12>N12;"+";"-");SI(E12=9;SI(N12>M12;"+";"-");si(e12=8;si(m12>l12;"+";"-");si(e12=7;si(l12>k12;"+";"-");si(e12=6;si(k12>j12;"+";"-");si(e12=5;si(j12>i12;"+";"-");si(e12=4;si(i12>h12;"+";"-");SI(e12=3;si(h12>g12;"+";"-")"daaaaa")))))))

Y'aurait-il une limite dans le nombre de "si"??
Enfin, comment pourrai-je faire pour afficher une troisième hypothèse, si le chiffre est égal .. donc pas de "+" ou "-"...
J'espère que mon charabiat aura pu être compréhensible, ca fait trois jours que je suis là-dessus et j'ai pas trouvé..

Merci d'avance pour le temps que vous voudrez bien accorder à mon problème..

PtitBichon (en périle lol)

 

[nat54]

Re : trop de "si" dans ma formule??

Limite = 7 SI imbriqués

 

[mjo]

Re : trop de "si" dans ma formule??

Bonjour,

Un début de formule à vérifier :
=SI(INDIRECT(CAR(E12+69)&12)>INDIRECT(CAR(E12+68)&12);"+";"-")

mjo

 

[Gorfael]

Re : trop de "si" dans ma formule??

Bonjour,
j'ai un ptit souci avec une formule "si" et malgré les premières indications que j'ai pu trouver sur les précédents posts, je n'ai pas réussi à trouver la solution à mon problème...

Bon, voici ma formule qui devrait me permettre dans un tableau de bord de comparer, au fil des mois la dernière valeur saisie avec celle du mois précécent, pour donner une tendance. J'ai créé une colonne masquer qui me permet de compter les cellules non vide ( et de ce fait savoir lesquelles comparer). Cela marche trs bien pour les trimestres, mais qd j'en rajoute pour faire tous les mois de l'année, ca bug ...

Voici la formule :
=SI(E12=15;SI(T12>S12;"+";"-");SI(E12=14;SI(S12>R12;"+";"-");SI(E12=13;SI(R12>Q12;"+";"-");SI(E12=12;SI(Q12>P12;"+";"-");SI(E12=11;SI(P12>O12;"+";"-");SI(E12=10;SI(O12>N12;"+";"-");SI(E12=9;SI(N12>M12;"+";"-");si(e12=8;si(m12>l12;"+";"-");si(e12=7;si(l12>k12;"+";"-");si(e12=6;si(k12>j12;"+";"-");si(e12=5;si(j12>i12;"+";"-");si(e12=4;si(i12>h12;"+";"-");SI(e12=3;si(h12>g12;"+";"-")"daaaaa")))))))

Y'aurait-il une limite dans le nombre de "si"??
Enfin, comment pourrai-je faire pour afficher une troisième hypothèse, si le chiffre est égal .. donc pas de "+" ou "-"...
J'espère que mon charabiat aura pu être compréhensible, ca fait trois jours que je suis là-dessus et j'ai pas trouvé..

Merci d'avance pour le temps que vous voudrez bien accorder à mon problème..

PtitBichon (en périle lol)

Salut
On peut s'affranchir de la limite de 7 avec une réfrénce à une cellule, mais ça devient encore plus illisible :
Tu pourrais pas mettre un fichier avec une seule ligne et ce que doit faire tes imbrications de Si, comme tu voudrais ton résultat qu'on essaie de simplifier ta formule ? à vue de nez, ta formule varie en fonction de E12 tu pourrais faire une formule du genre
=(E12=15)*SI(T12>S12;1;-1)+(E12=14)*SI(S12>R12;1;-1)+etc...
avec un format personnalisé de cellule "+";"-";"pas glop, pas glop"

mais ça ne répondrait pas à ton 3ème cas :
T12>S12 =>"+" / T12=S12 => ??? /T12<S12 =>"-"

Donc un exemple avec ce que tu en attends nous aidera à trouver
A+

 

[Monique]

Re : trop de "si" dans ma formule??

Bonjour,

à essayer :
=SI(OU(E12>15;E12<3);"daaaaa";SI((E12=15)*(T12>S12)+(E12=14)*(S12>R12)+(E12=13)*(R12>Q12)+(E12=12)*(Q12>P12)+(E12=11)*(P12>O12)+(E12=10)*(O12>N12)+(E12=9)*(N12>M12)+(E12=8)*(M12>L12)+(E12=7)*(L12>K12)+(E12=6)*(K12>J12)+(E12=5)*(J12>I12)+(E12=4)*(I12>H12)+(E12=3)*(H12>G12)>0;"+";"-"))

L'intérieur des parenthèses est traduit par Excel par VRAI ou FAUX
=(VRAI)*(FAUX) = 0
=(VRAI)*(VRAI) = 1
=(FAUX)*(FAUX) = 0
=(VRAI)*(VRAI)+(FAUX)*(VRAI) = 1

En presque français :
=SI(OU(E12>15;E12<3);"daaaaa";SI(etc etc etc >0;"+";"-"))

Mais un bout de fichier rendrait service.

 

[Monique]

Re : trop de "si" dans ma formule??

Re,

Celle-ci aussi :

=SI(OU(E12>15;E12<3);"daaaaa";SI(DECALER(E12;;E12)>DECALER(E12;;E12-1);"+";"-"))

 

[PtitBichon]

Re : trop de "si" dans ma formule??

Merci pour ces nombreuses réponses que je vais m'empresser d'essayer !!
je vous transmet le fichier "en l'état" en attendant..
Je découvre pleins de fonctions que je ne connaissais pas !! Va falloir que je m'y mette lol !!
Petite explication sur le fichier :
C'est la colonne D qui me pose problème : Elle est cencée comparer les chiffres au fur et à mesure que je les saisie. Pour les trimestres, la feinte marche bien puisque je reste dans le "quota de SI" lol. Tous se complique quand j'ai des valeurs mensuelles qui nécessitent plus de SI...

 

[Gorfael]

Re : trop de "si" dans ma formule??

Merci pour ces nombreuses réponses que je vais m'empresser d'essayer !!
je vous transmet le fichier "en l'état" en attendant..
Je découvre pleins de fonctions que je ne connaissais pas !! Va falloir que je m'y mette lol !!
Petite explication sur le fichier :
C'est la colonne D qui me pose problème : Elle est cencée comparer les chiffres au fur et à mesure que je les saisie. Pour les trimestres, la feinte marche bien puisque je reste dans le "quota de SI" lol. Tous se complique quand j'ai des valeurs mensuelles qui nécessitent plus de SI...

Salut
Plusieurs formules possible
ligne 12 :
=CHOISIR(E12;"val1";"val2";"val3";"val4";"val5";"val6";SI(L12>K12;"+";SI(K12>L12;"-";"rien"));"val8";"val9";"val10";"val11";"val12";"val13";"val14";"val15")
comme il n'y avait que 7 en E12, je n'ai traité que cette valeur et je suis partis sur une autre piste
ligne 17

=SI(INDIRECT(ADRESSE(LIGNE();$E17+5))>INDIRECT(ADRESSE(LIGNE();$E17+4));"+";SI(INDIRECT(ADRESSE(LIGNE();$E17+5))<INDIRECT(ADRESSE(LIGNE();$E17+4));"-";"AAA"))

cette formule me semble mieux convenir (même les intelligents peuvent venir )
indirect("A" & 10) fait référence au contenu de la cellule A10
Adresse(y;x) fait référence à la cellule Colonne X, Ligne Y)
Ligne() fait référence à la ligne en cours
Si E17 = 15, on vérifie le changement entre S17 et T17
Si E17 = 1 on vérifie le changement entre E17 et F17

Pour le troisième cas (stagnation, ni "+", ni "-"), j'ai mis AAA, mais il faut le remplacer par "=" par exemple
A+

 

[Monique]

Re : trop de "si" dans ma formule??

Bonjour,

Non seulement tu as des mois et des trimestres
mais tu as aussi des semestres.

La différence entre la dernière et l'avant dernière cellules contenant une valeur numérique :
=SI(NB(F8:T8)<2;"";RECHERCHE(1;F8:T8)-DECALER(A8;;GRANDE.VALEUR(SI(ESTNUM(F8:T8);COLONNE(F8:T8));2)-1))
Formule matricielle, à valider par ctrl, maj et entrée

Contenu de la dernière cellule numérique :
RECHERCHE(1;F8:T8)
(si tu peux dépasser 100%, tu remplaces 1 (100%) par autre chose de plus grand que 1)

Contenu de l'avant-dernière cellule numérique :
DECALER(A8;;GRANDE.VALEUR(SI(ESTNUM(F8:T8);COLONNE(F8:T8));2)-1)

Format nombre +;-;=
pour positif, négatif et 0

Il n'y a plus besoin de la colonne E
Mais je ne sais pas à quoi correspond « NM »