[Résolu] Vérifier et compter un nombre de format de cellule date spécifique

[zored]

Bonjour le forum,

Après moult recherche je viens vers vous car je n'ai pas trouvé ce que je cherchais. J'ai plusieurs onglets à chaque fois agencé de la même façon. Dans ces onglets il y a 2 colonnes qui m’intéresse:

date de début et date de fin situé en H et en J (je les ai nommés)

Ces 2 dates doivent être sous le format:
aaaa/mm/jj
par exemple:
20140102
où:
2014 est l'année
01 est le mois
02 est le jour

J'aimerais "compter" le nombre de fois où le format n'est pas bon:
13022014
20142405
20121224

par exemple il y a 2 fois où le format de la date n'est pas bon
j'ai essayer avec ceci:

=SOMME((NB.SI(datedebangers;CELLULE("format"=aaaa/jj/mm;datedebangers)));(NB.SI(datefinangers;CELLULE("format"=aaaa/jj/mm;datefinangers))))

Mais cela me sort un 0 systématiquement(il ne comprends pas le format)

J'espère que j'aurais été clair, je vous remercie d'avance je n'ai pas trouvé la solution

Cordialement
H.

 

[Dranreb]

Re : Vérifier et compter un nombre de format de cellule date spécifique

Bonjour.
Que contiennent exactement vos cellules, des textes composés de chiffres, des nombres ou des dates ?
Ne parlez pas de format: le format de cellule ne change pas si le contenu de la cellule n'est pas bon, il peut juste ne pas être appliqué !
En supposant que ce sont 3 nombres, les ayant mis en J3:J5, cette formule, validée par Ctrl+Majucule+Entrée donne 1 :

=SOMME(N(TEXTE(DATE(ENT($J$3:$J$5/10000);MOD(ENT($J$3:$J$5/100);100);MOD($J$3:$J$5;100));"aaaammjj")+0=$J$3:$J$5))

Et comme ça, toujours validée en matriciel, elle donne 2:

=SOMME(N(TEXTE(DATE(ENT($J$3:$J$5/10000);MOD(ENT($J$3:$J$5/100);100);MOD($J$3:$J$5;100));"aaaammjj")+0<>$J$3:$J$5))

 

[zored]

Re : Vérifier et compter un nombre de format de cellule date spécifique

Bonjour Dranreb,

Merci pour votre réponse

Le format de mes cellules est actuellement en "standard", ce que je cherche c'est effectivement le "type" de "format"

Je n'ai pas compris votre formule (je n'ai pas un super niveau en excel mais j'apprends )



je pensais partir sur quelque chose via:

Fonction CELLULE - Excel - Office.com

On peut y voir une liste de format de cellule, notamment un tableau reprenant des "type" de dates

Je me demandais s'il était possible de rajouter son propre "type" de "format", notamment pour mon cas concernant les "dates"
un peu comme ici où on peut voir un format personnalisé, mais pour un chiffre (ce que je cherche c'est pour une date) j'ai essayer aa/mm/jj, aaaa/mm/jj , aa/m/j ... etc lol je sais plus trop quoi faire

EDIT: j'ai essayé votre formule, mais cela ne fonctionne pas j'ai toujours 0 peu importe le type de format de date dont il s'agit

j'ai une autre question, dans mon tableau chaque ligne contient 10 cellules (dont 2 concernant la date, debut et fin), mon objectif est de compter le nombre de LIGNES où il y a une (ou plus) anomalie:
le problème est que lorsque j'ai 4 erreurs dans la même ligne, j'aimerais compter une seule fois l'erreur.

Concrètement, voici un exemple de la synthèse de l'extraction de la commune NOGENT (j'ai au total 10 communes)



Remarquez le problème:

un OT = une ligne
le total d'anomalie = somme de C4 à C9
Or si une de mes anomalies apparaît sur la même ligne, j'aimerais compter une seule fois l'anomalie, par exemple:
si ma ligne 5 ne contient pas de distance, ni de poids, ni de quantité

j'aimerais compter tout ça en une seule erreur, actuellement ça m'en compte 3

Au final, mon résultat comme par exemple le nombre d'OT en anomalies, sera faussé





Cordialement
H.

 

[Dranreb]

Re : Vérifier et compter un nombre de format de cellule date spécifique

Je n'ai pas compris votre formule

C'est une formule matricielle du fait qu'elle a été validée par la combinaison successivement maintenues appuyées des touches Ctrl, Majuscule (encore appelée Shift) et Entrée, et elle apparait encadrée de "{" et "}" dans la barre de formule. Elle est donc calculée, si nécessaire à chaque étape, autant de fois qu'il y a de cellules dans J3:J5. Par "si nécessaire" j'entends "chaque fois qu'une valeur unique est requise".
ENT($J$3:$J$5/10000) prend la partie entière de chaque cellule divisée par 10000, donc la valeur formée par les 4 iers chiffres. Ce sont en principe les années codées.
MOD(ENT($J$3:$J$5/100);100) prend le reste de la division par 100 de la partie entière de chaque cellule divisée par 100, donc la valeur formée par les 2 chiffres suivants. Ce sont est en principe les mois codés.
MOD($J$3:$J$5;100) prend le reste de la division par 100 de la valeur de chaque cellule, donc la valeur formée par les 2 derniers chiffres. Ce sont en principe les jours codés.
DATE(LesAnnées;LesMois;LesJours) trouve les dates en principe représentées.
TEXTE(LesDatesDePrincipe;"aaaammjj") forme les groupes chiffres qu'on devait avoir s'ils codaient des dates correctes.
LesChiffresQuOnDevraitAvoir+0 convertit ces groupes de chiffres en les nombres qu'on devrait avoir.
LesNombresQuOnDevraitAvoir<>$J$3:$J$5 trouve VRAI si c'est différent, FAUX si c'est pareil.
N(LesVRAIsEtLesFAUX) les convertit en des 1 et des 0.
=SOMME(Les1EtLes0) en fait la somme. Il n'y a plus d'interprétation matricielle à cette toute dernière étape puisque la fonction SOMME n'attend pas une cellule unique, mais le résultat est bien dans une plage matricielle d'une seule cellule.

 

[zored]

Re : Vérifier et compter un nombre de format de cellule date spécifique

Excusez moi, voici un fichier d'exemple

(j'ai essayer d'y appliquer votre formule)

EDIT1: je n'avais pas vu votre réponse, je vais tester merci beaucoup
EDIT2: cela m'indique #VALEUR




merci à vous

EDIT 3: j'ai mis à jour mon fichier joint

EDIT4: cela fonctionne, j'ai voulu faire d'une pierre deux coups en faisant 2 sommes avec votre formule (datedeb et datefin), et cela fonctionnait pas en une seule formule, en revanche cela fonctionne si on le fait 1 à part de l'autre

EDIT5: enfaite non, ça ne fonctionnait pas non plus: la solution était de ne pas nommé ma plage concernée...
EDIT6: enfaite si, ça fonctionnait avec le nom de la plage, mais j'avais nomé mes en-têtes de colonne avec donc forcément...

bref, Sujet résolue, merci !
bonne continuation !

Cordialement,
H.