Selectionner et copier des fichiers jpg depuis une liste excel

[pouloucarine]

Bonjour,

j'ai une un fichier excel dans lequel dans une colonne, j'ai une liste d'ean (format nombre)

Dans un répertoire fixe de mon réseau, j'ai des milliers de fichiers .jpg intitulé ean.jpg

J'ai régulièrement besoin de pouvoir sélectionner à partir d'une liste restreinte d'ean les fichiers ean.jpg correspondant et les copier dans un répertoire de mon choix (support amovible possible)

Aujourd'hui, je perds un temps fou à faire cette recherche en manuel, et je souhaiterai pouvoir faire une macro qui permette cette automatisation.

Est-ce possible ?

Merci de votre aide

Cordialement

 

[job75]

Re : Selectionner et copier des fichiers jpg depuis une liste excel

Bonjour pouloucarine, bienvenue sur XLD,

Quant on connaît FileCopy c'est élémentaire :

Sub CopierFichiers()
Dim r As Range, DosSource$, DosDestin$, ext$
Set r = [A2:A20] 'plage avec les noms des fichiers (sans extension)
DosSource = "C:\Fichiers JPG\" 'à adapter
DosDestin = "C:\Fichiers JPG sélectionnés\" 'à adapter
ext = ".jpg"
Application.DisplayAlerts = False
On Error Resume Next
MkDir DosDestin 'crée le dossier s'il n'existe pas
For Each r In r
FileCopy DosSource & r & ext, DosDestin & r & ext
Next
End Sub

A+

 

[pouloucarine]

Re : Selectionner et copier des fichiers jpg depuis une liste excel

Super,

merci pour la réponse rapide.

Je teste de suite

Cordialement

 

[pouloucarine]

Re : Selectionner et copier des fichiers jpg depuis une liste excel

Ca marche très bien, je n'ai juste pas de message à la fin pour me dire que l'opération est terminée, mais je vais trouver la réponse

Merci encore

Cordialement

 

[job75]

Re : Selectionner et copier des fichiers jpg depuis une liste excel

Re,

Inscription de "OK" en colonne B si la copie est faite et message à la fin :

Sub CopierFichiers()
Dim P As Range, DosSource$, DosDestin$, ext$, c As Range
Set P = [A2:A20] 'plage avec les noms des fichiers (sans extension)
DosSource = "C:\Fichiers JPG\" 'à adapter
DosDestin = "C:\Fichiers JPG sélectionnés\" 'à adapter
ext = ".jpg"
Application.DisplayAlerts = False
On Error Resume Next
MkDir DosDestin 'crée le dossier s'il n'existe pas
For Each c In P
  FileCopy DosSource & c & ext, DosDestin & c & ext
  c(1, 2) = IIf(Dir(DosDestin & c & ext) = "", "", "OK")
Next
MsgBox Application.CountA(P.Offset(, 1)) & " fichiers copiés"
End Sub

A+

 

[job75]

Re : Selectionner et copier des fichiers jpg depuis une liste excel

Re,

Sur Excel 2003 Application.DisplayAlerts = False est inutile, pas testé sur Excel 2010.

Edit : c'est inutile aussi sur Excel 2010.

A+

 

[pouloucarine]

Re : Selectionner et copier des fichiers jpg depuis une liste excel

Tout fonctionne, le ok à coté de ma colonne EAN c'est super.

Merci

A+