Supprimer 2 valeurs min

[EricSimon]

Je souhaite supprimer les 2 valeurs minimales d'une liste de 8 nombres afin de faire la somme des 6 plus forts.

Merci pour votre aide

 

[jocelyn]

Bonjour le Forum,
Bonjour EricSimon,

Pour ce qui est de supprimer les 2 plus petites valeurs je ne sais pas trop mais en attendant pour te dépanner tu peux faire une formule de ce type qui ne sommera pas les 2 plus petites valeurs.

=SOMME(A1:A8)-PETITE.VALEUR(A1:A8;1)-PETITE.VALEUR(A1:A8;2)

Voila espérant t'avoir aidé un peu

A+
Jocelyn

 

[Sylvie]

Bonjour EricSimon, Le Forum

je pense que tu peux te reporter au lien suivant. Lien supprimé
Monique notamment te livre des formules avec GRANDE.VALEUR te permettant de ne retenir qu'un nombre déterminé de valeurs dans une somme (dans ton cas les 6 + fortes)

Le tout est ensuite d'adapter. Joins eventuellement un bout de fichier pour que l'on puisse de la théorie à la pratique

Sylvie

 

[Monique]

Bonjour,

à valider par ctrl, maj et entrée :
=SOMME(GRANDE.VALEUR(A2:A9;{1;2;3;4;5;6}))
Plus pratique sur une grande plage :
=SOMME(GRANDE.VALEUR(A2:A9;LIGNE(1:6)))
Si les lignes 1:6 risquent d'être supprimées :
=SOMME(GRANDE.VALEUR(A2:A9;LIGNE(INDIRECT('1:6'))))

Si tu as parfois moins de 6 valeurs :
=SOMME(GRANDE.VALEUR(A2:A9;LIGNE(INDIRECT('1:'&MIN(6;NB(A2:A9))))))

Sans savoir si j'ai bien compris la question.

 

[Sylvie]

Re bonjour

tu peux également essayer ceci en disposant tes données en colonne (on prend l'exemple de 8 valeurs dans ta colonne)

=SOMME(A1:A8*(A1:A8>=GRANDE.VALEUR(A1:A8;6)))

Formule matricielle à valider par Ctrl+Maj+Entree

Sylvie

 

[Monique]

Re,

Sylvie, tu n'as pas pensé aux doublons ?
(il n'y en a peut-être pas, en fin de compte)

 

[Sylvie]

Re bonjour,


il me semble que cela fonctionne même avec des doublons. Du moins je n'ai pas d'erreurs dans mon essai.
Brouterais-je les coteaux de l'erreur en te disant cela ?

Sylvie

 

[Monique]

Re,

J'ai des erreurs en cas de doublons (pas dans les 6 premiers nombres)
Fais un essai avec les 8 nb identiques,
un autre avec les 3 plus petits identiques, puis les 4 + petits, etc.

 

[Sylvie]

Rebonjour Monique, le Fil, le Forum,

je te joins un bout de fichier Monique car je n'ai pas d'erreur en colonne A qu'il s'agisse de 8 valeurs identiques, des 3 plus petites valeurs identiques ou des 4.

Je ne comprends pas ... ce que je ne comprends pas !


Sylvie [file name=GdeValeur.zip size=5168]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/GdeValeur.zip[/file]

 

[EricSimon]

Voici la solution que j'ai adopté

1- Je détermine le nb de courses auxquelles le coureur a participé le maxi étant de 8

ensuite je calcule les 2 moins bonnes et je les retranche du total de point
si le coureur a partici^pé à 8 je lui retire les 2 moins bonnes et s'il n'a participé qu'à 7 alors je lui en retire qu'une


voici la formule pour récupérer les min-1 et min-2
min-1
=SI(Y4=8;PETITE.VALEUR((F4;H4;J4;L4;N4;P4;R4;T4);1);SI(Y4=7;PETITE.VALEUR((F4;H4;J4;L4;N4;P4;R4;T4);1);'0'))

min-2
=SI(Y4=8;PETITE.VALEUR((F4;H4;J4;L4;N4;P4;R4;T4);2);'0')


et encore Merci pour vos messages trsè instructifs

 

[Monique]

Re,

Sylvie, je viens de voir ton message et ton fichier.
Je me suis mal exprimée.
C'est cette formule qui donne des résultats faux :
=SOMME(A2:A9*(A2:A9>=GRANDE.VALEUR(A2:A9;6)))

Dans le fichier que tu as posté, elle donne
180, 186 et 200 au lieu de 150, 146 et 150

 

[Monique]

Re,

Eric ou Simon, tu pourrais essayer cette formule :
=SOMME(GRANDE.VALEUR((F4;H4;J4;L4;N4;P4;R4;T4);LIGNE(INDIRECT('1:6'))))
à valider par ctrl, maj et entrée.
Elle t'évite de calculer à part des 2 plus petites valeurs.

Ou bien, si le coureur n'a pas toujours 6 courses ou plus :
=SOMME(GRANDE.VALEUR((F4;H4;J4;L4;N4;P4;R4;T4);LIGNE(INDIRECT('1:'&MIN(6;Y4)))))