[RÉSOLU] Mise en forme commentaires de la feuille active

[aubelix]

Bonjour à tous les Amis du Forum.

Je reviens de nouveau vers vous, pour solliciter votre aide.
J'aurai souhaité adapter le code suivant pour modifier les
commentaires de "la feuille active" et non de toutes les feuilles
car le temps d'exécution est extrêmement long.
D'autre part, j'ai essayé d'avoir un fond rouge pour une police en blanc
je n'ai pas réussi.
Par avance, Merci pour aide.

Sub MODIFIER_POLICE_COMMENTAIRES()
    On Error Resume Next
    Dim wks As Worksheet, MyCmt As Comment
    For Each wks In Worksheets
        For Each MyCmt In wks.Comments
            MyCmt.Shape.OLEFormat.Object.AutoSize = True
            With MyCmt.Shape.OLEFormat.Object.Font
                .Name = "Arial"
                .Size = 30
                .ColorIndex = 11
                .Bold = False
            End With
            MyCmt.Shape.OLEFormat.Object.ShapeRange.Fill.ForeColor.SchemeColor = 35
            MyCmt.Shape.AutoShapeType = msoShapeRoundedRectangle
        Next MyCmt
    Next wks
    Call MsgBox("  La mise en forme s'est déroulée avec succès    ", vbInformation Or vbDefaultButton1, "MEF Commentaire")
End Sub

Cordialement.

 

[DoubleZero]

Re : Mise en forme commentaires de la feuille active

Bonjour, aubelix, le Forum,

Peut-être ainsi :

Option Explicit
Sub Commentaire_personnaliser()
    On Error Resume Next
    Dim MyCmt As Comment
    For Each MyCmt In ActiveSheet.Comments
        MyCmt.Shape.OLEFormat.Object.AutoSize = True
        With MyCmt.Shape.OLEFormat.Object.Font
            .Name = "Arial"
            .Size = 30
            .ColorIndex = 2
            .Bold = False
        End With
        With MyCmt.Shape
            .OLEFormat.Object.ShapeRange.Fill.ForeColor.SchemeColor = 2
            .OLEFormat.Object.ShapeRange.Line.BackColor.RGB = RGB(255, 255, 255)
            .OLEFormat.Object.ShapeRange.Fill.ForeColor.SchemeColor = 10
            .AutoShapeType = msoShapeRoundedRectangle
        End With
    Next MyCmt
    Call MsgBox("  La mise en forme s'est déroulée avec succès    ", vbInformation Or vbDefaultButton1, "MEF Commentaire")
End Sub

A bientôt

 

[aubelix]

Re : Mise en forme commentaires de la feuille active

Bonjour DoubleZero et tous les Amis du Forum.

Merci pour ta réponse et ton aide.
Ta macro fonctionne très bien.
Mille Mercis.

Cordialement.

 

[DoubleZero]

Re : Mise en forme commentaires de la feuille active

Re-bonjour, aubelix, le Forum,

En attendant mieux... la macro mentionnée en #2 pourrait devenir :

Option Explicit
Sub Commentaire_personnaliser_V2()
    Dim MyCmt As Comment
    For Each MyCmt In ActiveSheet.Comments
        MyCmt.Shape.TextFrame.AutoSize = True
        MyCmt.Shape.AutoShapeType = msoShapeRoundedRectangle
        With MyCmt.Shape.OLEFormat.Object
            .Font.Name = "Arial"
            .Font.Size = 30
            .Font.ColorIndex = 2
            .Font.Bold = False
            .ShapeRange.Fill.ForeColor.SchemeColor = 2
            .ShapeRange.Line.BackColor.RGB = RGB(255, 255, 255)
            .ShapeRange.Fill.ForeColor.SchemeColor = 10
        End With
    Next
End Sub

A bientôt

 

[aubelix]

Re : [RÉSOLU] Mise en forme commentaires de la feuille active

Bonjour DoubleZero et tous les Amis du Forum.

Merci pour ta nouvelle réponse.
Elle paraît plus rapide.
Mille Mercis.

Cordialement.​

 

[STEPIQ76FR]

Re : [RÉSOLU] Mise en forme commentaires de la feuille active

Bonjour,
Juste pour info et rien à voir avec le sujet. Comment tu as fait pour afficher RESOLU dans le titre de ta demande.
A plus,

 

[DoubleZero]

Re : [RÉSOLU] Mise en forme commentaires de la feuille active

Bonjour à toutes et à tous,

... afficher RESOLU dans le titre...

En modifiant le titre du #1.

A bientôt