Supprimer des lignes ?

[DJ FA]

Bonjour, j'aimerais avec une macro qu'elle me supprime les lignes contenant les valeurs : Paris et Vincennes.

 

[Gareth]

Re : Supprimer des lignes ?

Bonsoir,

Voir le fichier joint

 

[DJ FA]

Re : Supprimer des lignes ?

Merci grand chef.

 

[job75]

Re : Supprimer des lignes ?

Bonsoir DJ FA,

Cette macro est très rapide car elle utilise des tableaux :

Sub SupprimerLignes()
Dim plage As Range, t, ncol%, rest(), i&, n&, j%
Set plage = ActiveSheet.UsedRange
If plage.Count = 1 Then Exit Sub 'sécurité
t = plage 'matrice, plus rapide
ncol = UBound(t, 2)
ReDim rest(1 To UBound(t), 1 To ncol)
For i = 1 To UBound(t)
 If InStr(LCase(t(i, 1)), "paris") + InStr(LCase(t(i, 1)), "vincennes") = 0 Then
   n = n + 1
   For j = 1 To ncol
     rest(n, j) = t(i, j)
   Next
 End If
Next
plage = rest
End Sub

Edit : bien sûr c'est fait pour des bases de données importantes.

A+

 

[DJ FA]

Re : Supprimer des lignes ?

Superbe, j'ai ce qu'il me faut., mais juste un détail : si j'ai 60 mots à traiter c'est pareil ?

 

[Gareth]

Re : Supprimer des lignes ?

Re,

Dans la meme veine, voie le fichier joint

 

[DJ FA]

Re : Supprimer des lignes ?

Merci à vous.

 

[job75]

Re : Supprimer des lignes ?

Bonjour DJ FA, Gareth, le forum,

Avec les tableaux :

Option Explicit
Option Base 1 'la numérotation des tableaux commence à 1
Option Compare Text 'la casse est ignorée 'facultatif

Sub SupprimerLignes()
Dim a, ub%, plage As Range, t, ncol%, rest(), i&, j%, n&
a = Array("paris", "vincennes")
ub = UBound(a)
Set plage = ActiveSheet.UsedRange
If plage.Count = 1 Then Exit Sub 'sécurité
t = plage 'matrice, plus rapide
ncol = UBound(t, 2)
ReDim rest(UBound(t), ncol)
For i = 1 To UBound(t)
  For j = 1 To ub
    If InStr(t(i, 1), a(j)) Then GoTo 1
  Next
  n = n + 1
  For j = 1 To ncol
    rest(n, j) = t(i, j)
  Next
1 Next
plage = rest
End Sub

Option Compare Text fait gagner un peu de temps.

A+

 

[DJ FA]

Re : Supprimer des lignes ?

Encore mieux !!