selctionner des cellules avec la même date

[bbobb]

Bonjour le forum,
Encore un fois, j'ai besoin d'aide 🙂 vive le forum !

voilà : en cellule A1 j'ai la date et l'heure qui s'actualise automatiquement.
en colonne 1, à partir de la ligne 3, au fur et mesure que j'agrémente mon tableau, la première cellule vide de la colonne a se remplit automatiquement avec la date et l'heure. jusque là, ça va.

Je cherche à selectionner toutes les cellules du jour (dans le cas présent : toutes les cellules contenant 03/11/12, quelques soit l"heure) en prenant la cellule A1 comme référence.

Je joint un petit fichier.

Merci d'avance

Bbobb

 

[JCGL]

Re : selctionner des cellules avec la même date

Bonjour à tous,

Peux-tu essayer :

Sub Select_Jour()
Dim DerL%
DerL = Range("A65000").End(xlUp).Row
For x = 3 To DerL
If Day(Cells(x, 1)) = Day(Date) Then Cells(x, 1).Interior.ColorIndex = 40
Next
End Sub

A + à tous

Edition : Salut Hervé 😉, Salut Bernard 🙂

 

[Hervé]

Re : selctionner des cellules avec la même date

salut 🙂

à essayer :

Sub selectionjour()
Dim plg As Range
Dim Datejour As Date


Datejour = Cells(1, 1)

For Each c In Range("a3:a" & Range("a65536").End(xlUp).Row)
    If trouvedate(c.Value) = trouvedate(Datejour) Then
        If plg Is Nothing Then
            Set plg = c
        Else
            Set plg = Union(plg, c)
        End If
    End If
Next c

plg.Select

End Sub


Public Function trouvedate(jour As Date) As Date
trouvedate = CDate(Day(jour) & "/" & Month(jour) & "/" & Year(jour))
End Function

a plus


edit : salut JC 🙂

 

[Dranreb]

Re : selctionner des cellules avec la même date

Bonjour.
Comme ça, ça a l'air pas mal:

Sub SélectionJour()
Dim DateJour As Date, L As Long
DateJour = Int(ActiveSheet.Cells(1, 1).Value)
For L = 3 To 65536
   If Int(ActiveSheet.Cells(L, 1).Value) = DateJour Then Exit For
   Next L
Range(ActiveSheet.Cells(L, 1), ActiveSheet.Cells(65536, 1).End(xlUp)).Select
End Sub

À +

Bonjour JCGL, Hervé.

 

[eriiic]

Re : selctionner des cellules avec la même date

Bonjour à tous,

Un peu moins rapide que vous autres mais comme un peu différent je le met :

Sub selDate()
    Dim pl As Range, lig As Long
    For Each c In [A3].Resize(Cells(Rows.Count, 1).End(xlUp).Row - 2, 1)
        If Int(c) = Int([A1]) Then
            If pl Is Nothing Then
                Set pl = c
            Else
                Set pl = Union(pl, c)
            End If
        End If
    Next c
    pl.Select
End Sub

eric

edit: oupsss, j'avais oublié le .End(xlUp)

 

[bbobb]

Re : selctionner des cellules avec la même date

Bonsoir tout le monde et merci beaucoup, n'en jetez plus 🙂
J'ai trouvé mon bonheur dans vos différentes propositions.

encore merci
Bonne soirée
Bbobb

 

[Staple1600]

Re : selctionner des cellules avec la même date

Bonsoir à tous

Sans VBA, avec filtre élaboré et critère formulé
formule en C2 par exemple

=TEXTE(A3;"jj/mm/aa")=TEXTE(AUJOURDHUI();"jj/mm/aa")

Cliquez sur la vignette ci-dessous pour voir la copie d'écran.