Somme de la valeur des codes de toutes les lettres d'un prénom.

[OliDay5]

Bonjour à tous...
Je me dois de créer un code unique pour une liste de noms et prénoms d'une gestion de crèche.
Comme il est possible qu'il y ai des jumeaux avec des prénoms proches.

Duduche Laïla et Duduche Leïla par exemple, la seule possibilité est de comptabiliser la valeur de chaque lettre du prénom , et d'en faire une somme.

Est il possible en une seule formule d'additionner le code de chaque lettre du prénom ?

Je sèche la...

Merci d'avance en tout cas...

 

[Tibo]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Bonjour,

Une approche, à condition d'éviter les caractères accentués :

=SOMMEPROD(CODE(STXT(MAJUSCULE(SUBSTITUE(A1;" ";""));LIGNE(INDIRECT("1:"&NBCAR(MAJUSCULE(SUBSTITUE(A1;" ";"")))));1))-64)

Je te laisse tester

@+

 

[Victor21]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Bonjour, Oliday5, Tibo.

la seule possibilité est de comptabiliser la valeur de chaque lettre du prénom , et d'en faire une somme.

Pas sûr que cette méthode garantisse un nombre unique...
Essaie avec :
Iannis Xenakis, Narciso Yepes.

Et pour les prénoms seuls :
ALBERT
ALIZEE
ANNAIS
ARCHIBALD
BERTHE
DANNY
DJAMILAH
JEANINE
JESSE
KARINE
LILY
NICOLE
PEDRO
REGINE
REGIS
ROBIN
SONIA
TINO
TONI

 

[OliDay5]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

La règle que j'applique est la date inversée AAMMJJ+code première lettre du prénom+code première lettre du nom+Somme des lettres du prénom.
Ce qui fait que des jumeaux avec un prénom presque pareil ne peut qu'être différent...

 

[Victor21]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Re,

Ce qui fait que des jumeaux avec un prénom presque pareil ne peut qu'être différent...

Sauf si les jumeaux s'appellent Tino et Toni, ou Archibald et Annais, ou...
Et, bien que je te concède que ce type de cas ne doit pas être très fréquent, il peut cependant se produire.

 

[OliDay5]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Mille excuses..., cela fonctionne bel et bien... Merci pour votre aide !

 

[OliDay5]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Re,



Sauf si les jumeaux s'appellent Tino et Toni, ou Archibald et Annais, ou...
Et, bien que je te concède que ce type de cas ne doit pas être très fréquent, il peut cependant se produire.

J'ai fait une formule de détection de doublons de ces code dans toutes la liste des enfants ce qui me prémuni d'un quelconque doublon... Merci de vous être penché sur ce soucis en tout cas...

 

[13GIBE59]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Bonjour à tous.

Heu...Tibo, je sais que tu es seul sur ta planète Formula, mais il serait intéressant que tu expliques au forum, et pas que pour moi !, cette super formule d'extra terrestre :

=SOMMEPROD(CODE(STXT(MAJUSCULE(SUBSTITUE(A1;" ";""));LIGNE(INDIRECT("1:"&NBCAR(MAJUSCULE(SUBSTITUE(A1;" ";"")))));1))-64)

Merci d'avance.

 

[Tibo]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Salut Jean-Bernard,

J'ai légèrement allégé la formule (en supprimant un MAJUSCULE) et qui devient :

=SOMMEPROD(CODE(STXT(MAJUSCULE(SUBSTITUE(A1;" ";""));LIGNE(INDIRECT("1:"&NBCAR(SUBSTITUE(A1;" ";""))));1))-64)

Petite tentative d'explication :

le coeur de la formule se trouve ici :

LIGNE(INDIRECT("1:"&NBCAR(SUBSTITUE(A1;" ";""))))

Cette formule retourne une matrice qui va de 1 à x (x étant le nombre de lettres du prénom). Avec le prénom Alexandre en A1, la matrice retournée donne :

{1;2;3;4;5;6;7;8;9}

Cette matrice va me servir comme 2ème paramètre dans une fonction STXT :

STXT(MAJUSCULE(SUBSTITUE(A1;" ";""));LIGNE(INDIRECT("1:"&NBCAR(SUBSTITUE(A1;" ";""))));1)

qui retourne, toujours avec le prénom Alexandre :

{"A";"L";"E";"X";"A";"N";"D";"R";"E"}

Reste à utiliser la fonction CODE pour obtenir le code ASCII de chaque lettre et à en déduire 64 pour avoir 1 pour A et 26 pour Z :

CODE(STXT(MAJUSCULE(SUBSTITUE(A1;" ";""));LIGNE(INDIRECT("1:"&NBCAR(SUBSTITUE(A1;" ";""))));1))-64

qui donne la matrice suivante :

{1;12;5;24;1;14;4;18;5}

et enfin, SOMMEPROD fait le reste en additionnant ces différentes valeurs.

Comme je l'avais indiqué, i y a une contrainte : les prénoms avec accents, les prénoms composés avec un tiret.

Pour gérer ces contraintes, je pense que la voie du VBA est celle qui s'impose.

Voilou

@+

 

[OliDay5]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Effectivement cela fonctionne très bien, cependant elle fonctionne d'autant mieux que je n'ai pas de soucis avec les caractères accentués, ni les prénoms comportant un tiret.
Pour moi, le code d'un espace, d'un tiret, d'un caractère, c'est une valeur comme un autre qui peut entrer en ligne de compte dans mon calcul...
Non ?

 

[13GIBE59]

Re : Somme de la valeur des codes de toutes les lettres d'un prénom.

Merci Tibo !

Celle-là, je l'ai imprimée, pour la relire moultes fois avant de la comprendre...Quelques semaines suffiront.

Juste une question, pour me sidérer encore plus : en combien de temps tu as trouvé une formule pareille ?