XL 2019 Somme en fonction de plusieurs critères

[team18fr]

Bonjour à tous,

Je cherche comment faire pour faire la somme suivant 2 critères. le premier une lettre et le deuxième une couleur et le tous sur plusieurs feuilles.
Sur le fichier joint dans l'onglet résultat je cherche à avoir la somme de toute les cellules A en vert, B et C.
J'arrive à faire la somme des cellules avec les lettres mais seulement sur une seule feuille et lorsque que je rajoute le critère couleur, ça ne marche pas.
Merci d'avance pour votre aide.

 

[job75]

Bonjour team18fr, le forum,

Function MaSomme#(txt$)
Application.Volatile
Dim nf$, coul&, w As Worksheet, c As Range
nf = Application.Caller.Parent.Name
coul = Application.Caller.Interior.Color
For Each w In Worksheets
    If w.Name <> nf Then
        For Each c In w.UsedRange
            If c.Row > 1 Then If c(0) = txt And IsNumeric(c) Then _
                If c.Interior.Color = coul Then MaSomme = MaSomme + CDbl(c)
        Next c
    End If
Next w
End Function

A+

 

[team18fr]

Bonjour et merci pour ton aide.
Ta macro fonctionne très bien mais je ne vais pas rechercher que des A ou des B mais aussi des 17N, 18N ou 17J et la ça marche plus.

Encore merci je viens de comprendre c'est vraiment top.
@+

 

[team18fr]

Bon mon fichier est trop gros et le calcule automatique le fait ramer.
Si je veut faire un bouton je met le code dans la feuille de résultat ?

 

[job75]

Bonjour team18fr,

Bon mon fichier est trop gros et le calcule automatique le fait ramer.

Pour arranger un peu les choses voyez ce fichier (2) :

- la fonction MaSomme a été rendue non volatile en supprimant Application.Volatile

- le bouton Calcul a été créé avec sa macro :

Private Sub CommandButton1_Click() 'bouton Calcul
With Application
    .ScreenUpdating = False: .Calculation = xlCalculationManual: .EnableEvents = False
    With [A2:C2] 'à adapter
        .Formula = "=Masomme(A1)"
        .Value = .Value 'supprime les formules
    End With
    .Calculation = xlCalculationAutomatic: .EnableEvents = True
End With
End Sub

A+

 

[team18fr]

Merci pour ton aide c'est vraiment top.

 

[team18fr]

Bonjour,
Je reviens vers vous car j'ai fais un deuxième fichier à l'identique de mon premier en collant les même formule et il ne veut pas fonctionner. Lorsque je clique sur mon bouton il m'indique "Erreur d'exécution 13: incompatibilité de type" et quand je fais Débogage il me renvoi sur le module sur cette ligne en jaune

If c(0) = txt And IsNumeric(c) Then _

et sur le "c" j'ai "c=erreur 2007" et je ne sais pas à quoi cela correspond.

 

[job75]

Bonjour team18fr, le forum,

Le bug est dû au fait que la cellule c(0) contient une valeur d'erreur (2007 => #DIV/0!)..

Pour l'éviter remplacez :

If c.Row > 1 Then If c(0) = txt And IsNumeric(c) Then _

par :

If c.Row > 1 Then If CStr(c(0)) = txt And IsNumeric(c) Then _

A+

 

[team18fr]

Merci ça fonctionne super bien mais je ne comprends pas quand tu dis que la cellule c(0) contient une valeur d'erreur (2007 => #DIV/0!) il n'y a pas de cellule C0 ?

 

[job75]

c(0) c'est la même chose que c(0, 1) => cellule au-dessus de la cellule c.

 

[team18fr]

Merci pour ton aide je comprends mieux.

 

[team18fr]

Bonjour,
Je me permets de réutiliser mon post, car au lieux de compter des chiffre qu'il y a dans les cellules, je voudrais compter le nombre de fois ou il y a le texte "ess". C'est possible en modifiant cette même formule ?

 

[job75]

Bonjour team18fr,

je voudrais compter le nombre de fois ou il y a le texte "ess".

Ce n'est pas clair, joignez le fichier avec plusieurs valeurs "ess" et les résultats attendus.

A+

 

[team18fr]

Encore merci pour ton aide et la au lieu de compter le chiffre qui est sous la couleur verte dans le fichier plus haut, je voudrais pouvoir compter tout les "ess" qui sont dans la couleur jaune par exemple, mais toujours en fonction de la cellule du dessus.

@+

 

[job75]

Voyez ce fichier (3) avec les 2 fonctions VBA Masomme1 et Masomme2.