SOMMEPROD imbriqué dans formule matricielle

[ACH]

Bonjour,

J’essaie de faire la somme des comptes commençant par 6 et par 7 avec la formule « SommeProd ».
Mais le résultat ne coïncide pas avec ce que j’attendais. J’aimerai aussi intégrer cette formule dans la formule suivante : =-IF(ISNA(INDEX(TableC;MATCH($D250;CompteC;0);MATCH(F$7;DateC;0)))=TRUE;0;(INDEX(TableC;MATCH($D250;CompteC;0);MATCH(F$7;DateC;0))))
Cette formule permet lorsque je sélectionne le mois et le compte de donner le montant concerné. Mon but est donc qu’en sélectionnant le mois, la formule me permettent de calculer la somme des montant repris dans les comptes commençant par 6 et 7 pour le mois concerné.
Je joins également un fichier exemple pour le Sommeprod.

D’avance merci pour votre aide,

ACH

 

[Victor21]

Re : SOMMEPROD imbriqué dans formule matricielle

Bonjour.

Pour le fichier joint :
Essayez en F4 :

=SOMMEPROD(($B:$B)*($A:$A>=60000000)*($A:$A<80000000))

Pour la 2° question... joignez un exemple

 

[excfl]

Re : SOMMEPROD imbriqué dans formule matricielle

Bonjour le forum,

Dans la liste des comptes présentés figurent ceux des classes 5 à 7.

Il serait intéressant d'ajouter ceux des classes 1 à 4 afin d'avoir une vérification :

le résultat du bilan doit être le même que celui du compte de résultat.

 

[ACH]

Re : SOMMEPROD imbriqué dans formule matricielle

Merci pour la réponse, je n'aurais jamais pensé une telle approche (c'est simple de compréhension et ça marche)
Comme demandé, je vous joins un exemple en Excel avec la formule dans laquelle j'aimerais incorporé le sommeprod pour la somme de comptes commençant par 6 et 7 en fonction du mois choisi.

Encore merci

ACH

 

[ACH]

Re : SOMMEPROD imbriqué dans formule matricielle

Merci pour ce beau tableau. Mon objectif est effectivement d'avoir cette égalité bilantaire en incorporant dans le passif le résultat de l'exercice en cours. C'est à cette fin que j'aimerai intégrer dans ma formule de sélection (de la période) la formule de SOMMEPROD.

Cordialement,

 

[excfl]

Re : SOMMEPROD imbriqué dans formule matricielle

Supprimé.

excfl

 

[ACH]

Re : SOMMEPROD imbriqué dans formule matricielle

Merci pour votre réponse.

Je n'arrive cependant toujours pas à ce que ma cellule jaune (D24) me retourne la somme des charges et des produits en fonction du mois selectionné. Le résultat retourné ne correspond pas la somme et ne varie pas suivant la sélection du mois (cellule D6).
Je joins le fichier test1 avec un formule brouillon.

Cordialement

 

[excfl]

Re : SOMMEPROD imbriqué dans formule matricielle

D11 :

=SOMME.SI('X CUMUL'!$B:$B;$B11;'X CUMUL'!C:C)

A tirer vers la droite, puis vers le bas.

Le résultat de l'exercice (dans un compte de résultat) est tout simplement la différence entre le total des produits et celui des charges :

D27 : =D10*-1-D17

Vérification :

D27 :

=SOMMEPROD((CompteC>=70000000)*(CompteC<80000000)*('X CUMUL'!C3:C237))*-1-(SOMMEPROD((CompteC>=60000000)*(CompteC<70000000)*('X CUMUL'!C3:C237)))

A tirer vers la droite.

 

[gosselien]

Re : SOMMEPROD imbriqué dans formule matricielle

Bonjour,

je ne suis pas comptable, mais on peut faire un tcd non (ici les totaux correspondent) mais pas le total puisque les comptes "7" sont en négatif
bon, je dis peut être des conneries aussi ...

 

[Amilo]

Re : SOMMEPROD imbriqué dans formule matricielle

Bonsoir à tous,
En complétant la dernière partie de votre formule avec decaler :

=SOMMEPROD((CompteC>=60000000)*(CompteC<80000000)*(DECALER(CompteC;0;EQUIV($D$6;'X CUMUL'!$C$2:$M$2;0)+1)))

P.S : j'ai volontairement simuler une plage de 12 cellules au cas où d'autres mois venaient à se rajouter dans 2ème onglet
Cordialement

 

[excfl]

Re : SOMMEPROD imbriqué dans formule matricielle

=SOMMEPROD((CompteC>=60000000)*(CompteC<80000000)*(DECALER(CompteC;0;EQUIV($D$6;'X CUMUL'!$C$2:$M$2;0)+1)))

Le résultat en novembre est bon à condition d'être multiplié par -1.
La formule ne peut pas être tirée vers la droite.

Autre formule de vérification : D27 :

=SOMME.SI.ENS('X CUMUL'!C3:C29;'X CUMUL'!$A$3:$A$29;">="&70000000;'X CUMUL'!$A$3:$A$29;"<"&800000000)*-1-SOMME.SI.ENS('X CUMUL'!C3:C29;'X CUMUL'!$A$3:$A$29;">="&60000000;'X CUMUL'!$A$3:$A$29;"<"&70000000)

A tirer vers la droite.

 

[Amilo]

Re : SOMMEPROD imbriqué dans formule matricielle

Re,
Si tel est le souhait de Ach, pouvoir tirer la formule à droite alors il suffit de mettre simplement EQUIV(D$6; en valeur relative dans la formule,
Cdlt

 

[ACH]

Re : SOMMEPROD imbriqué dans formule matricielle

Merci pour toutes vos contributions
C'est étonnant de voir ces approches différentes menant au même résultat

 

[Amilo]

Re : SOMMEPROD imbriqué dans formule matricielle

Bonjour,

C'est étonnant de voir ces approches différentes menant au même résultat

,

Il y a effectivement 2 approches, comptable et mathématique :

- Comptable comme évoqué par excfl : si les charges (comptes de la classe 6) sont supérieures aux produits (comptes de la classe 7), le résultat est une perte donc devrait être précédé du signe –

- Approche mathématique : dans votre fichier, les produits sont précédés par le signe –,
La somme des produits (comptes 7) étant inférieure à la somme des charges (comptes 6), le résultat renvoyé est mathématiquement positif,

Toujours dans votre exemple, les charges étant supérieures aux produits, comptablement, il s'agît donc d’une perte à faire précéder d’un signe –

Ma formule devrait effectivement être multipliée par -1 que je viens de rajouter pour une approche comptable,

=SOMMEPROD((CompteC>=60000000)*(CompteC<80000000)*(DECALER(CompteC;0;EQUIV(D$6;'X CUMUL'!$C$2:$M$2;0)+1)))*-1

Cordialemenr