Somme si avec critere date egal

[nobru26]

Bonsoir,

Je suis en train de paufiner un code et impossible de trouver les bonnes sybntaxes!
J'essaye d'additionner des chiffres dans une colone en fonction de la date d'une autre colone, le tout comparé à la date d'aujourd'hui.

Ci joint l'exemple... mieux qu'un long discours!

@+

=SOMME.SI(A10:A999;ET(ANNEE(Feuil1!A1)=ANNEE(A10:A999);MOIS(Feuil1!A1)=MOIS(A10:A999));B10:B999)

 

[ROGER2327]

Re : Somme si avec critere date egal

Bonsoir nobru26.

Peut-être comme cela ?​

=SOMMEPROD((ANNEE(Feuil1!A1)=ANNEE(A10:A999))*(MOIS(Feuil1!A1)=MOIS(A10:A999));B10:B999)

Bonne nuit.


ℝOGER2327
#7834

Jeudi 19 Clinamen 142 (Saint Barbeau, procureur et Sainte Morue, juste - fête Suprême Quarte)
21 Germinal An CCXXIII, 9,3486h - gainier
2015-W15-5T22:26:12Z

 

[nobru26]

Re : Somme si avec critere date egal

Bonjour et merci! ça marche au top!

Me semblait bien que cela devait se passer par SOMMEPROD...
Pour ma culture y a t'il possibilité de le faire avec SOMME_SI?

Autre question sans rapport, comment faire un sous total avec des certaines cellules en #REF!? Car j'ai des adressages indirects vers des feuilles encore non créées et cela me bug les sous totaux?

Merci

 

[Dugenou]

Re : Somme si avec critere date egal

Bonjour,
Pour la première question, puisque tu es en .xlsx tu dois pouvoir utiliser somme.si.ens qui te permet de spécifier plusieurs critères.
Pour la seconde : fais précéder chaque calcul des données avec indirect de sierreur(ta formule;0)
Cordialement

 

[ROGER2327]

Re : Somme si avec critere date egal

Re...

(...)
Pour ma culture y a t'il possibilité de le faire avec SOMME_SI?
(...)

Je ne sais pas.
Avec SOMME.SI.ENS, on peut :​

=SOMME.SI.ENS(B10:B999;A10:A999;">"&DATE(ANNEE(A1);MOIS(A1););A10:A999;"<"&DATE(ANNEE(A1);MOIS(A1)+1;1))

(...) comment faire un sous total avec des certaines cellules en #REF!?
(...)

=SOMMEPROD(
(ANNEE(A1)=SI(ESTERREUR(A10:A999);0;ANNEE(A10:A999)))
*(MOIS(A1)=SI(ESTERREUR(A10:A999);0;MOIS(A10:A999)))
*SIERREUR(B10:B999;0))

(À valider par Ctrl Maj Entrée !)


Bonne journée.


ℝOGER2327
#7837

Lundi 23 Clinamen 142 (Locus Solus - Vacuation)
25 Germinal An CCXXIII, 3,8260h - pigeon
2015-W16-2T09:10:57Z