XL pour MAC (RESOLU) Formule STXT

[luno123]

Bonjour à tous,

J'ai un souci avec ma formule stxt. Dans l'onglet "14 06 21 ERROR" vous verrez que cette formule est utilisée en colonne B et permet de remplir automatiquement les colonne F et G via une rechercheV. Cependant, les lignes en jaune ne fonctionne pas avec "stxt(C;11;7). Par contre si je remplace 11 (manuellement) par 8 (que dans les cellules en jaune), je n'ai pas de message "pas de site" en colonne F et G.
J'applique certainement mal la formule en un moment donné.

Merci d'avance


Luno

 

[Hasco]

Bonjour,

Tous vos numéros sont précédés de "CB " alors cherchez cette sous-chaîne :

=STXT(C11;CHERCHE("CB ";C11)+3;7)

Cordialement

 

[st007]

Bonjour,
préférez en b4 étiré vers le bas. Je me base sur l'emplacement du "b" de CB puis ton code à extraire

=STXT(C4;CHERCHE("b";C4)+2;7)

 

[Hasco]

re,

préférez en b4 étiré vers le bas. Je me base sur l'emplacement du "b" de CB puis ton code à extraire

Sauf s'i peut y avoir a un 'b' avant le "CB "???

cordialement

 

[st007]

re,


Sauf s'i peut y avoir a un 'b' avant le "CB "???

cordialement

et si j'avais rafraichi avant de poster cette réponse, le plus important est qu'il comprenne le fonctionnement.

 

[luno123]

Merci beaucoup à tous ça fonctionne à merveille avec le code =STXT(C4;CHERCHE("b";C4)+2;7)

 

[soan]

Bonsoir Luno, le fil,

les 2 fichiers ci-joint sont les mêmes ; seul le type de fichier est différent ; le .xls fait 263 Ko ; le .xlsm fait 76 Ko ➯ taille réduite de 187 Ko (-71,10 %) ; j'ai créé ces 2 noms définis :​

* Sites : Fait référence à : =donnees!$A$4:$C$18

* Bus : Fait référence à : =donnees!$C$4:$D$18

---

formule en B4 :

=SI(C4="";"";SI(GAUCHE(C4;10)="REMISE CB ";STXT(C4;11;7);SI(GAUCHE(C4;7)="COM CB ";STXT(C4;8;7);"")))

note bien que ça retourne rien si C4 est vide et aussi dans ces 2 cas : si C4 ne commence ni par "REMISE CB ", ni par "COM CB " ; ainsi, ça retournera une valeur non vide uniquement si C4 commence par l'un des 2 textes bleu clair de cette phrase ; cette valeur non vide, c'est les 7 premiers chiffres du n° de CB indiqué en C4 ; cette formule est un peu longue, mais elle permet d'avoir une cellule vide pour tes libellés non concernés, par exemple ceux de C22:C25.​

---

formule en F4 :

=SI(B4="";"";SIERREUR(RECHERCHEV(SI(OU(B4<>"5334451";ET(B4="5334451";GAUCHE(C4)="C"));B4;STXT(C4;11-3*(GAUCHE(C4)="C");10));Sites;2;0);"pas de site"))

a) ça retourne rien si B4 est vide

b) ça recherche B4 si B4 est autre que "5334451" OU si B4 est "5334451" et que le 1er caractère de C4 est "C" (c'est-à-dire que selon les conditions de la formule de B4, c'est forcément pour : "COM CB ")

c) si ça n'a pas recherché B4 comme indiqué au point b), alors ça recherche les 10 chiffres du n° de CB indiqué en C4 ; à partir du 11ème caractère, OU : à partir du 8ème caractère si le 1er caractère de C4 est "C" (donc pour "COM CB")​

---

formule en G4 :

=SI(B4="";"";SIERREUR(RECHERCHEV(SI(OU(B4<>"5334451";ET(B4="5334451";GAUCHE(C4)="C"));B4;STXT(C4;11-3*(GAUCHE(C4)="C");10));Sites;3;0);"pas de site"))

seule différence par rapport à la formule de F4 : au lieu de ...;Sites;2;0) il y a : ...;Sites;3;0)

---

formule en H4 :

=SI(G4="";"";SIERREUR(RECHERCHEV(G4;Bus;2;0);""))

ça retourne rien si G4 est vide ; sinon ça recherche G4​

---

pour les 4 formules ci-dessus : je les ai tirées vers le bas jusqu'en ligne 108 ; il te reste plus qu'à vérifier tous les résultats, mais attention : dans tes propres résultats, tu as parfois "PLOEREN" alors que moi j'ai "CARQUEFOU- SIEGE" ; c'est à cause de ton erreur dans le tableau de la feuille "donnees" : en colonne A, il y a "5334451" À LA FOIS en A4 ET en A8 ! donc RECHERCHEV() trouve B4 et jamais B8 ! normalement, il ne devrait y avoir aucun doublon en colonne A ! je te laisse régler « ce détail » ! ​

soan

 

[luno123]

Bonjour Soan, bonjour le forum,

Merci beaucoup pour votre aide précieuse

 

[luno123]

J’ai un souci de formule dans mes cellules jaunes. Quelqu’un pourrait m’aider svp ?



Merci d’avance



Cordialement

 

[st007]

Attention au format, colonne A onglet donnees
Format texte précédé d'une apostrophe. mais pas partout .....

 

[luno123]

Attention au format, colonne A onglet donnees
Format texte précédé d'une apostrophe. mais pas partout .....

Effectivement en corrigeant l'apostrophe tout fonctionne. Merci beaucoup