Simplifier une formule

[MAZETTE]

Hello à tous,


Je refait un petit tour sur le forum pour simplifier une formule...

L'idée est la suivante:comment implifier la fromule ci dessous:


(H6+M6+R6+W6+AB6+AG6+AL6+AQ6+AV6+BA6+BF6+BK6+BP6+BU6+BZ6+CE6+CJ6+CO6+CT6+CY6+DD6+DI6+DN6+DS6+DX6+EC6+EH6+EM6+ER6+EW6+FB6+FG6+FL6+FQ6+FV6+GA6+GF6+GK6+GP6+GU6+GZ6+HE6+HJ6+HO6+HT6+HY6+ID6+II6+IN6+IS6);0)

Sachant que je veux faire la somme toutes les valeurs se trouvant à la ligne 6 de toute les 5ème colonne.


Merci à vous

 

[Tibo]

Re : Simplifier une formule

Bonjour,

Tu peux essayer :

=SOMMEPROD((H6:IS6)*(MOD(COLONNE(H6:IS6);5)=3))

@+

 

[MAZETTE]

Re : Simplifier une formule

Salut Tibo

Peux-tu m'expliquer ta formule s'il te plait....histoire de combler mon ignorance...

Merci à toi

 

[Tibo]

Re : Simplifier une formule

re,

La fonction MOD retourne le reste d'une division.

MOD(COLONNE(H6:IS6);5)=3 va créer une matrice de VRAI et de FAUX

VRAI quand le reste de la division du rang de la colonne par 5 donne 3
FAUX quand le reste de la division du rang de la colonne par 5 est différent de 3

Pour Excel VRAI = 1 et FAUX = 0

Reprenons la formule complète :

=SOMMEPROD((H6:IS6)*(MOD(COLONNE(H6:IS6);5)=3))

Excel va multiplier et additionner (avec SOMMEPROD) chaque valeur de H6:IS6 par VRAI (donc 1) pour les colonnes dont le reste de la division donne 3 et par FAUX (donc 0) pour les autres colonnes.

Une multiplication par 0 donnant depuis longtemps toujours 0, seules les colonnes qui t'intéressent seront additionnées.

Voila pour la tentative d'explication.

Pas sûr quand même d'avoir été assez clair ...

@+

 

[MAZETTE]

Re : Simplifier une formule

Re tibo,

Je pense avoir saisie une partie de ton explication.

J'ai un doute sur un truc...à savoir "=3"

Pourquoi avoir choisi 3?

Merci à toi

 

[Tibo]

Re : Simplifier une formule

re,

Parce que tu commences en colonne H, ce qui équivaut à la colonne 8

Or 8 / 5 = 1 et reste 3

et si tu fais le calcul avec les colonnes qui t'intéressent, le reste de la division par 5 te donnera toujours 3

Voilou

@+