Tri des onglets

[mutticool]

Bonjour à tous,
Nouvelle sur le forum, je viens vous demander comment peut on trier des onglets dans Excel. Exemple tout simple : mes onglets sont nommés par Nom. Afin de faciliter ma recherche, si ils étaient classés par ordre alphabétique cela me faciliterais ma selection. Merci bcp pour votre aide.

 

[James007]

Re : Tri des onglets

Bonjour,

Ci-dessous, copie de la macro que j'utilise :

Option Explicit 
 
Sub SortWorksheets() 
     
    Dim N As Integer 
    Dim M As Integer 
    Dim FirstWSToSort As Integer 
    Dim LastWSToSort As Integer 
    Dim SortDescending As Boolean 
     
    SortDescending = False 
     
    If ActiveWindow.SelectedSheets.Count = 1 Then 
         
         'Change the 1 to the worksheet you want sorted first
        FirstWSToSort = 1 
        LastWSToSort = Worksheets.Count 
    Else 
        With ActiveWindow.SelectedSheets 
            For N = 2 To .Count 
                If .Item(N - 1).Index <> .Item(N).Index - 1 Then 
                    MsgBox "You cannot sort non-adjacent sheets" 
                    Exit Sub 
                End If 
            Next N 
            FirstWSToSort = .Item(1).Index 
            LastWSToSort = .Item(.Count).Index 
        End With 
    End If 
     
    For M = FirstWSToSort To LastWSToSort 
        For N = M To LastWSToSort 
            If SortDescending = True Then 
                If UCase(Worksheets(N).Name) > UCase(Worksheets(M).Name) Then 
                    Worksheets(N).Move Before:=Worksheets(M) 
                End If 
            Else 
                If UCase(Worksheets(N).Name) < UCase(Worksheets(M).Name) Then 
                    Worksheets(N).Move Before:=Worksheets(M) 
                End If 
            End If 
        Next N 
    Next M 
     
End Sub

A +

 

[SOYA]

Re : Tri des onglets

Bonjour,

Comment fait-on pour trier des onglets dont le nom est numérique (nombre à 6 chiffres) ?

Merci !