RESOLU Re : imprimer cellules

[tany]

bonjour à tous,

j'ai sélectionné A1 puis A 7 avec Ctrl
ma macro enregistrée m'imprime bien mais sur 2 feuilles
comment faire pour que ce ne soit que sur une seule feuille ?
A7 à la suite de A1
merci de vos lumières. Bonne journée

Sub Macro1()
'
' Macro1 Macro
'

'
Range("A1,A7").Select
Range("A7").Activate
Selection.PrintOut Copies:=1
End Sub

 

[job75]

Re : imprimer cellules

Bonjour tany, le forum,

Sub Imprimer()
With Feuil1 'CodeName, à adapter
  .Rows("2:6").Hidden = True 'masque
  .PageSetup.PrintArea = "A1:A7"
  .PrintOut
  .Rows("2:6").Hidden = False 'affiche
End With
End Sub

A+

 

[tany]

Re : imprimer cellules

ça marche impeccable, merci le forum
en fait c'est en vue d'imprimer toutes les formules d'une feuille
je demande l'affichage des formules et de l'impression des titres et j'imprime avec cette macro
existe t-il une autre méthode pour ce faire ?
parce que je me rends compte que sélectionner plusieurs cellules dispersées
complique la tâche sérieusement.
en tous cas merci pour ces renseignements

 

[job75]

Re : imprimer cellules

Re,

en fait c'est en vue d'imprimer toutes les formules d'une feuille

Je ne vois pas le rapport avec le problème posé au post #1 mais bon :

Sub ImprimerFormules()
Dim F As Worksheet, c As Range
Set F = ActiveSheet 'ou Feuil1, à voir
Application.ScreenUpdating = False
Application.DisplayAlerts = False
With Sheets.Add 'feuille auxiliaire
  .Cells.NumberFormat = "@" 'format Texte
  F.Rows(1).Copy .[A1] 'copie la ligne de titres, à adapter
  For Each c In F.UsedRange
    If c.HasFormula Then .Range(c.Address) = c.FormulaLocal 'copie les formules
  Next
  .Columns.AutoFit 'ajuste les largeurs des colonnes
  .PageSetup.FitToPagesWide = 1 '1 page en largeur
  .PageSetup.FitToPagesTall = 1 'facultatif, 1 page en hauteur
  Application.ScreenUpdating = True
  Application.Wait Now + 5 / 86400 'facultatif, 5 secondes pour voir...
  .PrintOut
  .Delete
End With
End Sub

A+

 

[tany]

Re : imprimer cellules

Merci job75
je garde sous le coude ça fonctionne très bien, merci
la relation avec le post #1 est que je cherchais (mal) a imprimer les formules
ce que je souhaite c'est la liste sous cette forme
A1 ... formule
C7...formule
F 12...formule
etc...
d'où mon essai
probablement pas possible, me reste a copier coller dans word et
joindre l'impression aux impressions code feuille user...

 

[job75]

Re : imprimer cellules

Re,

Vous distillez vos desiderata au compte-gouttes

Sub ImprimerFormules()
Dim F As Worksheet, c As Range, lig As Long
Set F = ActiveSheet 'ou Feuil1, à voir
Application.ScreenUpdating = False
Application.DisplayAlerts = False
With Sheets.Add 'feuille auxiliaire
  .[A1] = "Cellule": .[B1] = "Formule"
  .[A1:B1].Font.Bold = True 'gras
  .Columns(2).NumberFormat = "@" 'format Texte
  lig = 2
  For Each c In F.UsedRange
    If c.HasFormula Then
      .Cells(lig, 1) = c.Address(0, 0)
      .Cells(lig, 2) = c.FormulaLocal 'copie la formule
      lig = lig + 1
    End If
  Next
  .Columns.AutoFit 'ajuste les largeurs des colonnes
  .PageSetup.FitToPagesWide = 1 '1 page en largeur
  .PageSetup.FitToPagesTall = 1 'facultatif, 1 page en hauteur
  Application.ScreenUpdating = True
  Application.Wait Now + 5 / 86400 'facultatif, 5 secondes pour voir...
  .PrintOut
  .Delete
End With
End Sub

A+

 

[tany]

Re : imprimer cellules

Bonjour,

oui c'est vrai et je dois m'en excuser, navré
je vais voir ce nouveau code et je reviens

 

[tany]

Merci infiniment job75
c'est exactement ce que je cherche, ça fonctionne impec
je ne sais même pas si je vais être capable de comprendre ce code
mais je vais pouvoir mettre au propre mes projets
encore merci et bravo

 

[job75]

Re : RESOLU Re : imprimer cellules

Bonjour tany, le forum,

J'avais oublié que quand on définit l'impression sur 1 page il faut mettre le Zoom à False.

Voyez le fichier joint avec cette macro corrigée :

Sub ImprimerFormules()
Dim F As Worksheet, c As Range, lig As Long
Set F = ActiveSheet 'ou Feuil1, à voir
Application.ScreenUpdating = False
Application.DisplayAlerts = False
With Sheets.Add 'feuille auxiliaire
  .[A1] = "Cellule": .[B1] = "Formule"
  .[A1:B1].Font.Bold = True 'gras
  .Columns(2).NumberFormat = "@" 'format Texte
  lig = 2
  For Each c In F.UsedRange
    If c.HasFormula Then
      .Cells(lig, 1) = c.Address(0, 0)
      .Cells(lig, 2) = c.FormulaLocal 'copie la formule
      lig = lig + 1
    End If
  Next
  .PageSetup.Zoom = False 'j'avais oublié
  .PageSetup.FitToPagesWide = 1 '1 page en largeur
  .PageSetup.FitToPagesTall = 1 'facultatif, 1 page en hauteur
  Application.ScreenUpdating = True
  Application.Wait Now + 5 / 86400 'facultatif, 5 secondes pour voir...
  .PrintPreview 'uniquement pour tester
  '.PrintOut 'pour imprimer
  .Delete
End With
End Sub

A+

 

[tany]

Re : RESOLU Re : imprimer cellules

rebonjour,

j'ai vu et rectifié, encore merci pour ce travail
je suis enchanté d'avoir mis au propre mes 10 derniers projets
comme cela j'ai une mine d'infos à disposition au fur et à mesure
bien amicalement.