Somme.si avec 2 critères

[Roger]

Bonjour à tous,
Êst-il possible d'utiliser une formule Somme.si avec 2 critères ?
Avec Excel 2007, il existe la formule Somme.si.ens.(.......).

Merci d'avance, cette aide serait la bienvenue.
Roger.

 

[jeanpierre]

Re : Somme.si avec 2 critères

Bonjour Roger, re tous,

Tout bête : =SOMME.SI(A1:A14;4)+SOMME.SI(A1:A14;3)

Où 4 et 3 sont les critères. On peut y mettre à la place l'appel aux cellules x ou y tel que

B1 ou B2.... mais sans exemple difficile d'aller plus loin.

Bon dimanche en Belgique.

Jean-Pierre

 

[Roll]

Re : Somme.si avec 2 critères

Bonjour,

C'est possible avec la formule sommeprod()
voir lien ci-joint.

(https://www.excel-downloads.com/threads/somme-si-avec-2-criteres.55907/

 

[jeanpierre]

Re : Somme.si avec 2 critères

Bonjour Roll, re tous,

Pour le moment, je n'ai plus de support d'ouvert (Excel), j'ai bien pensé à Sommeprod, mais en terme de longueur de formule Somme.si est plus court. Maintenant plus rapide, je ne sais.

Bon dimanche aussi.

Jean-Pierre

 

[Roger]

Re : Somme.si avec 2 critères

Salut Jean-Pierre,
Ci-joint, le fichier source de mon petit problème...
Merci d'avance.
Roger.

 

[jeanpierre]

Re : Somme.si avec 2 critères

Re,

Avec : =SOMMEPROD((H5:H8="TK 120")*(J5:J8="COMMANDE")*(G5:G8))

Où Tk 120 et COMMANDE, pourraient être remplacés pas deux cellules de choix avec les identifiants respectifs.

A te lire pour plus.

Jean-Pierre

 

[Roll]

Re : Somme.si avec 2 critères

Bonjour Roger,

une solution avec sommeprod()

Bon dimanche

 

[jeanpierre]

Re : Somme.si avec 2 critères

Bonsoir tous,

Roll, lorsque l'on peut donner une formulation sans encombrer le serveur du Forum, qui, finalement, a, ou va avoir, des limites, il n'est besoin de reposter un fichier, seulement la solution..

Merci et bon dimanche à toi.

Jean-Pierre

 

[Roger]

Re : Somme.si avec 2 critères

Merci Jean-Pierre,
Clair, net et précis...
Cela fonctionne nickel ;-)
Bonne journée.
A+
Roger

 

[Monique]

Re : Somme.si avec 2 critères

Bonjour,

C’est plus mieux comme ça :
=SOMMEPROD((H5:H10="TK 120")*(J5:J10="COMMANDE");G5:G10)

Au cas où il y aurait du texte ou des formules renvoyant "" en colonne G

 

[jeanpierre]

Re : Somme.si avec 2 critères

Bonsoir Monique,

Peux-tu m'expliquer la différence entre *(G5:G10) et ;G5:G10

Merci à toi.... Sur un autre fil, hier, j'ai galéré un peu.... entre moyenne, rang (usine à gaz que je tentais de faire sans pouvoir m'en sortir avec Sommeprod), j'y ai appris beaucoup, utilisable certe, mais pas dans tous les cas...

Je te souhaite bonne soirée.

Jean-Pierre

 

[Monique]

Re : Somme.si avec 2 critères

Re,

Je ne suis pas douée pour ce genre d'explication
C'est la manière de calculer de SommeProd qui fait ça
C'est un peu comme (B6+B7) ou (B6*B7) qui renvoient #VALEUR! s'il y a du texte
SommeProd fait la somme des produits.
Elle se "crée des matrices" {VRAI;FAUX;VRAI;etc} et {4;2;3;etc}
elle fait le produit de chaque ligne, puis le total

En A2:A8 : A, A, A, B, B puis 2 cellules vides
En B2:B8 : 4, 6, 8, 10, 12, puis 2 cellules contenant du texte

=SOMMEPROD((A2:A8="A")*B2:B8)
fait ce calcul :
=SOMMEPROD({VRAI;VRAI;VRAI;FAUX;FAUX;FAUX;FAUX}*{4;6;8;10;12;"texte1";"texte2"})
puis ce calcul :
=SOMMEPROD({4;6;8;0;0;#VALEUR!;#VALEUR!})
ça donne : VRAI*4 + VRAI*6 etc donc #VALEUR!

Si on lui demande seulement de compter, sans faire de somme :
=SOMMEPROD((A2:A8="A")*(B2:B8<>""))
=SOMMEPROD({VRAI;VRAI;VRAI;FAUX;FAUX;FAUX;FAUX}*{VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI})
=SOMMEPROD({1;1;1;0;0;0;0})

Cette formule
=SOMMEPROD((A2:A8="A")*1;B2:B8)
(le *1, c'est pour rendre numérique les FAUX et VRAI, quand il n'y a qu'1 seul critère)
Elle fait ce calcul :
=SOMMEPROD({VRAI;VRAI;VRAI;FAUX;FAUX;FAUX;FAUX}*1;{4;6;8;10;12;"texte1";"texte2"})
puis
=SOMMEPROD({1;1;1;0;0;0;0};{4;6;8;10;12;"texte1";"texte2"})
Et là ça marche, sauf que mon F9 refuse d'aller plus loin

Il y a une page de Laurent Longre sur SommeProd et les autres formules matricielles
Ce lien n'existe plus

 

[jeanpierre]

Re : Somme.si avec 2 critères

Merci à Toi, Monique,

Il est vrai que sur le clavier aussi, ce n'est pas simple...Merci.

Jean-Pierre

Edit : Ce que j'ai voulu dire avec le clavier... c'est que je ne suis pas très didactique non plus....

 

[Anais51]

Re : Somme.si avec 2 critères

Bonjour à tous,

Je suis moi aussi habituée aux formules somme.si.ens() mais là ma version d'Excel est trop ancienne. Je test donc votre formule mais je n'arrive pas à la faire fonctionner j'ai un "erreur nombre" qui apparait dans mes cellules. J'essai donc sur une version simplifié test pour m'entrainner:

E F G H

1 5 A 1
1 4 B 1
1 3 A 1
1 5 B 1
1 4 A 1
2 3 B 1
2 5 A 1
2 4 B 1
2 3 A 1
2 5 B 1

dans une cellule j'ai mis ceci: (en gros je veux la somme des cellules de la colonne H, si dans E = 1, dans F à 5 et dans G à A.

=SOMMEPROD((E12:E21="1")*(F12:F21="5")*(G12:G21="A")*H12:H21)

Mais même là j'obtiens 0 alors que je devrais obtenir 1.

Quelqu'un peut-il m'expliquer ce qui cloche?
Sinon il me semblait qu'avec une formule matricielle on pouvait aussi y arriver mais je ne les maitrise pas vraiment
Merci par avance

 

[JBOBO]

Re : Somme.si avec 2 critères

Bonjour,

Peux tu tester :

=SOMMEPROD((E12:E21=1)*(F12:F21=5)*(G12:G21="A")*(H12:H21))