Selection de cellules [Macro]

[Benzema]

Bonjour a tous,

J'ai un probleme relativement simple:

Je veux realiser une macro realisant 1 graph. Avant il faut que je selectionne les cellules du tableau pour ce graph.

le nombre de cellules du tableau peut changer a chaque fois, pour les selectionner je sais que la premiere cellule est en A31 tout le temps et la derniere est la cellule precedent la cellule contenant "not implemented".

Je precise de les valeurs sont toutes sur la colonne A.


Merci de votre aide pour realiser cette macro de selection, je suis sur que l'on peut y arriver facilement, mais je suis encore debutant!

Cordialement Clement

 

[Pierrot93]

Re : Selection de cellules [Macro]

Bonjour,

essaye ainsi, à noter qu'en vba il est rarement utile d'effectuer des sélections...

Sub test()
Dim x As Range, z As Range
Set x = Range("A:A").Find("not implemented", , xlValues, xlWhole, , , False)
If Not x Is Nothing Then
    Set z = Range("A31", x.Offset(-1, 0))
    z.Select
End If
End Sub

bonne journée
@+

 

[Benzema]

Re : Selection de cellules [Macro]

Ca a l'air top ! Je test ta solution merci beaucoup.

Tu parles de selection, mais pour faire 1 graphe je suis bien obliger de selectionner les donnees a tracer en X et Y ?

Bonne journee et encore merci

 

[Pierrot93]

Re : Selection de cellules [Macro]

Re,

un exemple de création de graph sur feuille de calcul sans sélection :

Sub CreationGraphique()
Dim c As ChartObject
Set c = Feuil1.ChartObjects.Add(Range("G15").Left, Range("G15").Top, 300, 200)
With c.Chart
    .ChartType = xlLineMarkers
    .SeriesCollection.Add Range("C1:C17"), , True
    .SeriesCollection(1).XValues = Range("A2:A17")
    With .Legend
        .Position = xlBottom
        With .Font
            .Size = 8
            .Bold = True
        End With
    End With
    With .ChartTitle
        .Text = "mongraph"
        With .Font
            .Size = 8
            .Bold = True
        End With
    End With
    With .Axes(xlCategory).TickLabels
        .Font.Size = 8
        .NumberFormat = "dd/mm/yy"
        .Orientation = 45
    End With
    .Axes(xlValue).TickLabels.Font.Size = 8
End With
End Sub

 

[Benzema]

Re : Selection de cellules [Macro]

Merci !

Donc si j'ai bien compris tu as les valeurs A2 -->A17 sur l'axe X

et pour l'axe Y C1-->C17 ?

Pourquoi on utilise la valeur de G15 quand tu declare le graph ?

"Set c = Feuil1.ChartObjects.Add(Range("G15").Left, Range("G15").Top, 300, 200"

Merci en tout cas je cherche a comprendre ton exemple et je vais m'en inspirer pour faire mon graph =)

 

[Pierrot93]

Re : Selection de cellules [Macro]

Re

je me réfère aux coordonnées de G15 pour positionner le graph, dans l'éditeur vba, touche de fonction F1 lorsque le curseur est placé sur le mot "add", te donnera les différents arguments....

 

[Benzema]

Re : Selection de cellules [Macro]

J'ai compris les differents parametres, ca m'aide bien merci !

Sinon en utilisant ton code comment puis je afficher le graphique dans 1 autre feuille pour ne pas encombrer le tableau ?

Merci

Clem

 

[Pierrot93]

Re : Selection de cellules [Macro]

Bonjour,

modifie cece :

With Sheets("NomFeuille")
    Set c = .ChartObjects.Add(.Range("G15").Left, .Range("G15").Top, 300, 200)
End With

bonne journée
@+

 

[Benzema]

Re : Selection de cellules [Macro]

Tout marche nickel merci bien, jai juste 1 detail a regler pour adapter ma macro a tout type de tableau :comment grace a ton code pr trouver la derniere case :"not implemented", je peux renvoyer au moment de la saisie des Xvalue l'adresse de la case juste avant ?

Merci, jai presque resolu le probleme mais je me heurte a des problemes de syntaxe..🙁

 

[Pierrot93]

Re : Selection de cellules [Macro]

Re,

c'est la cellule trouvée suite au code d'hier à 10h26 :

Set z = Range("A31", x.Offset(-1, 0))

en l'occurence identifiée ici par z....

 

[Pierrot93]

Re : Selection de cellules [Macro]

Re,

pour l'adresse essaye avec :

z.Address

@+

 

[Benzema]

Re : Selection de cellules [Macro]

.SeriesCollection(1).XValues = Range("A31", z.Address)


Mon probleme est ici ou est l'erreur ?

merci pour ton aide 🙂

@++

 

[Pierrot93]

Re : Selection de cellules [Macro]

Re,

essaye tout simplement ceci :

.SeriesCollection(1).XValues = z

ou bien :

.SeriesCollection(1).XValues = z.Values

 

[Benzema]

Re : Selection de cellules [Macro]

Jai essaye deja, mais quelque chose m'echappe je te joins le fichier si quelqu'un trouve !

Merci

 

[Pierrot93]

Re : Selection de cellules [Macro]

Re,

tu asessayé les 2 propositions de mon dernier post ?