sélection nombreuses lignes et colonnes

[stagiairee]

Bonjour,

J'ai un tableau colossal de différentes données de qualité des eaux sur des stations de mesures sur une région entière.
Je souhaite sélectionner seulement les stations présentes sur 225 communes. Sachant qu'il y a plusieurs stations de mesures pour une seule commune.
Comment je peux croiser le tableau de mes communes avec ce gros tableau regroupant toutes les données?

Merci

 

[Lolote83]

Re : sélection nombreuses lignes et colonnes

Salut Stagiaire,
Tout d'abord, bonjour et bienvenue sur le forum.
Pour commencer, et je vois que c'est ton premier post, il sera difficile de te donner une réponse claire et précise sans avoir sous les yeux un exemple avec un fichier joint (Si celui-ci contient des données confidentielles, fais simplement une copie ou tu saisies des données bidons) et tu donnes ensuite un maximum d'explications sur ce que tu veux obtenir.
@+ Lolote83

 

[stagiairee]

Re : sélection nombreuses lignes et colonnes

Merci pour tes conseils mais je ne vois pas comment insérer un fichier mis à part une image, un lien ou une vidéo...

 

[Lolote83]

Re : sélection nombreuses lignes et colonnes

Salut,
Un peu plus bas tu as accès à "Gerer les pièces jointes"
Cordialement
@+ Lolote83

 

[stagiairee]

Re : sélection nombreuses lignes et colonnes

Bonjour,
J'ai joins un fichier où je n'ai laissé que quelques données.
On voit qu'il y a plusieurs lignes (en réalité il y en a bien plus que dans ce fichier) pour une seule ville.
J'ai 225 villes à sélectionner sur toutes celles qui sont présentes dans ce fichier (je sais d'avance que parmi mes 225 villes, seulement certaines seront retrouvées dans ce fichier, mais je ne sais pas lesquelles...)
Je souhaite donc extraire toutes les données (colonnes+lignes) pour les 225 villes.

J'espère mettre faite comprendre,
Merci!

 

[Lolote83]

Re : sélection nombreuses lignes et colonnes

Re salut,
Merci pour le fichier, mais je n'ai pas tout compris dans ta demande.

J'ai 225 villes à sélectionner

Quelles sont elles ?
En fait, de ce que j'ai cru comprendre, tu souhaites extraire toutes les données de 225 villes parmi "x" villes contenues dans ce fichier, d’où ma question.
L'extraction doit-elle concerner :
- la totalité des 225 villes ?
- Une ville parmi 225 villes ?
- Quelques villes parmi les 225 villes ?
Bref, ce n'est pas clair
@+ Lolote83

 

[stagiairee]

Re : sélection nombreuses lignes et colonnes

Mes 225 communes sont dans ce nouveau fichier joins
Je dois retrouver dans le premier fichier (qual_coupé) ces 225 communes, (qui ne sont en réalité pas toute présentes).
En gros je travaille sur un territoire de 225 communes, des points de mesures sont faits sur certaines de ces communes mais pas toutes, et les résultats de ces points sont retrouvés dans le fichier qual_coupé.
Donc dans le fichier qual_coupé je dois retrouver certaines des 225 communes qui concernent mon territoire

 

[chris]

Re : sélection nombreuses lignes et colonnes

Bonjour

Comme Lolote83 que je salue, je ne suis pas sûre de comprendre la demande.

Sélectionner veut-il dire filtrer dans ton esprit ?

Si oui et si le tableau contient des données pour plus de 255 communes et que tu ne veux donc voir que les données de ces 255, mets en concordance le titre des colonnes Code commune dossier BSS ou INSEE_COM si c'est bien la même info et utilise les codes de ta liste de communes comme zone de critères pour faire un filtre avancé.

Ici pas de points communs entre tes deux listes, donc difficile d'illustrer l'exemple...

 

[stagiairee]

Re : sélection nombreuses lignes et colonnes

Bonjour,
Je vous remercie, effectivement le filtre avancé parait correspondre à mes besoins!
je ne connaissais pas cette fonctionnalité...

 

[Aimo Rauidos dit AieAie]

Re : sélection nombreuses lignes et colonnes

on peut aussi faire un tableau croisé dans ce ceas. Cordialement




"la constipacion no es tu amigo"

 

[chris]

Re : sélection nombreuses lignes et colonnes

Bonjour

on peut aussi faire un tableau croisé dans ce ceas. Cordialement

Un TCD ne sert pas à filtrer des lignes détaillées mais à les synthétiser statistiquement

Même en le détournant de sa vocation, filtrer manuellement les 255 villes souhaitées... je ne vois pas bien l'intérêt.

 

[klin89]

Re : sélection nombreuses lignes et colonnes

Bonsoir à tous,

Si j'ai bien pigé le problème
Pour faire simple, j'ai placé tes données dans le même classeur.
En Feuil2, la liste de tes communes comme tu l'as présentée.
En Feuil1, les données à extraire en s'appuyant sur la colonne 9
En Feuil3, restitution du résultat.

Sub Mes_Communes()
Dim a, i As Long, j As Long, n As Long
    Sheets("Feuil3").Cells.Clear
    With Sheets("Feuil2")
        a = .Range("b1", .Range("b" & Rows.Count).End(xlUp)).Value
    End With
    With CreateObject("Scripting.Dictionary")
        For i = 2 To UBound(a, 1)
            .Item(a(i, 1)) = Empty
        Next
        With Sheets("Feuil1")
            a = .Range("a1").CurrentRegion.Value
        End With
        n = 1
        For i = 2 To UBound(a, 1)
            If .exists(a(i, 9)) Then
                n = n + 1
                For j = 1 To UBound(a, 2)
                    a(n, j) = a(i, j)
                Next
            End If
        Next
        'Restitution en Feuil3
        If n > 1 Then
            With Sheets("Feuil3").Range("a1")
                .Resize(n, UBound(a, 2)) = a
                With .CurrentRegion
                    .Font.Name = "calibri"
                    .Font.Size = "10"
                    .VerticalAlignment = xlCenter
                    .Borders(xlInsideVertical).Weight = xlThin
                    .BorderAround Weight:=xlThin
                    With .Rows(1)
                        .Interior.ColorIndex = 42
                        .BorderAround Weight:=xlThin
                    End With
                    .Columns.AutoFit
                End With
                .Parent.Activate
            End With
        Else
            MsgBox "Aucune donnée"
        End If
    End With
End Sub

klin89