syntaxe d'erreur en vba sous excel et PDF dans la même feuille

[bruno66]

bonjour , quand je mets l'ouverture automatisé de fichier sous excel en vba il me marque l'erreur suivante en fichier joint imprim ecran..;





Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
'Si le double clic est fait sur la colonne j
'alors on ouvre le fichier correspondant à la commande
'si il est présent dans le répertoire "profil"
'sinon message d'erreur
If Target.Column = 10 Then

On Error Resume Next
Workbooks.Open ActiveWorkbook.Path & "/commande en cours/" & Target.Value & ".xls"
If Err.Number <> 0 Then
Call MsgBox("Le fichier " & Chr(34) & " " & Target.Value & ".xls " & Chr(34) & " n'éxiste pas dans le répertoire commande en cours.", vbCritical, "Manque fichier commande")
Target.Select
End If
On Error GoTo 0

End If

End Sub


Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
'Si le double clic est fait sur la colonne j
'alors on ouvre le fichier correspondant à la commande
'si il est présent dans le répertoire "profil"
'sinon message d'erreur
If Target.Column = 3 Then

On Error Resume Next
'Workbooks.Open ActiveWorkbook.Path & "/profil/" & Target.Value & ".pdf"
Shell ("D:\Program Files\Adobe\Reader 10.0\Reader\AcroRd32.exe " & ActiveWorkbook.Path & "\Profil PDF\" & Target.Value & ".pdf"), vbMaximizedFocus
If Err.Number <> 0 Then
Call MsgBox("Le fichier " & Chr(34) & " " & Target.Value & ".pdf " & Chr(34) & " n'éxiste pas dans le répertoire Profil pdf.", vbCritical, "Manque fichier profil")
Target.Select
End If
On Error GoTo 0
'D:\Program Files\Adobe\Reader 10.0\Reader\AcroRd32.exe

End If

End Sub

 

[Fred0o]

Re : syntaxe d'erreur en vba sous excel et PDF dans la même feuille

Bonsoir Bruno,

C'est normal que tu aies une erreur de compilation puisque tu as 2 Sub portant le même nom dans la même feuille. Je te propose donc de les regrouper en une seule comme ceci :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
'Si le double clic est fait sur la colonne j
'alors on ouvre le fichier correspondant à la commande
'si il est présent dans le répertoire "profil"
'sinon message d'erreur
    If Target.Column = 10 Then
        On Error Resume Next
        Workbooks.Open ActiveWorkbook.Path & "/commande en cours/" & Target.Value & ".xls"
        If Err.Number <> 0 Then
            Call MsgBox("Le fichier " & Chr(34) & " " & Target.Value & ".xls " & Chr(34) & " n'éxiste pas dans le répertoire commande en cours.", vbCritical, "Manque fichier commande")
            Target.Select
        End If
        On Error GoTo 0
    ElseIf Target.Column = 3 Then
        On Error Resume Next
        'Workbooks.Open ActiveWorkbook.Path & "/profil/" & Target.Value & ".pdf"
        Shell ("D:\Program Files\Adobe\Reader 10.0\Reader\AcroRd32.exe " & ActiveWorkbook.Path & "\Profil PDF\" & Target.Value & ".pdf"), vbMaximizedFocus
        If Err.Number <> 0 Then
            Call MsgBox("Le fichier " & Chr(34) & " " & Target.Value & ".pdf " & Chr(34) & " n'éxiste pas dans le répertoire Profil pdf.", vbCritical, "Manque fichier profil")
            Target.Select
        End If
        On Error GoTo 0
        'D:\Program Files\Adobe\Reader 10.0\Reader\AcroRd32.exe
    End If
End Sub

A+

 

[bruno66]

Re : syntaxe d'erreur en vba sous excel et PDF dans la même feuille

la formule fonctionne a merveille ,quand je pense au possibilités qui me sont faite dans excel par ses formules en double clic c'est énorme
encore merci du coup de main